Skysnake

a little help with GUIRegisterMsg

3 posts in this topic

#1 ·  Posted (edited)

I have read the Tutorial. Used the Help File and used an example script by @Melba23.  I am still struggling.

To use GUIRegisterMsg one needs the following

  • a control in the GUI
  • a GUIRegisterMsg instruction in the GUI to link the control to the WM_COMMAND function
  • a Case statement in the Switch loop to run it
  • a WM_COMMAND function
  • and a processor function...

Mine looks like this

;~  ; QuickSearch combo box
    $g_cbQwkSrch = GUICtrlCreateCombo("", 8, 26, 180, 17) ; start blank
    GUICtrlSetTip($g_cbQwkSrch, "Type to search", "QuickSearch")


    GUIRegisterMsg($WM_COMMAND, "__WM_COMMAND_QWKSEARCH_CMB")



;------------------------------------

; use in Switch Loop

;~              ; QuickSearch
            Case $g_cbQwkSrch
                ConsoleWrite("221 Case $g_cbQwkSrch" & @CRLF)



;--------------------------------------

Func _QwkSrch_Edit_Changed()
    ConsoleWrite("41 _QwkSrch_Edit_Changed" & @CRLF)

    ; Autocomplete the edit
    _GUICtrlComboBox_AutoComplete($g_cbQwkSrch)
    ; Change the label to match the autocompleted edit entry

EndFunc   ;==>_QwkSrch_Edit_Changed

Func __WM_COMMAND_QWKSEARCH_CMB($hWnd, $iMsg, $wParam, $lParam) ; GUIRegisterMsg($WM_COMMAND, "__WM_COMMAND_QWKSEARCH_CMB")
    ConsoleWrite("50 _WM_COMMAND_QWKSEARCH_CMB fired " & @CRLF)
    Local $Found = ''

    #forceref $hWnd, $iMsg
    If $lParam = GUICtrlGetHandle($g_cbQwkSrch) And BitShift($wParam, 16) = $CBN_EDITCHANGE Then ; Our combo edit content has changed

; get data from source ----------------------------
Local $datafromsource = fFindFilesForQuickSearch($stringtofind)

; datafromsource convert to Combo friendly format

                    ; Add data to combo
                    _GUICtrlComboBox_BeginUpdate($g_cbQwkSrch)
                    GUICtrlSetData($g_cbQwkSrch, $Found)
                    _GUICtrlComboBox_EndUpdate($g_cbQwkSrch)


        EndIf

        _QwkSrch_Edit_Changed() ; Action this function

    EndIf

EndFunc   ;==>_WM_COMMAND_QWKSEARCH_CMB

Func fFindFilesForQuickSearch($stringtofind)
    ; helper function for QuickSearch

; get data here

    Return $aResult

EndFunc   ;==>fFindFilesForQuickSearch

Now the following:

  1. Can I declare the variable $g_cbQwkSrch in Global, then use in multiple functions - reassigning different combo's to it as I go along?
  2. Should GUIRegisterMsg be expressly de-registered, or does that happen automatically at GuiDelete()?
  3. Where is the best/correct place to call GUIRegisterMsg? With the creation of its control, before the GUISetState, or before the start of the loop?
  4. The Help File contains this entry, what is the intent?  Must this always be called with four args, or a max of four...   !!! To make the user function workable you have to define it with maximum 4 function parameters otherwise the function won't be called !!!
Edited by Skysnake

Skysnake

Why is the snake in the sky?

Share this post


Link to post
Share on other sites



#2 ·  Posted

Skysnake,

1. This is how I would deal with multiple combos:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>
#include <File.au3>

; A flag to prevent the autocomplete from continually firing
Global $bAutoComplete = False

; Your AutoIt folder
Global $sRootFolder = StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", Default, -1))
ConsoleWrite($sRootFolder & @CRLF)

; Create GUI
$hGUI = GUICreate("Test", 500, 500)

GUICtrlCreateLabel("Include files", 10, 30, 200, 20)
$cCombo_1 = GUICtrlCreateCombo("", 10, 50, 200, 20)
GUICtrlCreateLabel("SciTE Property files", 10, 80, 200, 20)
$cCombo_2 = GUICtrlCreateCombo("", 10, 100, 200, 20)
; Create a dummy control which fires when a combo is edited
$cComboChange_Dummy = GUICtrlCreateDummy()

GUISetState()

; Register the mesasge handler
GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cComboChange_Dummy
            ; A Combo was changed - read the dummy to find out which one
            $cComboChanged = GUICtrlRead($cComboChange_Dummy)
            ; And then run the function with the correct combo ControlID
            _Combo_Changed($cComboChanged)
    EndSwitch

WEnd

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    ; Check it is a cambo edit change messgae and that it is not an autocomplete change
    If BitShift($wParam, 16) = $CBN_EDITCHANGE And $bAutoComplete = False Then
        ; Check which combo sent the message
        Switch $lParam
            Case GUICtrlGetHandle($cCombo_1)
                ; Send the combo ControlID to the dummy so we can read it later
                GUICtrlSendToDummy($cComboChange_Dummy, $cCombo_1)
                ; Set the flag so that the autocomplete does not fire the handler
                $bAutoComplete = True
            Case GUICtrlGetHandle($cCombo_2)
                GUICtrlSendToDummy($cComboChange_Dummy, $cCombo_2)
                $bAutoComplete = True
        EndSwitch
    EndIf

EndFunc

Func _Combo_Changed($cCombo)

    Switch $cCombo
        Case $cCombo_1
            ; Set the required path
            $sPath = $sRootFolder & "Include"
            ; Get the files which match
            $aList = _FileListToArray($sPath, "*.au3")
        Case $cCombo_2
            $sPath = $sRootFolder & "SciTE"
            $aList = _FileListToArray($sPath, "*.properties")
    EndSwitch

    ; Convert the list to required format
    $sComboData = ""
    For $i = 1 To $aList[0]
        $sComboData &= "|" & $aList[$i]
    Next

    ; Read the current content of the edit
    $sCurrContent = GUICtrlRead($cCombo)
    ; Load the file list into the combo
    GUICtrlSetData($cCombo,$sComboData)
    ; Reload the edit content as it has been cleared by the combo data load
    ControlSend($hGUI, "", $cCombo, $sCurrContent)
    ; Do the sutocomplete
    _GUICtrlComboBox_AutoComplete($cCombo)
    ; Clea the flag so new user input will allow the handler to fire
    $bAutoComplete = False

EndFunc

2. There is no need to specifically deregister messages on exit - AutoIt does this for you

3. I usually register messages just before entering the idle loop - although you can do it earlier and in some cases it is necessary to do so.

4. The Help file is correct - there is a maximum of 4 parameters. If you are not going to use parameters then you can omit them - as long as there are no subsequent parameters required:

Func _WM_COMMAND($hWnd, $iMsg)                  ; Correct syntax

Func _WM_COMMAND($hWnd, $iMsg, $lParam)         ; Incorrect syntax - $lParam will actually hold $wParam value

All clear?

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

#3 ·  Posted

Much :)

Thank you kindly.


Skysnake

Why is the snake in the sky?

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now

  • Similar Content

    • Skysnake
      By Skysnake
      Hi
      Best example I could find is here
      ::/html/libfunctions/_GUICtrlTreeView_ClickItem.htm
      The way I understand this, the standard Windows messages, such as Left/Right Click etc are covered by AutoIt macros, but the real power is locked up inside this WM_NOTIFY .  I have tried, but I am not even sure I understand what I am looking at.
      I need help understanding this.  What I am looking for is Help file or Tutorial explaining how this works?  
      Perhaps if there is a script showing both the working of an AutoIt macro and the WM_NOTIFY  in action, it would help.
      Right now I am so lost, I do not even know what are the right questions to ask.  One issue I have is on ListViews, how to combine the "Click" of a line with a standard Switch loop?  Like users clicks a line, then get the loop to detect the click and ;do something ...
      Any ideas?
      Skysnake
    • kcvinu
      By kcvinu
      Hi all,
      I know this is a crazy idea. But i think it might be a help for somebody. The name of this program is GRM Helper. i.e. GUIRegisterMsg Helper. 
      This program helps you to write the guiregistermsg function code automatically. You can choose a control from the combo box. Then all events of that control will be displayed in a list view. You can click on an event for it;s details. Then you can check the events which you want to include in your code. Then type some details like; 1) Your control's handle. 2) Line number for inserting GUIRegisterMsg code. 3) Line number for inserting main function.
      And press the "Isert To SciTE" button. Your code is ready in scite.
       
      Here is the program.
      Updated Version 1.1
      GRM Helper V1.1.zip
       
       

      The code written by this program.
      GUIRegisterMsg($WM_COMMAND, "WM_COMMAND") Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam) #forceref $hWnd, $iMsg Local $hWndFrom, $iIDFrom, $iCode, $hWndListBox If Not IsHWnd($Sample) Then $hWndListBox = GUICtrlGetHandle($Sample) $hWndFrom = $lParam $iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word $iCode = BitShift($wParam, 16) ; Hi Word Switch $hWndFrom Case $Sample, $hWndListBox Switch $iCode Case $LBN_ERRSPACE ; Insert your code here Case $LBN_SELCHANGE ; Insert your code here Case $LBN_DBLCLK ; Insert your code here Case $LBN_SELCANCEL ; Insert your code here EndSwitch EndSwitch Return $GUI_RUNDEFMSG EndFunc ;==>WM_COMMAND  
       
    • kcvinu
      By kcvinu
      Hi all,
      I am playing with a combo box. The code from help file is working. But the code i wrote is not working. Help file uses "_GUICtrlComboBox_Create" for creating combo box. But i used native "GUICtrlCreateCombo". Then i replaced my native combo creation function with the UDF. Then my code worked. I think the hi word and low word parameters are the problem. 
      Here is my code.
      #include <ComboConstants.au3> #include <GUIConstantsEx.au3> #include <WindowsConstants.au3> Local $sCMB_Items = "Apple|Orange|Mango|Banana|Grape" #Region ### START Koda GUI section ### Form= Global $hForm1 = GUICreate("Form1", 283, 188, 312, 166) Global $hCombo1 = GUICtrlCreateCombo("", 40, 48, 185, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL)) GUISetState(@SW_SHOW) #EndRegion ### END Koda GUI section ### GUICtrlSetData($hCombo1, $sCMB_Items) GUIRegisterMsg($WM_COMMAND, "WM_COMMAND") While 1 $nMsg = GUIGetMsg() Switch $nMsg Case $GUI_EVENT_CLOSE Exit EndSwitch WEnd Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam) #forceref $hWnd, $iMsg Local $hWndFrom, $iIDFrom, $iCode $hWndFrom = $lParam $iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word $iCode = BitShift($wParam, 16) ; Hi Word Switch $hWndFrom Case $hCombo1 Switch $iCode Case $CBN_DBLCLK ; Insert your code here MsgBox(0,"","$CBN_DBLCLK") Case $CBN_DROPDOWN ; Insert your code here MsgBox(0,"","$CBN_DROPDOWN") Case $CBN_EDITCHANGE ; Insert your code here MsgBox(0,"","$CBN_EDITCHANGE") Case $CBN_SELCHANGE ; Insert your code here MsgBox(0,"","$CBN_SELCHANGE") EndSwitch EndSwitch Return $GUI_RUNDEFMSG EndFunc ;==>WM_COMMAND And this is the code from help file. Slightly modified. But working
      #include <GuiComboBox.au3> #include <GUIConstantsEx.au3> #include <MsgBoxConstants.au3> #include <WindowsConstants.au3> Global $g_hCombo Example() Func Example() Local $hGUI ; Create GUI $hGUI = GUICreate("(UDF) ComboBox Create", 400, 296) $g_hCombo = _GUICtrlComboBox_Create($hGUI, "", 2, 2, 396, 296) GUISetState(@SW_SHOW) ; Add files _GUICtrlComboBox_BeginUpdate($g_hCombo) _GUICtrlComboBox_AddDir($g_hCombo, "", $DDL_DRIVES, False) _GUICtrlComboBox_EndUpdate($g_hCombo) GUIRegisterMsg($WM_COMMAND, "WM_COMMAND") ; Loop until the user exits. Do Until GUIGetMsg() = $GUI_EVENT_CLOSE GUIDelete() EndFunc ;==>Example Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam) #forceref $hWnd, $iMsg Local $hWndFrom, $iIDFrom, $iCode $hWndFrom = $lParam $iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word $iCode = BitShift($wParam, 16) ; Hi Word Switch $hWndFrom Case $g_hCombo Switch $iCode Case $CBN_CLOSEUP ; Sent when the list box of a combo box has been closed MsgBox(0,"","$CBN_CLOSEUP") Case $CBN_DBLCLK ; Sent when the user double-clicks a string in the list box of a combo box MsgBox(0,"","$CBN_DBLCLK") Case $CBN_DROPDOWN ; Sent when the list box of a combo box is about to be made visible MsgBox(0,"","$CBN_DROPDOWN") Case $CBN_EDITCHANGE ; Sent after the user has taken an action that may have altered the text in the edit control portion of a combo box MsgBox(0,"","$CBN_EDITCHANGE") Case $CBN_EDITUPDATE ; Sent when the edit control portion of a combo box is about to display altered text Case $CBN_ERRSPACE ; Sent when a combo box cannot allocate enough memory to meet a specific request Case $CBN_KILLFOCUS ; Sent when a combo box loses the keyboard focus Case $CBN_SELCHANGE ; Sent when the user changes the current selection in the list box of a combo box MsgBox(0,"","$CBN_SELCHANGE") EndSwitch EndSwitch Return $GUI_RUNDEFMSG EndFunc ;==>WM_COMMAND For those who wants the au3 file;
      Here it is
       
      Code From help file.au3
      My code.au3
    • kcvinu
      By kcvinu
      Hi all,
      I am playing with GUIRegisterMsg function for learning it. This is my code. It is not working. The error msg is this
      Variable used without being declared.:
      $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
      $tNMHDR = DllStructCreate($tagNMHDR, ^ ERROR
      I can't find lParam as a declared variable in _GUICtrlListView_Create.au3 in help file.
      #include <ButtonConstants.au3> #include <ComboConstants.au3> #include <EditConstants.au3> #include <GUIConstantsEx.au3> #include <GUIListBox.au3> #include <WindowsConstants.au3> #include <MouseOnEvent.au3> #include <Alert.au3> #include <ListBoxConstants.au3> Opt("GUIOnEventMode", 1) #Region ### START Koda GUI section ### Form=K:\GUI Reg Msg Test works\GRM test GUI.kxf Global $Form1 = GUICreate("Form1", 611, 430, 260, 140) GUISetFont(12, 400, 0, "Segoe UI") GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close") GUISetOnEvent($GUI_EVENT_MINIMIZE, "Form1Minimize") GUISetOnEvent($GUI_EVENT_MAXIMIZE, "Form1Maximize") GUISetOnEvent($GUI_EVENT_RESTORE, "Form1Restore") Global $Button1 = GUICtrlCreateButton("Button1", 368, 360, 137, 49) GUICtrlSetOnEvent(-1, "Button1Click") Global $List1 = GUICtrlCreateList("", 16, 216, 161, 181) GUICtrlSetOnEvent(-1, "List1Click") Global $Combo1 = GUICtrlCreateCombo("Combo1", 352, 24, 193, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL)) GUICtrlSetOnEvent(-1, "Combo1Change") Global $Input1 = GUICtrlCreateInput("Input1", 48, 32, 169, 33) GUICtrlSetOnEvent(-1, "Input1Change") Global $Edit1 = GUICtrlCreateEdit("", 248, 80, 321, 161) GUICtrlSetData(-1, "Edit1") GUICtrlSetOnEvent(-1, "Edit1Change") GUIRegisterMsg($WM_NOTIFY,"List1Click") GUISetState(@SW_SHOW) #EndRegion ### END Koda GUI section ### Local $tmp = ["Orange","Apple","Banana","Papaya","Grapes"] For $i = 0 to 4 GUICtrlSetData($List1,$tmp[$i]) Next While 1 Sleep(100) WEnd Func List1Click($hWnd, $iMsg, $wParam, $lParam) #forceref $hWnd, $iMsg Local $hWndFrom,$iIDfrom, $iCode, $tNMHDR, $hWndList, $tInfo $hWndList = $List1 if Not IsHWnd($List1) Then $hWndList = GUICtrlGetHandle($List1) $tNMHDR = DllStructCreate($tagNMHDR, $lParam) $hWndFrom = HWnd(DllStructGetData($tNMHDR,"hWndFrom")) $iIDfrom = DllStructGetData($tNMHDR,"IDFrom") $iCode = DllStructGetData($tNMHDR, "Code") Switch $hWndFrom Case $List1 Switch $iCode Case $LBN_DBLCLK ;$tInfo = DllStructCreate($tagNMMOUSE) Alert("You Clicked Twice") EndSwitch EndSwitch Return $GUI_RUNDEFMSG EndFunc This gui is only for learning pupose. So please don't mind its aesthetic style.
    • cabrunco
      By cabrunco
      Dear all (and especially Martin, if available), I am working on a GUI that reads the signals from a gas flow meter (ProFLow 6000, by Restek). In the manual of the device, there are the instructions for how to read the signal using a computer via comm ports. I can do it using the CommMG.au3 UDF by Martin, it works fine. However, I am trying to make a GUI in which there are 2 buttons: start and stop, the start button starts the reading of the comm port signal, and the stop button stops it. I did this following the tutorial available on https://www.autoitscript.com/wiki/Interrupting_a_running_function , more specifically the first example for GUI message loop mode that employs GUIRegisterMsg as a way to enable a function to stop another. It works, the start function is stopped by the stop button. However, if I try to start again, it does not work. I press the start button and nothing happens.
      I must say that this only happens if I use a function to read the comm port. For other kinds of functions, for example, reading the computer clock, there is no problem, after stopping I can re-start again.
      My question is: how to make it possible to re-start the reading function for the Comm port once it was stopped using the GUIRegisterMsg?
      Below goes my code (sorry, it is my first time and I am not sure of the best way of pasting it here). If includes also the clock button that can be used to test the stopping process (it should work). 
       
       
      #include "commMG.au3"
      #include <GUIConstantsEx.au3>
      #include <ColorConstants.au3>
      #include <StaticConstants.au3>
      #include <WindowsConstants.au3>
       
      Local $FlowMeterPort
      Local $PortError
       
      $Interrupt_flag = 0
       
      $FlowMeter = GUICreate("Flow meter reader", 200, 160, 500, 200)
       
      $Reading = GUICtrlCreateLabel("",20,40,120,18)
      GUICtrlSetBkColor($Reading,$COLOR_WHITE)
      $Start = GUICtrlCreateButton("Start", 20, 60, 50, 20)
      $Stop = GUICtrlCreateButton("Stop", 20, 80, 50, 20)
      $Clock = GUICtrlCreateButton("Clock", 20, 100, 50, 20)
       
       
      $FlowMeterPort = InputBox("Flow meter reader","Welcome to the flow meter reader! Please type in the number of the COM port connecting the computer to the flow meter. If you do not know, go to Control Panel, Hardware settings, and try to find it among the listed COM ports.")
       
      GUISetState()
      GUIRegisterMsg($WM_COMMAND, "FlowMeter_WM_COMMAND")
       
      While 1
      Switch GUIGetMsg()
      Case $GUI_EVENT_CLOSE
      Exit
      Case $Start
      _CommSetPort($FlowMeterPort, $PortError, 115200, 8, 0, 1, 2)
      $Interrupt_flag = 0
      While $Interrupt_flag = 0
      $FlowMeterReading = _CommReadString(100)
      GUICtrlSetData($Reading,$FlowMeterReading)
      WEnd
      Case $Clock
      $Interrupt_flag = 0
      While $Interrupt_flag = 0
      GUICtrlSetData($Reading,@HOUR & @MIN & @SEC)
      WEnd
      EndSwitch
      WEnd
       
      Func FlowMeter_WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
      If BitAND($wParam, 0x0000FFFF) = $Stop Then $Interrupt_flag = 1
      EndFunc
       
       
      Func _CommReadString($TimeSpan)
      Local $Reading
      $Start = TimerInit()
      $End = 0
      $ReadStep = 0
      While $End < $TimeSpan
      $Reading = $Reading & _Commgetstring()
      $End = TimerDiff($Start)
      If $Reading <> '' Then
      $ReadStep = $ReadStep + 1
      EndIf
      If $ReadStep > 100 Then $End = $TimeSpan
      Sleep(0)
      WEnd
      Return $Reading
      EndFunc ;==>_CommReadString