_ArrayDisplay after loop?

[youtuber]

I want to display _ArrayDisplay after the For loop

#include <File.au3>
#include <Array.au3>

Local $FolderList = @ScriptDir
Local $len = 259
Local $aRec = ""
Local $AllFilesFolder

$AllFilesFolder = _FileListToArrayRec($FolderList, "*", $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH)
If IsArray($AllFilesFolder) Then
    For $i = 1 To $AllFilesFolder[0]
        If StringLen($AllFilesFolder[$i]) > $len Then
            $aRec &= $AllFilesFolder[$i] & @CRLF
        EndIf
    Next
    ConsoleWrite($aRec & @CRLF) ;No problem
    MsgBox(48,"Files folders length is more than 259", $aRec) ;No problem
    _ArrayDisplay($aRec, " Files folders length is more than 259") ;problem!
EndIf

 

[Melba23]

youtuber,

As $aRec is not an array but a string, why would you expect _ArrayDisplay to work? If you were to use StringSplit on $aRec before the _ArrayDisplay call then you would then have an array to pass to the function.

M23

[youtuber]

I added but failed

$AllFilesFolder = _FileListToArrayRec($FolderList, "*", $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH)
If IsArray($AllFilesFolder) Then
    For $i = 1 To $AllFilesFolder[0]
        If StringLen($AllFilesFolder[$i]) > $len Then
            $aRec &= StringSplit($AllFilesFolder[$i],@CRLF)
        EndIf
    Next
    ConsoleWrite($aRec & @CRLF) ;No problem
    MsgBox(48,"Files folders length is more than 259", $aRec) ;No problem
    _ArrayDisplay($aRec, " Files folders length is more than 259") ;problem!
EndIf

 

[Subz]

As Melba23 pointed out $aRec is a string,, use something like _ArrayAdd to create an array or just use the $AllFilesFolder Array for example:

#include <File.au3>
#include <Array.au3>

Local $FolderList = @ScriptDir
Local $len = 259
Local $AllFilesFolder

$AllFilesFolder = _FileListToArrayRec($FolderList, "*", $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH)
If IsArray($AllFilesFolder) Then
    For $i = $AllFilesFolder[0] To 1 Step - 1
        If StringLen($AllFilesFolder[$i]) <= $len Then _ArrayDelete($AllFilesFolder, $i)
    Next
    $AllFilesFolder[0] = UBound($AllFilesFolder) - 1
    MsgBox(48,"Files folders length is more than 259", _ArrayToString($AllFilesFolder, @CRLF, 1)) ;No problem
    _ArrayDisplay($AllFilesFolder, " Files folders length is more than 259") ;problem!
EndIf

 

Edited June 3, 2019 by Subz

[youtuber]

Does the search on file names take longer, do you have a faster suggestion?

[Nine]

I believe it is the multiple _ArrayDelete that's taking more time.  Just use your code with a StringSplit like this :

#include <File.au3>
#include <Array.au3>

Local $FolderList = @ScriptDir
Local $len = 259
Local $aRec = ""
Local $AllFilesFolder

$AllFilesFolder = _FileListToArrayRec($FolderList, "*", $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH)
If IsArray($AllFilesFolder) Then
    For $i = 1 To $AllFilesFolder[0]
        If StringLen($AllFilesFolder[$i]) > $len Then
            $aRec &= $AllFilesFolder[$i] & @LF
        EndIf
    Next
    ConsoleWrite($aRec) ;No problem
    MsgBox(48,"Files folders length is more than 259", $aRec) ;No problem
    $aRec = StringSplit ($aRec, @LF)
    _ArrayDisplay($aRec, " Files folders length is more than 259") ;NO MORE problem!
EndIf