Prevent Mouse Right Click Menu?

[iAmNewbe]

I wrote a little application to remote control a music player application with one of my multi-button mouses.

Is there a way to prevent the right click menu from appearing but still allow the right click button to register?

I also want to track the mouse wheel so I can control volume.  Anyway to do that also?

There was no mention in the manual about these two things, not sure if there is another way to go about this.

[iAmNewbe]

I am not interested in SENDING these commands.. I want to track through something like _isPressed or some similar function to register physical mouse clicks, scroll wheel turn front or back and also the  middle mouse click which that exists.

[Nine]

Callback mouse function to track mouse usage...

[mikell]

Here it is 
 

expandcollapse popup

#include <WinAPI.au3>
#include <WindowsConstants.au3>

HotKeySet('{ESC}', '_Close')

Global Const $tagMSLLHOOKSTRUCT = $tagPOINT & ';uint mouseData;uint flags;uint time;ulong_ptr dwExtraInfo;'
Global $hFunc, $pFunc, $hHook, $hMod, $iCounter = 0 ; The wheel counter
$hFunc = DllCallbackRegister('_MouseProc', 'lresult', 'int;int;int')
$pFunc = DllCallbackGetPtr($hFunc)
$hMod = _WinAPI_GetModuleHandle(0)
$hHook = _WinAPI_SetWindowsHookEx($WH_MOUSE_LL, $pFunc, $hMod)

While 1
    Sleep(20)
WEnd

Func _MouseProc($iCode, $iwParam, $ilParam)
    Local $tMSLL, $iDelta
    If $iCode < 0 Then Return _WinAPI_CallNextHookEx($hHook, $iCode, $iwParam, $ilParam)
    $tMSLL = DllStructCreate($tagMSLLHOOKSTRUCT, $ilParam)
    Switch $iwParam
     Case $WM_RBUTTONUP   ; right ckick
        ConsoleWrite("Right click" & @LF) ; <<<< some action here
        Return 1   ;<<<<<<< without further condition setting this disables right click everywhere (context menus etc)
     Case $WM_MBUTTONUP ; middle click
        ConsoleWrite("Middle button click" & @LF)
     Case $WM_MOUSEWHEEL ; mouse wheel
        $iDelta = BitShift(DllStructGetData($tMSLL, 'mouseData'), 16)
        If $iDelta < 0 Then
            $iCounter -= 1
        Else
            $iCounter += 1
        EndIf
        ConsoleWrite($iCounter & @LF)
       ; Return 1 ; <<<< ditto  
    EndSwitch
    Return _WinAPI_CallNextHookEx($hHook, $iCode, $iwParam, $ilParam)
EndFunc

Func _Close()
    _WinAPI_UnhookWindowsHookEx($hHook)
    DllCallbackFree($hHook)
    Exit
EndFunc

 

Edited August 8, 2019 by mikell
comments