Monitor a folder before moving to next command

[Buster2000]

Hi - I have an app which which writes files to a folder and once those files have been written it moves on to another task.  I have some of this automated using AutoIT - but I'm looking for help with a loop or a pause so AutoIT waits for the files to finish writing to a folder before moving onto the next AutoIT command.  Can someone help guide me down the right path on this?  I've investigated many methods but have been unable to find much in the forums.  

[Musashi]

Have a look at : FileFlush

Your script would also be helpful for further support .

[junkew]

https://www.autoitscript.com/autoit3/docs/functions/FileGetSize.htm

Check filesize for a certain number of seconds not growing in size.

[Buster2000]

Thanks for your replies.  After further investigation I found DirGetSize is the way to go.  My next question is how do I put DirGetSize into a loop so the script pauses while $iSize is changing in dize, until I've had 30 seconds of $iSize not changing before moving onto the next command?  I've included my script below.

Thanks in advance.

Quote

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

DirSize()

Func DirSize()

    Local $iSize = DirGetSize("C:\Temp", $DIR_EXTENDED)
    If Not @error Then

        MsgBox($MB_SYSTEMMODAL, "", "Size(Bytes): " & $iSize[0] & @CRLF _
                 & "Files: " & $iSize[1] & @CRLF)

    EndIf
 EndFunc

; Next Command

 WinWaitActive("Desktop")
         Sleep(3000)
         Send("{Runscript.exe}")
         Send("{Enter}")
 

 

[Nine]

Try this :

#include <Constants.au3>

CheckDirSize("C:\Temp")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "", "Error reading directory")
; do the things you need to do here

Func CheckDirSize($sFolder)
  Local $iSize = DirGetSize($sFolder)
  If @error Then Return SetError(1)
  Local $hTimer = TimerInit(), $iNewSize
  While True
    Sleep(1000)
    $iNewSize = DirGetSize($sFolder)
    If $iSize = $iNewSize Then
      If TimerDiff($hTimer) > 30 * 1000 Then Return
    Else
      $iSize = $iNewSize
      $hTimer = TimerInit()
    EndIf
  WEnd
EndFunc   ;==>CheckDirSize

 

[Danp2]

A few observations --

• I hope that the c:\temp directory is just an example. Otherwise, it's likely that other programs will also be writing to this directory and you won't get the results that you expect
• @Nine Wouldn't it be more efficient to change your Sleep to 30000? That way, you aren't repeatedly checking the directory size during the 30 second "delay" period. You wouldn't even need to timer. 😄

[Nine]

@Danp2  Well I thought about it, but checking on a large folder with multiple subfolders can take a little while.  So I just wanted to make sure it is as close as possible to the 30 secs.

[Danp2]

Not sure of the OP's requirements, but maybe use $DIR_NORECURSE for the optional flag to prevent recursion of the subdirectories.

[Buster2000]

@Nine this is exactly what I needed and your script works perfectly!  Thank you so much for sharing this.  I was able to shorten the timer down to 5 seconds because the folder I'm watching is small.  

@Danp2 this is just an example of the folder I'm using - I just threw the temp folder in there as an example. 

[junkew]

Maybe just monitoring events can help improve

 

[Buster2000]

@Nine I have one final question.  In your script where you say:

; do the things you need to do here

How would I add multiple tasks in there, each consecutive task running once the directory stops changing in size?  Meaning - once Task 1 is finished due to the folder size not changing anymore.  It then runs Task 2, then when the folder stops changing in size, run Task 3 and so on.

Thanks!

[Danp2]

@Buster2000 Just stack the calls, like this --

; Launch task 1 here
CheckDirSize("C:\Temp")
; Launch task 2 here
CheckDirSize("C:\Temp")
; Launch task 3 here
CheckDirSize("C:\Temp")
; etc

 

[Nine]

You mean :

CheckDirSize("C:\Temp")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "", "Error reading directory")
Task1()
CheckDirSize("C:\Temp")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "", "Error reading directory")
Task2()
CheckDirSize("C:\Temp")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "", "Error reading directory")
Task3()
...

Or you could make a loop :

For $i = 1 to $NUMBER_OF_TASKS
  CheckDirSize("C:\Temp")
  If @error Then Exit MsgBox($MB_SYSTEMMODAL, "", "Error reading directory")
  Call ("Task" & $i)
Next

 

[Buster2000]

Thanks @Nine that works exactly as expected.  Thanks again for your help!