Jump to content

[solved] problem to drive a command prompt via a NamedPipe


Recommended Posts

I'm trying to drive a command prompt by sending instructions via a NamedPipe.
This way you can (should) be able to send commands to the command prompt and at the same time "view" the result in the same window.
This is not allowed if you run a command prompt with "opt_flag" parameters (redirected streams) because this will disable StdOut on the cmd itself.

This small (trivial) snippet works for the first command sent to the cmd, but further submissions will fail.

Maybe the problem is in how I use the run () command to start a new cmd with the StdIn redirect from the NamedPipe. It seems that the generated cmd will close automatically after the first reception of the command via NamedPipe.

suggestions on how to make it work are welcome
thanks

#include <NamedPipes.au3>
#include <WinAPI.au3>

; Creates an instance of a named pipe
Global $sPipeName = "\\.\pipe\pipename"
Global $hPipe = _NamedPipes_CreateNamedPipe($sPipeName, 1, 1)

MsgBox(0, "Debug", "Pipe created. Now open a CMD")

; run a cmd with only StdIn redirected (StdIn data incoming from a pipe)
Global $hCMD = Run(@ComSpec & " /K cmd < " & $sPipeName & @CRLF, "c:\") ; ok?

MsgBox(0, "Debug", "now Send a command to the cmd via a NamedPipe")
_StdInPipeWrite("dir" & @CRLF)

MsgBox(0, 'Debug', "further commands will fail" & @CRLF & "now send command 'dir c:\windows'")
$sMessage = "Dir c:\windows" & @CRLF
_StdInPipeWrite($sMessage)

MsgBox(0, 'Debug', "send another command (will also fail)" & @CRLF & "now send command 'echo Hello'")
_StdInPipeWrite("echo Hello" & @CRLF)

MsgBox(0, "Debug", "end of test")
ProcessClose($hCMD)

Func _StdInPipeWrite($sMessage)

    ; ===============================================================================================================================
    ; This function writes a message to the pipe
    ; ===============================================================================================================================
    Local $iWritten, $iBuffer, $pBuffer, $tBuffer

    $iBuffer = StringLen($sMessage) + 1
    $tBuffer = DllStructCreate("char Text[" & $iBuffer & "]")
    $pBuffer = DllStructGetPtr($tBuffer)
    DllStructSetData($tBuffer, "Text", $sMessage)
    If Not _WinAPI_WriteFile( _
            $hPipe, _ ; ...... Handle to the file to be written
            $pBuffer, _ ; .... Pointer to the buffer containing the data to be written
            $iBuffer, _ ; .... Number of bytes to be written to the file
            $iWritten, _ ; ... The number of bytes written
            0 _ ; ............ [optional] A $tagOVERLAPPED structure or a pointer to it
            ) Then
        ConsoleWrite("WriteMsg: _WinAPI_WriteFile failed" & @CRLF & _WinAPI_GetLastErrorMessage())
    Else
        ConsoleWrite("WriteMsg: write OK" & @CRLF & _WinAPI_GetLastErrorMessage() & @CRLF)
    EndIf
EndFunc   ;==>_StdInPipeWrite

 

Edited by Chimp

 

image.jpeg.9f1a974c98e9f77d824b358729b089b0.jpeg Chimp

small minds discuss people average minds discuss events great minds discuss ideas.... and use AutoIt....

Link to comment
Share on other sites

... it seems that at the end of each command sent to cmd, there is a request pending from the pipe asking for something to the 'caller'. (something like'do you need to send more data?') I have seen that sending an @CRLF as the first character of the next sending allows you to send further commands to cmd via NomedPipe. As if the @CRLF accepts the default answer which I suppose is "yes, I have more data to send, stay connected" (?) ... or something similar.
However, although this workaround works (see line 30 in listing), it is not clear to me what happens under the hood.
if anyone has a clearer idea than mine, i would be glad to know it.
Thanks for any suggestions

#include <NamedPipes.au3>
#include <WinAPI.au3>

; Creates an instance of a named pipe
Global $sPipeName = "\\.\pipe\pipename"
Global $hPipe = _NamedPipes_CreateNamedPipe($sPipeName, 1, 2)
Global $sPrefix = ''

MsgBox(0, "Debug", "Pipe created. Now open a CMD")

; run a cmd with only StdIn redirected (StdIn data incoming from a pipe)
Global $hCMD = Run(@ComSpec & " /K cmd /K < " & $sPipeName & @CRLF, "c:\") ; ok? (maybe a better way?)

_StdInPipeWrite("@echo off" & @CRLF)
MsgBox(0, "Debug", "Result: @error:" & @error & @TAB & "$hCMD:" & $hCMD & @CRLF & "now Send a command to the cmd via a NamedPipe")
_StdInPipeWrite("cls & @Echo. & Echo Hello from AutoIt & Echo ----------------- & @Echo." & @CRLF)

MsgBox(0, 'Debug', "further commands" & @CRLF & "now send command 'dir c:\windows'")
$sMessage = "Dir c:\windows" & @CRLF
_StdInPipeWrite($sMessage)

MsgBox(0, 'Debug', "send another command)" & @CRLF & "now send command 'cls & HELP'")
_StdInPipeWrite("cls & HELP" & @CRLF)

MsgBox(0, "Debug", "end of test")
ProcessClose($hCMD)

Func _StdInPipeWrite($sMessage)

    $sMessage = @CRLF & $sMessage ; <----------- Workaround

    ; ===============================================================================================================================
    ; This function writes a message to the pipe
    ; ===============================================================================================================================
    Local $iWritten, $iBuffer, $pBuffer, $tBuffer

    $iBuffer = StringLen($sMessage) + 1
    $tBuffer = DllStructCreate("char Text[" & $iBuffer & "]")
    $pBuffer = DllStructGetPtr($tBuffer)
    DllStructSetData($tBuffer, "Text", $sMessage)
    If Not _WinAPI_WriteFile( _
            $hPipe, _ ; ...... Handle to the file to be written
            $pBuffer, _ ; .... Pointer to the buffer containing the data to be written
            $iBuffer, _ ; .... Number of bytes to be written to the file
            $iWritten, _ ; ... The number of bytes written
            0 _ ; ............ [optional] A $tagOVERLAPPED structure or a pointer to it
            ) Then
        ConsoleWrite("WriteMsg: _WinAPI_WriteFile failed" & @CRLF & _WinAPI_GetLastErrorMessage())
    Else
        ConsoleWrite("WriteMsg: write OK" & @CRLF & _WinAPI_GetLastErrorMessage() & @CRLF)
    EndIf
EndFunc   ;==>_StdInPipeWrite

 

 

image.jpeg.9f1a974c98e9f77d824b358729b089b0.jpeg Chimp

small minds discuss people average minds discuss events great minds discuss ideas.... and use AutoIt....

Link to comment
Share on other sites

Hi, i was just playing with this, searching for the solution.

Then i saw your workaround, and then it clicked !

 

If you change the $iBuffer = StringLen($sMessage) + 1

and remove the +1, it should work. (from your 1st post)

 

Logical explanation:

Looks like the cmd is waiting for data, but got nothing, because the string length was too short.

Edited by Dan_555

Some of my script sourcecode

Link to comment
Share on other sites

Thanks @Dan_555 

Your explanation clarifies!
I was completely out of the way.
my hypothesis was due to the fact that among the different requests, on the cmd appears a string that says "Ancora?" that is the Italian word for "More?" hence my (incorrect) thesis. (Sometimes things are simpler than it seems)
Thanks a lot for your solution! 👍

Edited by Chimp

 

image.jpeg.9f1a974c98e9f77d824b358729b089b0.jpeg Chimp

small minds discuss people average minds discuss events great minds discuss ideas.... and use AutoIt....

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share

×
×
  • Create New...