Numeric Lotto Prediction help.

[mucitbey]

Hello friends.

How can I prevent the same number from being repetitive in this program. Thank you in advance for your help.

expandcollapse popup

#include <Array.au3>
#include <GuiConstants.au3>

Dim $Num[6]
Global $_Chck = False
Global $Gui = GUICreate("", 610, 170, -1,-1, $WS_POPUP+$WS_BORDER)
GUISetBkColor(0x3366FF)

Local $Genr = GUICtrlCreateButton("Generate Number", 10, 10, 300, 35)
GUICtrlSetFont(-1, 20, 800,  0, "Arial Narrow")

Local $Exit = GUICtrlCreateButton("CLOSE", 500, 10, 100, 35)
GUICtrlSetFont(-1, 20, 800,  0, "Arial Narrow")

Global $I[6]

For $N = 0 To 5
    $I[$N] = GUICtrlCreateInput("", 10 + 100 * ($N), 60, 90, 100, $ES_READONLY+$ES_CENTER)
    GUICtrlSetFont(-1, 70, 800,  0, "Arial Narrow")
Next
GUISetState()

While 1
    $Msg = GUIGetMsg()
    Select
        Case $Msg = -3 Or $Msg = $Exit
            Exit
        Case $Msg = $Genr
            If $_Chck = False Then
                $_Chck = True
            Else
                $_Chck = False
            EndIf
            If $_Chck = True Then
                GUICtrlSetData($Genr, 'STOP')
                AdlibRegister('_RandomNum', 10)
            EndIf
            If $_Chck = False Then
                GUICtrlSetData($Genr, 'Generate Number')
                _ArraySort($Num)
                For $N = 0 To 5
                    GUICtrlSetData($I[$N], $Num[$N])
                Next
                AdlibUnRegister('_RandomNum')
            EndIf
    EndSelect
WEnd

Func _RandomNum()
    For $N = 0 To 5
        $Num[$N] = Random(1, 90, 1)
        GUICtrlSetData($I[$N], $Num[$N])
    Next
EndFunc

[TheDcoder]

Use an array to store the currently generated numbers and check against it to make sure there are no duplicates.

[Nine]

Here a simple way :

Func _RandomNum()
  For $N = 0 To 5
    $Num[$N] = Random(1, 90, 1)
    For $C = 0 To 5
      If $C = $N Then ContinueLoop
      If $Num[$C] = $Num[$N] Then
        $N -= 1
        ;ConsoleWrite ("Found duplicate" & @CRLF)
        ContinueLoop 2
      EndIf
    Next
    GUICtrlSetData($I[$N], $Num[$N])
  Next
EndFunc   ;==>_RandomNum

 

[TheXman]

Another simple way:

#include <Array.au3>


_ArrayDisplay(lotto_numbers(), "Lotto Numbers")

Func lotto_numbers()
    Local $aAvailableNumbers[0], $aSelectedNumbers[0]
    Local $iRandomIndex

    ;Load available numbers
    For $i = 1 To 90
        _ArrayAdd($aAvailableNumbers, $i)
    Next

    ;Select 6 random, non-repeating, numbers from available numbers
    For $i = 1 To 6
        $iRandomIndex = Random(0, UBound($aAvailableNumbers) - 1, 1)    ;Random available number index
        _ArrayAdd($aSelectedNumbers, $aAvailableNumbers[$iRandomIndex]) ;Add available number to selected numbers
        _ArrayDelete($aAvailableNumbers, $iRandomIndex)                 ;Remove selected number from available numbers
    Next

    Return $aSelectedNumbers
EndFunc

 

Edited November 2, 2020 by TheXman

[mucitbey]

You're great #Nine, we thank you once again. 

Also thanks #TheXman for a different recommendation.

[jchd]

Another skin for this cat:

Local $N = 99
Local $a[$N]
For $i = 0 To $N - 1
    $a[$i] = $i + 1
Next

For $i = 1 To 8
    _ArrayShuffle($a)
    ; display 6 random numbers without dups
    ConsoleWrite(_ArrayToString($a, " ", 0, 5, " ") & @LF)
    Sleep(1000)
Next