Microsoft.XMLDOM selectSingleNode problem

[gykisz]

Hi Guys,

I would need the value of i4 from the attached xml file, but the selectSingleNode doesn't work for me.

Help, pls.

 

#include <Array.au3>

Enum $iData_NodeName, $iData_AttributeName, $iData_AttributeValue, $iData_UBound

$oXML = ObjCreate("Microsoft.XMLDOM")

If Not IsObj($oXML) Then
    MsgBox(0, "", "Unable to create COM session to XML.")
    Exit
EndIf

$oXML.Load(@ScriptDir & "\teszt.xml")

$oParent = $oXML.selectSingleNode('//methodResponse/params/param/value/struct/member[name =""Id""]/value/i4')

$aData = ""

$i = 0

For $oChild In $oParent.childNodes
    For $oAttribute In $oChild.attributes
        If IsArray($aData) Then
            ReDim $aData[UBound($aData) + 1][$iData_UBound]
        Else
            Local $aData[1][$iData_UBound]
        EndIf
        $aData[UBound($aData) - 1][$iData_NodeName] = $oChild.nodename
        $aData[UBound($aData) - 1][$iData_AttributeName] = $oAttribute.nodename
        $aData[UBound($aData) - 1][$iData_AttributeValue] = $oAttribute.text
        ConsoleWrite("NodeName=[" & $oChild.nodename & "]: AttributeName=[" & $oAttribute.nodename & "] AttributeValue=[" & $oAttribute.text & "]" & @CRLF)
    Next
    $i += 1
Next
_ArrayDisplay($aData, $i)

 

teszt.xml

[mikell]

Alternative way... for such a simple request it could be done like this

Msgbox(0,"", StringRegExp(FileRead("teszt.xml"), '<i4>([^<]+)', 1)[0] )

 

Edited February 14, 2021 by mikell
typo

[Nine]

Try this :

$oXML = ObjCreate("Microsoft.XMLDOM")
If Not IsObj($oXML) Then Exit MsgBox(0, "", "Unable to create COM session to XML.")
$oXML.Load("teszt.xml")
$oParent = $oXML.selectSingleNode('//struct/member[name="id"]/value/i4')
MsgBox ($MB_SYSTEMMODAL, "", $oParent.text)

 

Edited February 14, 2021 by Nine

[gykisz]

Thank you, guys!

Both solutions work great. Just another question, @Nine. This xml file is a result of an http query, but if I use it this way: $oXML.Load = $XmlHttp.responsetext, then it doesn't work. What could be the reason for this?

 

[Nine]

The .load method is getting a file.  To load a string you must use .loadXML method instead :

$oXML.loadXML($sXML)

 

[gykisz]

Thanks, it works great.