How to make window active that is a specific class and also has a specific window title?

[KDoc]

Hi,

Is there any way in Autoit to make a specific window active that is of a certain class AND has a specific title?   The reason is that I have multiple instances of windows of the same class  but different titles (captions) and I want a specific window to come to the front with a Autoit command. 

Thanks

Kris

[Nine]

See WinList using "Title Special Definition" class option.  You will get an array of all the windows with a very specific class.  Parse the array to find the exact title you are looking for.  It will give you a unique handle that you could use to bring the window in front.

[ad777]

@KDoc

WinActivate(_WinGetByTC("CalcFrame", "Calculator"));active window by title = Calculator & class=CalcFrame
Func _WinGetByTC($class, $title)
    Local $WIN = WinList("[CLASS:" & $class & "]")
    For $i = 0 To UBound($WIN)
        If $WIN[$i][1] <> "" Then
            If $title = WinGetTitle($WIN[$i][1]) Then
                Return $WIN[$i][1]
            EndIf
        EndIf
    Next
EndFunc   ;==>_WinGetByTC

 

Edited February 24, 2022 by ad777

[Nine]

Not quite.  WinList returns a 1-based array.  And there is no need to retrieve the title again since WinList already give it. Streamlined :

WinActivate(_WinGetByTC("CalcFrame", "Calculator"));active window by title = Calculator & class=CalcFrame
Func _WinGetByTC($class, $title)
    Local $WIN = WinList("[CLASS:" & $class & "]")
    For $i = 1 To $WIN[0][0]
        If $WIN[$i][0] = $title Then Return $WIN[$i][1]
    Next
EndFunc   ;==>_WinGetByTC

 

[dogisay]

Just?

WinActivate("[TITLE:Calculator; CLASS:CalcFrame]")