Shell Application Bar

[Nine]

I was wondering how to create an Application Bar that would be recognized by the system.  Searching on the forum here revealed that there was a few attempts of doing so but none was successful.  So here a working example of how to perform it.  Notice how maximized windows are shrunk by the application bar. 😎

expandcollapse popup

#NoTrayIcon
;#AutoIt3Wrapper_UseX64=y

#include <GUIConstants.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>
#include <TrayConstants.au3>

; #SHAppBarMessage# =============================================================================================================
; Name ..........: SHAppBarMessage.AU3
; Description ...: Create an Application Bar recognized by the system
; Author ........: Nine
; Created .......: 2025-04-04
; Modified ......:
; Remarks .......:
; Example .......: Yes
; ===============================================================================================================================

Opt("MustDeclareVars", True)
Opt("GUICloseOnESC", False)
Opt("TrayMenuMode", 1)
Opt("TrayAutoPause", 0)

Global Enum $ABM_NEW, $ABM_REMOVE, $ABM_QUERYPOS, $ABM_SETPOS, $ABM_GETSTATE, $ABM_GETTASKBARPOS, $ABM_ACTIVATE, $ABM_GETAUTOHIDEBAR, _
    $ABM_SETAUTOHIDEBAR, $ABM_WINDOWPOSCHANGED, $ABM_SETSTATE
Global Enum $ABS_ONTOP, $ABS_AUTOHIDE, $ABS_ALWAYSONTOP
Global Enum $ABE_LEFT, $ABE_TOP, $ABE_RIGHT, $ABE_BOTTOM

Global Enum $ABN_STATECHANGE, $ABN_POSCHANGED, $ABN_FULLSCREENAPP, $ABN_WINDOWARRANGE
Global Const $CALLBACK = $WM_USER + 0x10
Global Const $tagAPPBARDATA = "dword cbSize;hwnd hWnd;uint uCallbackMessage;uint uEdge;" & $tagRECT & ";lparam lParam"

Global $idDummy

Example()

Func Example()
  Local $tAppBarData = DllStructCreate($tagAPPBARDATA)
  $tAppBarData.cbSize = DllStructGetSize($tAppBarData)

  Local $hGUI = GUICreate("", 80, @DesktopHeight, 0, 0, $WS_POPUP, $WS_EX_TOOLWINDOW + $WS_EX_TOPMOST)
  GUISetBkColor(0x202020)
  GUISetFont(11, 0, 0, "Comic Sans MS")

  Local $idHide = GUICtrlCreateButton(" Hide", 5, 5, 70, 30)
  GUICtrlSetImage(-1, "shell32.dll", 200, 0)
  Local $idTask = GUICtrlCreateButton(" Task", 5, 40, 70, 30)
  GUICtrlSetImage(-1, "shell32.dll", 16739, 0)

  Local $idDo = GUICtrlCreateButton(" Do", 5, 75, 70, 30)
  GUICtrlSetImage(-1, "shell32.dll", 16802, 0)
  Local $idDont = GUICtrlCreateButton(" Don't", 5, 110, 70, 30)
  GUICtrlSetImage(-1, "shell32.dll", 240, 0)

  Local $idExit = GUICtrlCreateButton(" Exit", 5, 300, 70, 30)
  GUICtrlSetImage(-1, "shell32.dll", 290, 0)

  $tAppBarData.hWnd = $hGUI
  $tAppBarData.uCallbackMessage = $CALLBACK
  DllCall("shell32.dll", "int", "SHAppBarMessage", "dword", $ABM_NEW, "struct*", $tAppBarData)
  AppBarSetPos($tAppBarData)

  GUIRegisterMsg($CALLBACK, AppBarProc)
  GUISetState()

  $idDummy = GUICtrlCreateDummy()

  While True
    Switch GUIGetMsg()
      Case $idExit
        ExitLoop
      Case $idDummy
        AppBarSetPos($tAppBarData)
      Case $idHide
        GUISetState(@SW_HIDE)
        DllCall("shell32.dll", "int", "SHAppBarMessage", "dword", $ABM_REMOVE, "struct*", $tAppBarData)
        TraySetIcon("shell32.dll", 255)
        TraySetState($TRAY_ICONSTATE_SHOW)
        TraySetToolTip("Left click to restore" & @CRLF & "Right click to Exit")
      Case $idTask
        ToggleTaskBar()
    EndSwitch
    Switch TrayGetMsg()
      Case $TRAY_EVENT_PRIMARYDOWN
        GUISetState(@SW_SHOW)
        DllCall("shell32.dll", "int", "SHAppBarMessage", "dword", $ABM_NEW, "struct*", $tAppBarData)
        AppBarSetPos($tAppBarData)
        TraySetState($TRAY_ICONSTATE_HIDE)
      Case $TRAY_EVENT_SECONDARYUP
        Exit
    EndSwitch
  WEnd

  DllCall("shell32.dll", "int", "SHAppBarMessage", "dword", $ABM_REMOVE, "struct*", $tAppBarData)
EndFunc   ;==>Example

Func AppBarSetPos(ByRef $tAppBar)
  $tAppBar.uEdge = $ABE_LEFT
  $tAppBar.left = 0
  $tAppBar.top = 0
  $tAppBar.Right = 80
  $tAppBar.Bottom = @DesktopHeight

  DllCall("shell32.dll", "int", "SHAppBarMessage", "dword", $ABM_QUERYPOS, "struct*", $tAppBar)
  DllCall("shell32.dll", "int", "SHAppBarMessage", "dword", $ABM_SETPOS, "struct*", $tAppBar)

  WinMove($tAppBar.hWnd, "", $tAppBar.Left, $tAppBar.Top, $tAppBar.Right, $tAppBar.Bottom)
EndFunc   ;==>AppBarSetPos

Func ToggleTaskBar()
  Local $tAppBar = DllStructCreate($tagAPPBARDATA)
  $tAppBar.cbSize = DllStructGetSize($tAppBar)
  Local $iState = DllCall("shell32.dll", "int", "SHAppBarMessage", "dword", $ABM_GETSTATE, "struct*", $tAppBar)[0]
  $tAppBar.lParam = $iState = $ABS_AUTOHIDE ? $ABS_ALWAYSONTOP : $ABS_AUTOHIDE
  DllCall("shell32.dll", "int", "SHAppBarMessage", "dword", $ABM_SETSTATE, "struct*", $tAppBar)
EndFunc   ;==>ToggleTaskBar

Func AppBarProc($hWnd, $iMsg, $wParam, $lParam)
  If $wParam = $ABN_POSCHANGED Then GUICtrlSendToDummy($idDummy, $wParam)
  Return $GUI_RUNDEFMSG
EndFunc   ;==>AppBarProc

 

Edited April 4 by Nine

[Parsix]

Very Nice, Thank you 😍

[Nine]

Glad you like it  

[Parsix]

If the program crashes for any reason, the separated empty section will remain. Then, when the program is run again, the program code will ignore the separated section and display the program bar on the remaining section. ?!!!!!

 

 

 

 

Spoiler

 

Edited yesterday at 11:49 AM by Parsix

[Nine]

@Parsix

Try replacing the beginning of the example function with this :

Func Example()
  Local $tAppBarData = DllStructCreate($tagAPPBARDATA)
  $tAppBarData.cbSize = DllStructGetSize($tAppBarData)

  If WinExists("SHAppBarMessage") Then RunWait('TaskKill /PID ' & WinGetProcess("SHAppBarMessage") & ' /F', '', @SW_HIDE)
  Local $hGUI = GUICreate("SHAppBarMessage", 80, @DesktopHeight, 0, 0, $WS_POPUP, $WS_EX_TOOLWINDOW + $WS_EX_TOPMOST)

Works well for me...

[Parsix]

2 hours ago, Nine said:

@Parsix

Try replacing the beginning of the example function with this :

Func Example()
  Local $tAppBarData = DllStructCreate($tagAPPBARDATA)
  $tAppBarData.cbSize = DllStructGetSize($tAppBarData)

  If WinExists("SHAppBarMessage") Then RunWait('TaskKill /PID ' & WinGetProcess("SHAppBarMessage") & ' /F', '', @SW_HIDE)
  Local $hGUI = GUICreate("SHAppBarMessage", 80, @DesktopHeight, 0, 0, $WS_POPUP, $WS_EX_TOOLWINDOW + $WS_EX_TOPMOST)

Works well for me...

not work

"SHAppBarMessage" It has been closed abruptly before and there is no window with the above name.

As shown in the image, when the program is run again, the form will appear after the cropped bar because x=0 is the previous cropped area for it.

A solution must be found to recover the partitioned area, especially when the program closes due to an unknown error without properly executing the exit commands.

 

for test :

I compiled the program and then ran it, so far everything is fine

To test the program, I ended the task from the Windows task manager, when I run the program again, the program behaves like the picture in the previous post

[Nine]

16 minutes ago, Parsix said:

for test :

I compiled the program and then ran it, so far everything is fine

To test the program, I ended the task from the Windows task manager, when I run the program again, the program behaves like the picture in the previous post

It seems to be a bug in Windows 10 (I was able to reproduce the issue).  In Windows 11, the bad behavior has disappeared, as it is working correctly now.  At this stage, I have no idea how to recuperate the lost region.

[Parsix]

this func recover it ?

GUIRegisterMsg($CALLBACK, AppBarProc)

[Nine]

What do you mean ?

If the app crashes, nothing can recuperate the region, beside Windows itself, unless I am missing something...