Consolewrite problem

[MrCal]

On 9/6/2019 at 10:00 AM, jchd said:

I use this to be able to write to console in any case (compiled or not):

Global $CW = @Compiled ? __ConsoleWrite : _ConsoleWrite

Func __ConsoleWrite(ByRef $s)
    Local Static $hCon = __ConsoleInit()
    DllCall("kernel32.dll", "bool", "WriteConsoleW", "handle", $hCon, "wstr", $s & @LF, "dword", StringLen($s) + 1, "dword*", 0, "ptr", 0)
    Return
EndFunc   ;==>__ConsoleWrite

Func __ConsoleInit()
    DllCall("kernel32.dll", "bool", "AllocConsole")
    Return DllCall("kernel32.dll", "handle", "GetStdHandle", "int", -11)[0]
EndFunc   ;==>__ConsoleInit

; Unicode-aware ConsoleWrite
Func _ConsoleWrite($s)
    ConsoleWrite(BinaryToString(StringToBinary($s & @LF, 4), 1))
EndFunc   ;==>_ConsoleWrite

I setup the SciTE console to Unicode, so that's why the last function is needed.

Use it like that:

$CW("some text" & @LF)

I'm trying to send a ESC character to the console using you function but I get the error "Expected a variable in user function call."

$color = Chr(27) & '[31m'
$CW($color & "some text" & @LF)

Do you have solution for this?

[Melba23]

MrCal,

Please do not hijack 5 yr old threads - just start a new one as I have done for you.

M23

[Nine]

Remove the ByRef, but do not expect colors to be displayed...

[jchd]

12 hours ago, MrCal said:

$color = Chr(27) & '[31m'
$CW($color & "some text" & @LF)

My fault: there was an extra $  there. CW is a function not a variable!

$color = Chr(27) & '[31m'
$CW($color & "some text" & @LF)

Original post fixed. was correct!

Edited Monday at 08:47 PM by jchd

[Nine]

36 minutes ago, jchd said:

CW is a function not a variable!

Yes it is !  A variable containing a function...

[Nine]

Here a working way to print colors in console with WriteConsole API.  It seems the culprit is AllocConsole which does not provide the feature.  I also added a way to ControlSend a command to the console.

#include <WinAPIProc.au3>

If Not @Compiled Then Exit MsgBox($MB_OK, "Error", "This script must be runned compiled")

Local $iPID = Run(@ComSpec & " /k @echo off & echo " & Chr(27) & "[31mRed")
ProcessWait($iPID)
_WinAPI_AttachConsole($iPID)
Local $hCon = _WinAPI_GetStdHandle(1)
Local $sText = Chr(27) & "[33mYellow" & @CRLF
_WinAPI_WriteConsole($hCon, $sText)

Local $hWnd = WinGetHandle(@ComSpec)
ControlSend($hWnd, "", "", "echo " & "^{^}[32mGreen" & @CRLF)  ; <<<<<< depends on keyboard (could be ^[ for english KB)

Sleep(2000)
DllCall("kernel32.dll", "bool", "FreeConsole")
ProcessClose($iPID)

Note that you can start the exe from Explorer.

ps. I must admit I spend way too many hours figuring what was the right ESC character to send

Edited Monday at 09:55 PM by Nine

[jchd]

5 hours ago, Nine said:

Yes it is !  A variable containing a function...

Sorry folks, I didn't realize this was an old version of the code I use daily now.