Low-Polygon Maker v0.60 build 2026-02-13

[UEZ]

I enhanced the Delaunay function in my _GDIPlus_BitmapApplyFilter Dll and created a front-end GUI to generate Low-Polygon images:

 

Code:

expandcollapse popup

;Coded by UEZ v0.60 build 2026-02-13
;Requires 3.3.15.0+ version
#AutoIt3Wrapper_Version=p
#AutoIt3Wrapper_UseX64=y
#AutoIt3Wrapper_Res_HiDpi=y

#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <ScreenCapture.au3>
#include <StaticConstants.au3>
#include <WinAPIGdi.au3>
#include <WindowsConstants.au3>
#include "_GDIPlus_BitmapApplyFilter.au3"


Global Const $hDLL = _GDIPlus_BitmapApplyFilter_Open()

Global Const $hGUI = GUICreate("Low-Polygon Maker v0.60", 252, 716, 4, 150, -1, $WS_EX_TOPMOST)
GUISetFont(8, 400, 0, "Consolas")
GUISetBkColor(0xABCDEF, $hGUI)

Global $aRet = _GDIPlus_BitmapCreateVerticalText("Coded by UEZ 2026", 21.75, "Consolas", 0x380000FF, 1)
Global Const $iPic_Label = GUICtrlCreatePic("", 204, 88, $aRet[1], $aRet[2])
_WinAPI_DeleteObject(GUICtrlSendMsg($iPic_Label, $STM_SETIMAGE, $IMAGE_BITMAP, $aRet[0]))

Global Const $iLbl_Title = GUICtrlCreateLabel("Low-Polygon Maker", 0, 8, 238, 32, $SS_CENTER)
GUICtrlSetFont(-1, 18, 400, 0, "Consolas")
Global Const $iLbl_EdgeDetection = GUICtrlCreateLabel("Edge Detection", 4, 58, 88, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")
Global Const $iCombo_EdgeDetection = GUICtrlCreateCombo("", 96, 56, 145, 25, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL))
GUICtrlSetFont(-1, 10, 400, 0, "Consolas")
GUICtrlSetData($iCombo_EdgeDetection, "SOBEL|" & _
                                      "SCHARR|" & _
                                      "PREWITT|" & _
                                      "FREI_CHEN|" & _
                                      "ROBERTS_CROSS|" & _
                                      "ROBINSON_COMPASS|" & _
                                      "KAYYALI|" & _
                                      "RIDGE_DETECTION|" & _
                                      "DIAGONAL_EDGES|" & _
                                      "SOVELVSPREWITT|" & _
                                      "OUTLINE3X3|" & _
                                      "LAPLACE3x3_1|" & _
                                      "LAPLACE3x3_2|" & _
                                      "LAPLACE5x5|" & _
                                      "EDGE_DETECTION1|" & _
                                      "EDGE_DETECTION2|" & _
                                      "EDGE_DETECTION3|" & _
                                      "EDGE_DETECTION4|" & _
                                      "EDGE_DETECTION5|" & _
                                      "EMBOSS1|" & _
                                      "EMBOSS2|" & _
                                      "EMBOSS3|" & _
                                      "EMBOSS4|" & _
                                      "KIRSCH|" & _
                                      "ISOTROPIC_SOBEL", _
                                      "DIAGONAL_EDGES")
Global $iInp_x = 96, $iInp_w = 100
Global Const $iLbl_Threshold = GUICtrlCreateLabel("ED Threshold", 4, 96, 76, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")
Global Const $iInp_Threshold = GUICtrlCreateInput(0.35, $iInp_x, 92, $iInp_w, 21)
GUICtrlSetFont(-1, 10, 400, 0, "Consolas")
Global Const $iLbl_Blur = GUICtrlCreateLabel("Blur Level", 4, 128, 64, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")
Global Const $iInp_Blur = GUICtrlCreateInput(4, $iInp_x, 124, $iInp_w, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_NUMBER))
GUICtrlSetFont(-1, 10, 400, 0, "Consolas")
Global Const $iLbl_Colors = GUICtrlCreateLabel("Max. Colors", 4, 160, 70, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")
Global Const $iInp_Colors = GUICtrlCreateInput(32, $iInp_x, 156, $iInp_w, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_NUMBER))
GUICtrlSetFont(-1, 10, 400, 0, "Consolas")
Global Const $iLbl_MinSpace = GUICtrlCreateLabel("Min Space", 4, 192, 58, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")
Global Const $iInp_MinSpace = GUICtrlCreateInput(4, $iInp_x, 188, $iInp_w, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_NUMBER))
GUICtrlSetFont(-1, 10, 400, 0, "Consolas")
Global Const $iLbl_MaxSpace = GUICtrlCreateLabel("Max Space", 4, 224, 58, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")
Global Const $iInp_MaxSpace = GUICtrlCreateInput(8, $iInp_x, 220, $iInp_w, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_NUMBER))
GUICtrlSetFont(-1, 10, 400, 0, "Consolas")
Global Const $iLbl_BorderSpaceX = GUICtrlCreateLabel("Border Space X", 4, 256, 88, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")
Global Const $iInp_BorderSpaceX = GUICtrlCreateInput(2, $iInp_x, 252, $iInp_w, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_NUMBER))
GUICtrlSetFont(-1, 10, 400, 0, "Consolas")
Global Const $iLbl_BorderSpaceY = GUICtrlCreateLabel("Border Space Y", 4, 288, 88, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")
Global Const $iInp_BorderSpaceY = GUICtrlCreateInput(2, $iInp_x, 284, $iInp_w, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_NUMBER))
GUICtrlSetFont(-1, 10, 400, 0, "Consolas")
Global Const $iLbl_Alpha = GUICtrlCreateLabel("Edges Alpha", 4, 320, 70, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")
Global Const $iInp_Alpha = GUICtrlCreateInput(32, $iInp_x, 316, $iInp_w, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_NUMBER))
GUICtrlSetFont(-1, 10, 400, 0, "Consolas")
Global Const $iLbl_PosterizeLvl = GUICtrlCreateLabel("Posterize Lvl", 4, 352, 80, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")
Global Const $iInp_PosterizeLvl = GUICtrlCreateInput(8, $iInp_x, 348, $iInp_w, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_NUMBER))
GUICtrlSetFont(-1, 10, 400, 0, "Consolas")
GUICtrlSetTip(-1, "When the posterization level is set, the value for “Max. Colors” is ignored.")

Global Const $iChkB_ShowEdges = GUICtrlCreateCheckbox("Show Edges", 4, 386, 233, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")
GUICtrlSetState(-1, $GUI_CHECKED)
Global Const $iChkB_Wireframe = GUICtrlCreateCheckbox("Show Wireframes only", 4, 414, 233, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")
Global Const $iChkB_GIFAnim = GUICtrlCreateCheckbox("Convert all GIF frames", 4, 442, 233, 17)
GUICtrlSetFont(-1, 8.5, 400, 0, "Consolas")

Global Const $iBtn_Apply = GUICtrlCreateButton("&Apply", 8, 476, 235, 57)
GUICtrlSetFont(-1, 12, 400, 0, "Consolas")
GUICtrlSetBkColor(-1, 0xCCCCFF)
Global Const $iBtn_Load = GUICtrlCreateButton("&Load Image", 8, 548, 235, 57)
GUICtrlSetFont(-1, 12, 400, 0, "Consolas")
GUICtrlSetBkColor(-1, 0xCCCCFF)
Global Const $iBtn_Save = GUICtrlCreateButton("&Save Image", 8, 620, 235, 57)
GUICtrlSetFont(-1, 12, 400, 0, "Consolas")
GUICtrlSetBkColor(-1, 0xCCCCFF)

Global $aParts[1] = [-1]
Global Const $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aParts, "Ready")
Local $hFont = _WinAPI_CreateFont(12, 0, 0, 0, $FW_MEDIUM, False, False, False, $DEFAULT_CHARSET, $OUT_DEFAULT_PRECIS, $CLIP_DEFAULT_PRECIS, $DRAFT_QUALITY, 0, "Segoe UI")
_WinAPI_SetFont($hStatusBar, $hFont, True)

GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_COMMAND, '_WM_COMMAND')

Global $aMsg, $hImage, $sImgFile, $hGUI_Display = 0, $hGDI_LowPoly, $sFileLowPoly
ConsoleWrite("Screen: " & @DesktopWidth & "x" & @DesktopHeight & @CRLF)

Dim $aFrameDelays[1], $aFramesGDI[1], $aFrames_LowPoly[1]
Global $iCurrentFrame = 0, $iAnimFrameCount = 0, $bIsGIF, $iPic_LowPoly, $iSeed, $i

While 1
    $aMsg = GUIGetMsg(1)
    Switch $aMsg[1]
        Case $hGUI
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    AdlibUnRegister("PlayGIFAnimPreview")
                    GUIDelete($hGUI)
                    If UBound($aFrameDelays) Then
                        For $i = 0 To UBound($aFrameDelays) - 1 
                            _WinAPI_DeleteObject($aFramesGDI[$i])
                            _GDIPlus_ImageDispose($aFrames_LowPoly[$i + 1])
                        Next
                    EndIf
                    _GDIPlus_BitmapApplyFilter_Close()
                    Exit
                Case $iBtn_Load
                    $sImgFile = FileOpenDialog("Select a GDI+ supported image", "", "Images (*.bmp;*.gif;*.png;*.jpg;*.tif)", $FD_FILEMUSTEXIST, "", $hGUI)
                    If @error Then ContinueLoop
                    If Not FileExists($sImgFile) Then
                        MsgBox($MB_ICONERROR, "Error", $sImgFile & " doesn't exist", 30)
                        ContinueLoop
                    EndIf
                    If $hImage Then _GDIPlus_ImageDispose($hImage)
                    $hImage = _GDIPlus_ImageLoadFromFile($sImgFile)
                    If Not $hImage Then
                        MsgBox($MB_ICONERROR, "Error", "Unable to load file to GDI+", 30)
                        ContinueLoop
                    EndIf
                    $bIsGIF = False
                    If StringRight($sImgFile, 4) = ".gif" Then $bIsGIF = True
                    $iSeed = Int(Random() * 0xFFFFFF)
                    $iCurrentFrame = 0
                    $iAnimFrameCount = 0
                    EncodeAndDisplay($hImage)
                Case $iBtn_Save
                    If $sImgFile = "" Or ($bIsGIF ? UBound($aFrames_LowPoly) < 2 : $hGDI_LowPoly = 0) Then ContinueLoop
                    $sFileLowPoly = FileSaveDialog("Save Low-Polygone Image", "", "Images (*.bmp;*.gif;*.png;*.jp?g;*.tif?)", 0, StringRegExpReplace($sImgFile, "^.*\\([^\\]+)(\.[^.]+)$", "\1_Low-Polygon\2"), $hGUI)
                    If @error Or $sFileLowPoly = "" Then ContinueLoop
                    If ((UBound($aFrames_LowPoly) > 1 And $bIsGIF) ? _GDIPlus_GIFAnimCreateFile2($aFrames_LowPoly, $sFileLowPoly, $aFrameDelays) : _ScreenCapture_SaveImage($sFileLowPoly, $hGDI_LowPoly, False)) Then
                        MsgBox($MB_ICONINFORMATION, "Information", "Low-Poly image saved.", 15, $hGUI)
                    Else
                        MsgBox($MB_ICONERROR, "Error", "Low-Poly image could not be save!", 15, $hGUI)
                    EndIf
                Case $iBtn_Apply
                    If $sImgFile = "" Or $hImage = 0 Then ContinueLoop
                    GUICtrlSetState($iBtn_Apply, $GUI_DISABLE)
                    EncodeAndDisplay($hImage)
                    GUICtrlSetState($iBtn_Apply, $GUI_ENABLE)
            EndSwitch
        Case $hGUI_Display
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    AdlibUnRegister("PlayGIFAnimPreview")
                    GUIDelete($hGUI_Display)
                    $hGUI_Display = 0
            EndSwitch
    EndSwitch
WEnd

Func Min($a, $b)
    Return $a < $b ? $a : $b
EndFunc

Func EncodeAndDisplay($hImage, $ResizeinGUI = True)
    Local $iW = _GDIPlus_ImageGetWidth($hImage), $iH = _GDIPlus_ImageGetHeight($hImage)
    If $iW = 0 Or $iH = 0 Then Return SetError(1, 0, 0)
    
    Local $iMode = 0, $fScaleX, $fScaleY, $fFactor = 0.925
    ConsoleWrite("Original: " & $iW & "x" & $iH & @CRLF)
    
    If $ResizeinGUI Then
        If $iH > @DesktopHeight And $iW < @DesktopWidth + 1 Then
            $fScaleY = @DesktopHeight / $iH
            $iW *= $fScaleY
            $iH *= $fScaleY
            $iMode = 1
        ElseIf $iH < @DesktopHeight + 1 And $iW > @DesktopWidth Then
            $fScaleX = @DesktopWidth / $iW
            $iW *= $fScaleX
            $iH *= $fScaleX
            $iMode = 2
        ElseIf $iH > @DesktopHeight And $iW > @DesktopWidth Then
            If $iH > $iW Then
                $fScaleY = @DesktopHeight / $iH
                $iH *= $fScaleY
                $iW *= $fScaleY
            Else
                $fScaleX = @DesktopWidth / $iW
                $iH *= $fScaleX
                $iW *= $fScaleX
            EndIf
            $iMode = 3
        EndIf
        If $iMode Then
            $iW *= $fFactor
            $iH *= $fFactor
        EndIf
    EndIf

    ConsoleWrite("Display: " & Int($iW) & "x" & Int($iH) & @CRLF)
    
    Static $iWp = 0, $iHp = 0
    If $iW <> $iWp Or $iH <> $iHp Then
        If $hGUI_Display Then GUIDelete($hGUI_Display)
        $hGUI_Display = GUICreate("", $iW, $iH, -1, -1, $WS_POPUP, $WS_EX_OVERLAPPEDWINDOW)
        $iPic_LowPoly = GUICtrlCreatePic("", 0, 0, $iW - 1, $iH - 1)
        GUISetState(@SW_SHOWNA, $hGUI_Display)
    EndIf
    $iWp = $iW
    $iHp = $iH

    If $hGDI_LowPoly Then _WinAPI_DeleteObject($hGDI_LowPoly)
    $hGDI_LowPoly = 0

;~ ConsoleWrite("Blur level: " & Number(GUICtrlRead($iInp_Blur)) & @CRLF & _
;~           "Kernel: " & Execute("$" & GUICtrlRead($iCombo_EdgeDetection)) & @CRLF & _
;~           "Threshold: " & Number(GUICtrlRead($iInp_Threshold), $NUMBER_DOUBLE) & @CRLF & _
;~           "Amount of Colors: " & Number(GUICtrlRead($iInp_Colors)) & @CRLF & _
;~           "Min Space: " & Number(GUICtrlRead($iInp_MinSpace)) & @CRLF & _
;~           "Max Space: " & Number(GUICtrlRead($iInp_MaxSpace)) & @CRLF & _
;~           "Border Space X: " & Number(GUICtrlRead($iInp_BorderSpaceX)) & @CRLF & _
;~           "Border Space Y: " & Number(GUICtrlRead($iInp_BorderSpaceY)) & @CRLF & _
;~           "Show Edges Checked: " & Int(BitAND(GUICtrlRead($iChkB_ShowEdges), $GUI_CHECKED) = $GUI_CHECKED) & @CRLF & _
;~           "Alpha Value: " & Number(GUICtrlRead($iInp_Alpha)) & @CRLF & _
;~           "Wireframe Checked: " & Int(BitAND(GUICtrlRead($iChkB_Wireframe), $GUI_CHECKED) = $GUI_CHECKED) & @CRLF & _
;~           "Posterize level: " & Number(GUICtrlRead($iInp_PosterizeLvl)) & @CRLF & _
;~           "GIF Mode Checked: " & Int(BitAND(GUICtrlRead($iChkB_GIFAnim), $GUI_CHECKED) = $GUI_CHECKED) & @CRLF)
;~ ConsoleWrite("-----------------------------------------------------------------------" & @CRLF)
    
    AdlibUnRegister("PlayGIFAnimPreview")
    Local $i
    Local Const $iAnimDimCount = _GDIPlus_GIFAnimGetFrameDimensionsCount($hImage)
    Local Const $tGUID = _GDIPlus_GIFAnimGetFrameDimensionsList($hImage, $iAnimDimCount)
    $iAnimFrameCount =  _GDIPlus_GIFAnimGetFrameCount($hImage, $tGUID)
    $aFrameDelays = _GDIPlus_GIFAnimGetFrameDelays($hImage, $iAnimFrameCount)
    Local Const $fTimer = TimerInit()
    If Int(BitAND(GUICtrlRead($iChkB_GIFAnim), $GUI_CHECKED) = $GUI_CHECKED) And $bIsGIF And $iAnimFrameCount > 1 Then
        If UBound($aFramesGDI) > 1 Then
            For $i = 0 To UBound($aFramesGDI) - 1 
                _WinAPI_DeleteObject($aFramesGDI[$i])
                _GDIPlus_ImageDispose($aFrames_LowPoly[$i + 1])
            Next
        EndIf
        ReDim $aFramesGDI[$iAnimFrameCount]
        ReDim $aFrames_LowPoly[$iAnimFrameCount + 1]
        $aFrames_LowPoly[0] = $iAnimFrameCount
        For $i = 0 To $iAnimFrameCount - 1
            _GDIPlus_GIFAnimSelectActiveFrame($hImage, $tGUID, $i)
            $aFrames_LowPoly[$i + 1] = _GDIPlus_BitmapApplyFilter_Delaunay3($hImage, Number(GUICtrlRead($iInp_Blur)), _
                                                                            Execute("$" & GUICtrlRead($iCombo_EdgeDetection)), _
                                                                            Number(GUICtrlRead($iInp_Threshold), $NUMBER_DOUBLE), _
                                                                            Number(GUICtrlRead($iInp_Colors)), _
                                                                            Number(GUICtrlRead($iInp_MinSpace)), _
                                                                            Number(GUICtrlRead($iInp_MaxSpace)), _
                                                                            Number(GUICtrlRead($iInp_BorderSpaceX)), _
                                                                            Number(GUICtrlRead($iInp_BorderSpaceY)), _
                                                                            Int(BitAND(GUICtrlRead($iChkB_ShowEdges), $GUI_CHECKED) = $GUI_CHECKED), _
                                                                            Number(GUICtrlRead($iInp_Alpha)), _
                                                                            Int(BitAND(GUICtrlRead($iChkB_Wireframe), $GUI_CHECKED) = $GUI_CHECKED), _
                                                                            Number(GUICtrlRead($iInp_PosterizeLvl)), _
                                                                            $iSeed, _
                                                                            0xFFFFFFFF, _
                                                                            False)
            $aFramesGDI[$i] = _GDIPlus_BitmapCreateHBITMAPFromBitmap($aFrames_LowPoly[$i + 1])
            _GDIPlus_BitmapConvertTo8Bit($aFrames_LowPoly[$i + 1], 256, $GDIP_DitherTypeNone, $GDIP_PaletteTypeFixedHalftone256)
            ToolTip($i + 1 & "/" & $iAnimFrameCount & " : " & Round(($i + 1) / UBound($aFrameDelays) * 100, 2) & "%", MouseGetPos(0), MouseGetPos(1) + 30, "", 0, $TIP_CENTER)
        Next
        ToolTip("")
        AdlibRegister("PlayGIFAnimPreview", 10)
    Else
        $hGDI_LowPoly = _GDIPlus_BitmapApplyFilter_Delaunay3($hImage, Number(GUICtrlRead($iInp_Blur)), _
                                                             Execute("$" & GUICtrlRead($iCombo_EdgeDetection)), _
                                                             Number(GUICtrlRead($iInp_Threshold), $NUMBER_DOUBLE), _
                                                             Number(GUICtrlRead($iInp_Colors)), _
                                                             Number(GUICtrlRead($iInp_MinSpace)), _
                                                             Number(GUICtrlRead($iInp_MaxSpace)), _
                                                             Number(GUICtrlRead($iInp_BorderSpaceX)), _
                                                             Number(GUICtrlRead($iInp_BorderSpaceY)), _
                                                             Int(BitAND(GUICtrlRead($iChkB_ShowEdges), $GUI_CHECKED) = $GUI_CHECKED), _
                                                             Number(GUICtrlRead($iInp_Alpha)), _
                                                             Int(BitAND(GUICtrlRead($iChkB_Wireframe), $GUI_CHECKED) = $GUI_CHECKED), _
                                                             Number(GUICtrlRead($iInp_PosterizeLvl)), _
                                                             $iSeed, _
                                                             0, _
                                                             True)
        If $hGDI_LowPoly = 0 Then
            GUIDelete($hGUI_Display)
            $hGUI_Display = 0
            Return SetError(1, 0, 0)
        EndIf
        If $iMode Then ResizeImage($hGDI_LowPoly, $iW, $iH)
    
        Local $hHBmp = GUICtrlSendMsg($iPic_LowPoly, $STM_SETIMAGE, $IMAGE_BITMAP, $hGDI_LowPoly)
        If $hHBmp Then _WinAPI_DeleteObject($hHBmp)
    EndIf

    _GUICtrlStatusBar_SetText($hStatusBar, "Generated in: " & Round(TimerDiff($fTimer), 2) & " ms. Dimension: " & _GDIPlus_ImageGetWidth($hImage) & "x" & _GDIPlus_ImageGetHeight($hImage), 0, $SBT_POPOUT)
    
    _WinAPI_InvalidateRect($hGUI_Display)
    _WinAPI_RedrawWindow($hGUI_Display)
EndFunc   ;==>EncodeAndDisplay

Func PlayGIFAnimPreview()
    AdlibUnRegister("PlayGIFAnimPreview")
    Local $iDelay = $aFrameDelays[$iCurrentFrame]
    Local Static $iTimerCurrentFrame = TimerInit()
    _WinAPI_DeleteObject(GUICtrlSendMsg($iPic_LowPoly, 0x0172 , 0, $aFramesGDI[$iCurrentFrame])) ;$STM_SETIMAGE = 0x0172, $IMAGE_BITMAP = 0
    If TimerDiff($iTimerCurrentFrame) > $iDelay Then
        $iCurrentFrame += 1
        $iTimerCurrentFrame = TimerInit()
    EndIf
    If $iCurrentFrame > UBound($aFrameDelays) - 1 Then $iCurrentFrame = 0
    AdlibRegister("PlayGIFAnimPreview", 10)
EndFunc   ;==>PlayGIFAnimPreview

Func ResizeImage(ByRef $hBitmapGDI, $newW, $newH)
    Local $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmapGDI)
    Local $hImageResized = _GDIPlus_ImageResize($hImage, $newW, $newH)
    _WinAPI_DeleteObject($hBitmapGDI)
    $hBitmapGDI = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImageResized, 0)
    _GDIPlus_ImageDispose($hImageResized)
EndFunc

Func _WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $iNotifyCode = BitShift($wParam, 16)
    Local $iCtrlID = BitAND($wParam, 0x0000FFFF)
    Local $var
    If $iNotifyCode = $EN_KILLFOCUS Then
        Switch $iCtrlID
            Case $iInp_Blur
                $val = GUICtrlRead($iInp_Blur)
                If $val = "" Then $val = 4
                $val = Number($val)
                If $val < 1 Then $val = 1
                If $val > 127 Then $val = 127
                GUICtrlSetData($iInp_Blur, $val)

            Case $iInp_Threshold
                $val = GUICtrlRead($iInp_Threshold)
                If $val = "" Then $val = 0.35
                $val = Number($val)
                If $val < 0 Then $val = 0
                If $val > 10 Then $val = 10
                GUICtrlSetData($iInp_Threshold, StringFormat("%.2f", $val))

            Case $iInp_Colors
                $val = GUICtrlRead($iInp_Colors)
                If $val = "" Then $val = 32
                $val = Number($val)
                If $val < 2 Then $val = 2
                If $val > 255 Then $val = 255
                GUICtrlSetData($iInp_Colors, $val)

            Case $iInp_MinSpace
                $val = GUICtrlRead($iInp_MinSpace)
                If $val = "" Then $val = 3
                $val = Number($val)
                If $val < 1 Then $val = 1
                GUICtrlSetData($iInp_MinSpace, $val)

            Case $iInp_MaxSpace
                $val = GUICtrlRead($iInp_MaxSpace)
                If $val = "" Then $val = 8
                $val = Number($val)
                If $val < 1 Then $val = 1
                GUICtrlSetData($iInp_MaxSpace, $val)

            Case $iInp_BorderSpaceX, $iInp_BorderSpaceY
                $val = GUICtrlRead($iCtrlID)
                If $val = "" Then $val = 2
                $val = Number($val)
                If $val < 1 Then $val = 1
                If $val > 255 Then $val = 255
                GUICtrlSetData($iCtrlID, $val)

            Case $iInp_Alpha
                $val = GUICtrlRead($iInp_Alpha)
                If $val = "" Then $val = 32
                $val = Number($val)
                If $val < 0 Then $val = 0
                If $val > 255 Then $val = 255
                GUICtrlSetData($iInp_Alpha, $val)

            Case $iInp_PosterizeLvl
                $val = GUICtrlRead($iInp_PosterizeLvl)
                If $val = "" Then $val = 8
                $val = Number($val)
                If $val < 0 Then $val = 0
                If $val > 255 Then $val = 255
                GUICtrlSetData($iInp_PosterizeLvl, $val)

        EndSwitch
    EndIf

    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_COMMAND

Func _GDIPlus_BitmapCreateVerticalText($sString, $fFontSize = 10, $sFont = "Arial", $iColor_Text = 0xFF000000, $iFlip = 3)
    $iFlip = $iFlip <> 3 Or $iFlip <> 1 ? 3 : $iFlip
    Local Const $hDC = _WinAPI_GetWindowDC(0)
    Local Const $hGraphic = _GDIPlus_GraphicsCreateFromHDC($hDC)
    Local Const $hBrush = _GDIPlus_BrushCreateSolid($iColor_Text)
    Local Const $hFormat = _GDIPlus_StringFormatCreate()
    Local Const $hFamily = _GDIPlus_FontFamilyCreate($sFont)
    Local Const $hFont = _GDIPlus_FontCreate($hFamily, $fFontSize)
    Local $tLayout = _GDIPlus_RectFCreate()
    Local Const $aInfo = _GDIPlus_GraphicsMeasureString($hGraphic, $sString, $hFont, $tLayout, $hFormat)
    Local $iError = 1
    If Not @error Then
        Local Const $iW = Ceiling($aInfo[0].Width), $iH = Ceiling($aInfo[0].Height)
        Local Const $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH), $hCanvas = _GDIPlus_ImageGetGraphicsContext($hBitmap)
        _GDIPlus_GraphicsSetSmoothingMode($hCanvas, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
        _GDIPlus_GraphicsSetTextRenderingHint($hCanvas, $GDIP_TEXTRENDERINGHINTANTIALIASGRIDFIT)
        $tLayout.X = 0
        $tLayout.Y = 0
        $tLayout.Width = $iW
        $tLayout.Height = $iH
        _GDIPlus_GraphicsDrawStringEx($hCanvas, $sString, $hFont, $tLayout, $hFormat, $hBrush)
        _GDIPlus_ImageRotateFlip($hBitmap, $iFlip)
        Local Const $hBitmap_GDI = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
        _GDIPlus_GraphicsDispose($hCanvas)
        _GDIPlus_BitmapDispose($hBitmap)
        $iError = 0
    EndIf
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _WinAPI_ReleaseDC(0, $hDC)
    If $iError Then Return SetError(1, 0, 0)
    Local $aResult[3] = [$hBitmap_GDI, $iH, $iW]
    Return $aResult
EndFunc   ;==>_GDIPlus_BitmapCreateVerticalText

;_GDIPlus_GIFAnim* function taken from _GDIPlus_GIFAnim UDF
Func _GDIPlus_GIFAnimGetFrameDimensionsCount($hImage)
    Local Const $aResult = DllCall($__g_hGDIPDll, "int", "GdipImageGetFrameDimensionsCount", "handle", $hImage, "ulong*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)
    Return $aResult[2]
EndFunc   ;==>_GDIPlus_GIFAnimGetFrameDimensionsCount

Func _GDIPlus_GIFAnimGetFrameDimensionsList($hImage, $iFramesCount)
    Local Const $tGUID = DllStructCreate($tagGUID)
    Local Const $aResult = DllCall($__g_hGDIPDll, "int", "GdipImageGetFrameDimensionsList", "handle", $hImage, "struct*", $tGUID, "uint", $iFramesCount)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)
    Return $tGUID
EndFunc   ;==>_GDIPlus_GIFAnimGetFrameDimensionsList

Func _GDIPlus_GIFAnimGetFrameCount($hImage, $tGUID)
    Local Const $aResult = DllCall($__g_hGDIPDll, "int", "GdipImageGetFrameCount", "handle", $hImage, "struct*", $tGUID, "ptr*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)
    Return Int($aResult[3])
EndFunc   ;==>_GDIPlus_GIFAnimGetFrameCount

Func _GDIPlus_GIFAnimSelectActiveFrame($hImage, $tGUID, $iCurrentFrame)
    Local Const $aResult = DllCall($__g_hGDIPDll, "int", "GdipImageSelectActiveFrame", "handle", $hImage, "struct*", $tGUID, "uint", $iCurrentFrame)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)
    Return True
EndFunc   ;==>_GDIPlus_GIFAnimSelectActiveFrame

Func _GDIPlus_GIFAnimGetFrameDelays($hImage, $iAnimFrameCount)
    If $iAnimFrameCount < 2 Then Return SetError(1, 0, 0)
    Local Const $GDIP_PROPERTYTAGFRAMEDELAY = 0x5100
    Local $tPropItem = __GDIPlus_ImageGetPropertyItem($hImage, $GDIP_PROPERTYTAGFRAMEDELAY)
    If IsDllStruct($tPropItem) And (Not @error) Then
        Local $iType = $tPropItem.type, $iLength, $tVal
        If $iType Then
            $iLength = $tPropItem.length
            Switch $iType
                Case 1
                    $tVal = DllStructCreate("byte delay[" & $iLength & "]", $tPropItem.value)
                Case 3
                    $tVal = DllStructCreate("short delay[" & Ceiling($iLength / 2) & "]", $tPropItem.value)
                Case 4
                    $tVal = DllStructCreate("long delay[" & Ceiling($iLength / 4) & "]", $tPropItem.value)
                Case Else
                    Return SetError(3, 0, 0)
            EndSwitch
            Local $aFrameDelays[Int($iAnimFrameCount)], $i
            For $i = 0 To UBound($aFrameDelays) - 1
                $aFrameDelays[$i] = $tVal.delay(($i + 1)) * 10
            Next
        EndIf
        Return $aFrameDelays
    EndIf
    Return SetError(2, 0, 0)
EndFunc   ;==>_GDIPlus_GIFAnimGetFrameDelays

Func __GDIPlus_ImageGetPropertyItem($hImage, $iPropID)
    Local $aResult = DllCall($__g_hGDIPDll, "int", "GdipGetPropertyItemSize", "handle", $hImage, "uint", $iPropID, "ulong*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)
    Local Static $tBuffer
    $tBuffer = DllStructCreate("byte[" & $aResult[3] & "]")
    $aResult = DllCall($__g_hGDIPDll, "int", "GdipGetPropertyItem", "handle", $hImage, "uint", $iPropID, "ulong", $aResult[3], "struct*", $tBuffer)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(11, $aResult[0], 0)
    Local Const $tagGDIPPROPERTYITEM = "uint id;ulong length;word type;ptr value"
    Local $tPropertyItem = DllStructCreate($tagGDIPPROPERTYITEM, DllStructGetPtr($tBuffer))
    If @error Then Return SetError(20, $aResult[0], 0)
    Return $tPropertyItem
EndFunc   ;==>__GDIPlus_ImageGetPropertyItem

Func _GDIPlus_GIFAnimCreateFile2($aImages, $sFilename, $aDelays = 100, $bReplay = True)
    Local Const $GDIP_EVTFrameDimensionTime = 21
    Local $iMax = $aImages[0]
    If $iMax < 1 Then Return SetError(1, 0, False)
    Local Const $sCLSID = _GDIPlus_EncodersGetCLSID("GIF")
    Local $tMultiFrameParam = DllStructCreate("int type;")
    $tMultiFrameParam.type = 18
    Local $tParams = _GDIPlus_ParamInit(1)
    _GDIPlus_ParamAdd($tParams, $GDIP_EPGSAVEFLAG, 1, 4, DllStructGetPtr($tMultiFrameParam))
    Local Const $hStream = _WinAPI_CreateStreamOnHGlobal()
    Local $tGUID = _WinAPI_GUIDFromString($sCLSID)
    _GDIPlus_ImageSaveToStream($aImages[1], $hStream, DllStructGetPtr($tGUID), DllStructGetPtr($tParams))
    If $iMax > 1 Then
        $tMultiFrameParam.type = $GDIP_EVTFrameDimensionTime
        $tParams = _GDIPlus_ParamInit(1)
        _GDIPlus_ParamAdd($tParams, $GDIP_EPGSAVEFLAG, 1, 4, DllStructGetPtr($tMultiFrameParam))
        For $i = 2 To $iMax
            _GDIPlus_ImageSaveAddImage($aImages[1], $aImages[$i], $tParams)
        Next
        $tMultiFrameParam.type = 19
        $tParams = _GDIPlus_ParamInit(1)
        _GDIPlus_ParamAdd($tParams, $GDIP_EPGSAVEFLAG, 1, 4, DllStructGetPtr($tMultiFrameParam))
        _GDIPlus_ImageSaveAdd($aImages[1], $tParams)
    EndIf
    $tMultiFrameParam.type = 20
    $tParams = _GDIPlus_ParamInit(1)
    _GDIPlus_ParamAdd($tParams, $GDIP_EPGSAVEFLAG, 1, 4, DllStructGetPtr($tMultiFrameParam))
    _GDIPlus_ImageSaveAdd($aImages[1], $tParams)
    Local Const $hMemory = _WinAPI_GetHGlobalFromStream($hStream)
    Local Const $iMemSize = _MemGlobalSize($hMemory)
    Local Const $pMem = _MemGlobalLock($hMemory)
    Local Const $iNewSize = $bReplay ? ($iMemSize + 19) : $iMemSize
    Local Const $hNewMem = _MemGlobalAlloc($iNewSize, 0x0002)
    Local Const $pNewMem = _MemGlobalLock($hNewMem)
    Local $tNewData = DllStructCreate("byte mem[" & $iNewSize & "]", $pNewMem)
    Local Const $hDLL_msvcrt = DllOpen("msvcrt.dll")
    Local $iCopyOffset = 0
    If $bReplay Then
        Local $tNetscape = DllStructCreate("byte mem[19]")
        $tNetscape.mem = Binary("0x21FF0B4E45545343415045322E300301000000")
        Local $aResult = DllCall($hDLL_msvcrt, "ptr:cdecl", "memchr", "ptr", $pMem, "int", 0x21, "ulong_ptr", $iMemSize)
        If @error Or Not IsArray($aResult) Then
            _MemGlobalUnlock($hMemory)
            _MemGlobalUnlock($hNewMem)
            _MemGlobalFree($hNewMem)
            _WinAPI_ReleaseStream($hStream)
            DllClose($hDLL_msvcrt)
            Return SetError(3, 0, False)
        EndIf
        Local $pFound = $aResult[0], $tCheck, $iInsertPos
        While $pFound <> 0
            $tCheck = DllStructCreate("byte mem[3]", $pFound)
            If $tCheck.mem(1) = 0x21 And $tCheck.mem(2) = 0xF9 And $tCheck.mem(3) = 0x04 Then
                $iInsertPos = $pFound - $pMem
                DllCall($hDLL_msvcrt, "ptr:cdecl", "memcpy", "ptr", $pNewMem, "ptr", $pMem, "ulong_ptr", $iInsertPos)
                DllCall($hDLL_msvcrt, "ptr:cdecl", "memcpy", "ptr", $pNewMem + $iInsertPos, "struct*", $tNetscape, "ulong_ptr", 19)
                DllCall($hDLL_msvcrt, "ptr:cdecl", "memcpy", "ptr", $pNewMem + $iInsertPos + 19, "ptr", $pMem + $iInsertPos, "ulong_ptr", $iMemSize - $iInsertPos)
                $iCopyOffset = 19
                ExitLoop
            EndIf
            $aResult = DllCall($hDLL_msvcrt, "ptr:cdecl", "memchr", "ptr", $pFound + 1, "int", 0x21, "ulong_ptr", $iMemSize - ($pFound - $pMem) - 1)
            $pFound = $aResult[0]
        WEnd
    Else
        DllCall($hDLL_msvcrt, "ptr:cdecl", "memcpy", "ptr", $pNewMem, "ptr", $pMem, "ulong_ptr", $iMemSize)
    EndIf
    _MemGlobalUnlock($hMemory)
    _WinAPI_ReleaseStream($hStream)
    _MemGlobalFree($hMemory)
    Local $pSearch = $pNewMem
    Local $iRemainingByte = $iNewSize
    Local $iFrameCount = 0, $iDelay, $aResult, $pFound, $tCheck, $isArray = IsArray($aDelays)
    While $iFrameCount < $iMax And $iRemainingByte > 6
        $aResult = DllCall($hDLL_msvcrt, "ptr:cdecl", "memchr", "ptr", $pSearch, "int", 0x21, "ulong_ptr", $iRemainingByte)
        If $aResult[0] = 0 Then ExitLoop
        $pFound = $aResult[0]
        $tCheck = DllStructCreate("byte mem[6]", $pFound)
        If $tCheck.mem(2) = 0xF9 And $tCheck.mem(3) = 0x04 Then
            $iDelay = $isArray ? $aDelays[$iFrameCount] : $aDelays
            $iDelay = Int($iDelay / 10)
            $tCheck.mem(5) = BitAND($iDelay, 0xFF)
            $tCheck.mem(6) = BitShift($iDelay, 8)
            $iFrameCount += 1
            $pSearch = $pFound + 8
        Else
            $pSearch = $pFound + 1
        EndIf
        $iRemainingByte = $iNewSize - ($pSearch - $pNewMem)
    WEnd
    DllClose($hDLL_msvcrt)
    Local $hFile = FileOpen($sFilename, BitOR(16, 2))
    If $hFile = -1 Then
        _MemGlobalUnlock($hNewMem)
        _MemGlobalFree($hNewMem)
        Return SetError(2, 0, False)
    EndIf
    FileWrite($hFile, $tNewData.mem)
    FileClose($hFile)
    _MemGlobalUnlock($hNewMem)
    _MemGlobalFree($hNewMem)
    Return True
EndFunc   ;==>_GDIPlus_GIFAnimCreateFile2

Func _GDIPlus_BitmapConvertTo8Bit(ByRef $hBitmap, $iColorCount = 256, $iDitherType = 9, $iPaletteType = 8, $bUseTransparentColor = True)
    $iColorCount = ($iColorCount > 2 ^ 8) ? 2 ^ 8 : $iColorCount
    Local $tPalette = _GDIPlus_PaletteInitialize(256, $iPaletteType, $iColorCount, $bUseTransparentColor, $hBitmap)
    If @error Then Return SetError(1, @error, 0)
    Local $iRet = _GDIPlus_BitmapConvertFormat($hBitmap, 0x00030803, $iDitherType, $iPaletteType, $tPalette)
    If @error Then Return SetError(2, @error, 0)
    Return $iRet
EndFunc   ;==>_GDIPlus_BitmapConvertTo8Bit

 

Examples:

 

 

The required DLLs (_GDIPlus_BitmapApplyFilter.dll / _GDIPlus_BitmapApplyFilter_x64.dll) and  _GDIPlus_BitmapApplyFilter.au3 can be found on my OneDrive: _GDIPlus_BitmapApplyFilter

 

Edited 9 hours ago by UEZ
Update