output error message contains garbled characters

[haijie1223]

When the path contains Chinese, the output error message contains garbled characters. How can I solve this?

In the attachment, run test.au3 and you can see the garbled characters in 1.txt.

test.7z

[argumentum]

the files does have a duplicate function name, but that is not the problem for you. Your problem is how it looks in the console no displaying the characters in your SciTE editor that is not even from this site, right ?

Ok, so the redirect also gives the ?? instead of the characters.

No clue 🤷‍♂️

Edited Thursday at 05:36 AM by argumentum
🤷‍♂️

[haijie1223]

21 minutes ago, argumentum said:

the files does have a duplicate function name, but that is not the problem for you. Your problem is how it looks in the console no displaying the characters in your SciTE editor that is not even from this site, right ?

Ok, so the redirect also gives the ?? instead of the characters.

No clue 🤷‍♂️

yes，it is.

[ioa747]

#include <AutoItConstants.au3>
#include <FileConstants.au3>

; Define files
Local $scriptFile = "测试.au3"
Local $logFile = "1.txt"

Local $pid = Run('"' & @AutoItExe & '" /ErrorStdOut "' & $scriptFile & '"', @ScriptDir, @SW_HIDE, $STDOUT_CHILD + $STDERR_CHILD)

ProcessWaitClose($pid)

Local $output = StdoutRead($pid) & StderrRead($pid)
FileWrite($logFile, $output)

ShellExecute($logFile)

1.txt

"D:\_Test\??.au3" (4) : ==> Duplicate function name.:
Func test()

 

Edited Thursday at 05:41 PM by ioa747
add 1.txt

[haijie1223]

@ioa747   测试.au3 set any errors，then logs  contains garbled characters。

[argumentum]

..then is not a forum solution that you need but a bug report. And is better that you doit yourself because I'll never use that language and you can do a follow up on it

Edited Thursday at 01:44 PM by argumentum
added link

[Nine]

That works well :

#include <FileConstants.au3>

Local $scriptFile = "测试.au3"
Local $logFile = "1.txt"
Local $pid = ShellExecute($scriptFile)
ProcessWait($pid)
Local $hWnd = WinGetHandle("AutoIt Error")
Local $sText = ControlGetText($hWnd, "", "Static2")
WinClose($hWnd)
Local $hFile = FileOpen($logFile, $FO_OVERWRITE + $FO_UTF8)
FileWrite($hFile, $sText)
FileClose($hFile)

 

[ioa747]

I can't solve the problem, I can only overcome it.

Local $originalFile = "测试.au3"
Local $tempFile = "temp_syntax_check.au3"
Local $logFile = "1.txt"

FileCopy($originalFile, $tempFile, 1)

Local $pid = Run('"' & @AutoItExe & '" /ErrorStdOut "' & $tempFile & '"', @ScriptDir, @SW_HIDE, 8) ; $STDERR_MERGED
ProcessWaitClose($pid)
Local $output = StdoutRead($pid) & StderrRead($pid)

$output = StringReplace($output, $tempFile, $originalFile)

Local $hFile = FileOpen($logFile, 2 + 128) ; $FO_OVERWRITE + $FO_UTF8
FileWrite($hFile, $output)
FileClose($hFile)

FileDelete($tempFile)
ShellExecute('notepad.exe', $logFile)

1.txt

"D:\_Test\测试.au3" (4) : ==> Duplicate function name.:
Func test()

alternative

Local $scriptFile = "测试.au3"
Local $logFile = "1.txt"

; Run Au3Check - It's designed for exactly this job
Local $pid = Run('"' & StringReplace(@AutoItExe, "AutoIt3.exe", "Au3Check.exe") & '" "' & $scriptFile & '"', @ScriptDir, @SW_HIDE, 8) ; $STDERR_MERGED

ProcessWaitClose($pid)
Local $output = StdoutRead($pid) & StderrRead($pid)

; Write the output
Local $hFile = FileOpen($logFile, 2 + 128)  ; $FO_OVERWRITE + $FO_UTF8
FileWrite($hFile, $output)
FileClose($hFile)

ShellExecute($logFile)

1.txt

AutoIt3 Syntax Checker v3.3.18.0  Copyright (c) 2007-2025 Tylo & AutoIt Team

"测试.au3"(4,12) : error: test() already defined.
Func test()
~~~~~~~~~~~^
测试.au3 - 1 error(s), 0 warning(s)

 

Edited Thursday at 05:42 PM by ioa747