Cool Text Client

[GaryFrost]

Works great till an error occurs..... had to kill the script at that point, got tired of hitting ok on the error messages.

Might want to exit out after the error message.

[Valuater]

1

Appears to use the new IE.au3 T2.0... but not standardized throughout the script

sorry, my bad... lol

@frost... notice the toolbar comand... I use that all the time now

8)

Edited May 5, 2006 by Valuater

[RazerM]

Yes i'll fo that gafrost.

@Valuater

I just downloaded the new IE.au3 today and it works for me. I named it IE.au3 just so you know. (Dale named it something like IE T2.0 on his post)

[Valuater]

Yes i'll fo that gafrost.

@Valuater

I just downloaded the new IE.au3 today and it works for me. I named it IE.au3 just so you know. (Dale named it something like IE T2.0 on his post)

got it... sorry, i have the old

8)

[RazerM]

it's ok. I thought i'd messed up because you aren't a noob that gets things wrong

@gafrost

It now exits on error

Edited May 5, 2006 by RazerM

[onlee]

GuiCombo.au3 ?

[ludocus]

dude you brought up an old topic...

Edited June 18, 2009 by ludocus

[wakillon]

@RazerM

I was interested by your Topic, but there is no updated working version...

So I modified a little bit.

expandcollapse popup

;===============================================================================
;
; Program Name: CoolText Client
; Description:: Uses www.cooltext.com to generate images
; Requirement(s):  AutoIt Beta
; Author(s):    RazerM
;
;===============================================================================
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIConstants.au3>
#include <GuiCombobox.au3>
#include <GDIPlus.au3>
#Include <WinAPI.au3>
#include <file.au3>
#include <IE.au3>

Global $_Ext, $_TextRead, $hGUI, $hImage, $hGraphic, $hImage1,$_PngFilePath = @TempDir & '\logo.png'
If Not FileExists ( $_PngFilePath ) Then InetGet ( "http://mob0.com/ct/logo.png", $_PngFilePath, 1 )
$styles = "3D Outline Gradient|3D Outline Textured|Alien Glow|Animated Glow|Blended|Bovinated|Burning|Carved|Chalk|Chrome One|Chrome Two|Comic|Cool Metal" & _
"|Crystal|Cutout|Embossed|Felt|Fire|Glossy|Glowing Hot|Glowing Steel|Gradient Bevel|Neon|Nova|Old Stone|Outline|Pixel Badge|Simple|Slab|Starburst|Textured"

$hGUI       = GUICreate ( "CoolText Client", 600, 200 )
              GUICtrlCreateLabel ( "Style:", 10, 73 )
$style      = GUICtrlCreateCombo ( "3D Outline Gradient", 60, 70, 130 )
              GUICtrlSetData ( $style, $styles )
            GUICtrlCreateLabel ( "Text:", 200, 73 )
$_Input     = GUICtrlCreateInput ( "", 230, 70, 350 )
            GUICtrlCreateLabel ( "Text Size:", 10, 103 )
$_Inputsize = GUICtrlCreateInput ( 70, 60, 110, 65 )
            GUICtrlCreateLabel ( "File Format:", 170, 103 )
$format     = GUICtrlCreateCombo ( "", 230, 110, 240 )
              GUICtrlSetData ( $format, ".GIF|.GIF with Transparency|.GIF with Transparency, No Dither|.JPG|.PNG|.PNG with Transparency (Not supported in IE)", ".PNG" );|.PSD (Photoshop with Layers)", ".PNG")
$render     = GUICtrlCreateButton ( "Render", 10, 160, 580, 25 )
            _GDIPlus_StartUp ( )
$hImage    = _GDIPlus_ImageLoadFromFile ( $_PngFilePath )
$hGraphic  = _GDIPlus_GraphicsCreateFromHWND ( $hGUI )
            GUIRegisterMsg ( $WM_PAINT, "MY_WM_PAINT" )
              GUISetState ( )
            

While 1
    Switch GUIGetMsg ( )
        Case $GUI_EVENT_CLOSE
            _GDIPlus_GraphicsDispose ( $hGraphic )
            _GDIPlus_ImageDispose ( $hImage )
            _GDIPlus_ShutDown ( )
            Exit
        Case $render
            $_TextRead = GUICtrlRead ( $_Input )
            $_SelectedFormat = GUICtrlRead ( $format )
            $_Ext = StringLeft ( $_SelectedFormat, 4 ) ;            
            If $_TextRead Then _Render ( GUICtrlRead ( $style ), $_TextRead, GUICtrlRead ( $_Inputsize ), _GUICtrlComboBox_GetCurSel ( $format )+1 )
    EndSwitch
WEnd

Func _Render ( $style, $s_text, $i_size, $i_file )
    GUICtrlSetState ( $render, $GUI_DISABLE )
    $ie = _IECreate ( "http://www.cooltext.com", 0, 0 )
    _IELoadWait ( $ie )
    If $style = "Textured" Then _IEImgClick ( $ie, $style, "alt", 1, 1 )
    If $style <> "Textured" Then _IEImgClick ( $ie, $style, "alt", 0, 1 )
    $form = _IEFormGetObjByIndex ( $ie, 0 )
    $text = _IEFormElementGetObjByName ( $form, "Text" )
    _IEFormElementSetValue ( $text, $s_text )
    $size = _IEFormElementGetObjByName ( $form, "FontSize" )
    _IEFormElementSetValue ( $size, $i_size )
    $fileformat = _IEFormElementGetObjByName ( $form, "FileFormat" )
    _IEFormElementSetValue ( $fileformat, $i_file )
    $_document= $form.document
    $Inputs = _IETagNameGetCollection ( $_document, "input" )
    For $Input in $Inputs
        If String ( $Input.value ) = "Render Logo" Then 
            $Input.click
            ExitLoop
        EndIf
    Next
    Do
        Sleep ( 100 )
    Until _IEPropertyGet ( $ie, "locationname" ) = "Cool Text: Generated Image"
    $url = _IEPropertyGet ( $ie, "locationurl" )
    $code = StringRight ( $url, 8 )
    $ext = StringLeft ( GUICtrlRead ( $format ), 4 )
    $_document = $ie.document
    $imgs = _IETagNameGetCollection ( $_document, "img" )
    For $img In $imgs
        $url = $img.src
        $imgfile = $img.nameProp
        If StringInStr ( $url, $code ) And StringInStr ( $imgfile, "cooltext" ) Then
            _IEQuit ( $ie )
            $_FreePath = _GetFreePath ( @DesktopDir & '\' & $_TextRead & $_Ext )
            INetGet ( $url, $_FreePath, 1, 0 )
            GUICtrlSetState ( $render, $GUI_ENABLE )
            ShellExecute ( $_FreePath )
            Return 
        EndIf
    Next
EndFunc ;==> _Render ( )

Func _IEFormGetObjByIndex ( $o_object, $i_index )
    If IsObj ( $o_object.document.forms.item ( $i_index ) ) Then
        SetError ( 0 )
        Return $o_object.document.forms.item ( $i_index )
    Else
        SetError ( 1 )
        Return 0
    EndIf
EndFunc ;==> _IEFormGetObjByIndex ( )

Func _GetFreePath ( $_FilePath )
    Local $_N 
    Do
        $_NewPath = _InsertStringBeetweenNameAndExt ( $_FilePath, $_N )
        $_N = $_N + 1
    Until Not FileExists ( $_NewPath )  
    Return $_NewPath
EndFunc ;==> _GetFreePath ( )

Func _InsertStringBeetweenNameAndExt ( $_FullPath, $_InsertString )
    Local $szDrive, $szDir, $szFName, $szExt
    $_TestPath = _PathSplit ( $_FullPath, $szDrive, $szDir, $szFName, $szExt )
    Return $szDrive & $szDir & $szFName & $_InsertString & $szExt
EndFunc ;==> _InsertStringBeetweenNameAndExt ( )

Func MY_WM_PAINT ( $hWnd, $Msg, $wParam, $lParam )
    _WinAPI_RedrawWindow ( $hGUI, 0, 0, $RDW_UPDATENOW )
    _GDIPlus_GraphicsDrawImage ( $hGraphic, $hImage, 0, 0 )
    _WinAPI_RedrawWindow ( $hGUI, 0, 0, $RDW_VALIDATE )
    Return $GUI_RUNDEFMSG
EndFunc

If someone is interested...

There is 3 new styles and I have removed error function, i was tired by error messages...

Edited October 2, 2010 by wakillon