how to move a link in desktop [SOLVED]

[theAutoitSpammer]

I want to move a link in my desktop from one place to another.

can somebody point me in the right direction?

Al

Edited May 4, 2009 by alram

[Valuater]

http://www.autoitscript.com/autoit3/docs/f...ns/FileMove.htm

8)

[theAutoitSpammer]

  Valuater said:

http://www.autoitscript.com/autoit3/docs/f...ns/FileMove.htm

8)

I'm sorry I should said "within the desktop" (change the position coordinates)

in pixels from (x,y) to (x1,y1)

How do I select and drag it without knowing the original position

[Melba23]

alram,

This was a lot easier than I thought it would be - once I found that the DeskTop is a ListView! So the normal Autoit commands work on the icons - which are ListViewItems within the DeskTop.

This simple script will move the 'Recycle Bin' icon and then replace it:

#Include <GuiListView.au3>
#include <Array.au3>

; Get desktop handle
$hDeskTop = ControlGetHandle( "Program Manager", "", "SysListView321" )

; Save the listview items (icons) data to an array
Global $aIcons[_GUICtrlListView_GetItemCount($hDeskTop)][3]
For $i = 0 to _GUICtrlListView_GetItemCount($hDeskTop) - 1
    ; Name
    $aIcons[$i][0] = _GUICtrlListView_GetItemText($hDeskTop, $i)
    $aPos = _GUICtrlListView_GetItemPosition($hDeskTop, $i)
    ; Left
    $aIcons[$i][1] = $aPos[0]
    ; Top
    $aIcons[$i][2] = $aPos[1]
Next

; Show the icons and their positions
_ArrayDisplay($aIcons)

; Look for the Recycle Bin and get its index
$iIndex = _ArraySearch($aIcons, "Recycle Bin")

; Save its current position
$iOld_X = $aIcons[$iIndex][1]
$iOld_Y = $aIcons[$iIndex][2]

; Move it to a new position
MsgBox(64, "Moving the Recycle Bin icon",  "Press OK when ready to move!")
_GUICtrlListView_SetItemPosition($hDeskTop, $iIndex, 500, 500)

; Wait a bit
Sleep(5000)
; And move it back
_GUICtrlListView_SetItemPosition($hDeskTop, $iIndex, $iOld_X, $iOld_Y)

Over to you now.... :-)

M23

[Yashied]

Melba23, excelent example.

5+

[Melba23]

Yashied,

Spasiba.

M23

[Yashied]

  Melba23 said:

Yashied,

Spasiba.

M23

Correction: Spasibo

[theAutoitSpammer]

Thanks Melba

it works but the funny thing is that I was messing arround with the

same functions before and I couldn't get them to work.

I'll have to study your script and find my error. Thanks again

Al