set image transparent WinSetTrans??

[epicfail]

hi i have a slider in my script to change the transparent of my gui with WinSetTrans but how would i make it so that it only sets the transparent of the background image not the other images?

[PsaltyDS]

hi i have a slider in my script to change the transparent of my gui with WinSetTrans but how would i make it so that it only sets the transparent of the background image not the other images?

Try some experiments with _WinAPI_SetLayeredWindowAttributes(). See help file.

[Yashied]

Look at _WinAPI_AlphaBlend() from WinAPIEx.au3.

[epicfail]

the prob with _WinAPI_AlphaBlend() is that i still want to be able to see the other screens under my gui when i use the transparent thing but with _WinAPI_AlphaBlend() it makes it so u see the gray gui

[epicfail]

i cant find _WinAPI_SetLayeredWindowAttributes() in the help file

[martin]

i cant find _WinAPI_SetLayeredWindowAttributes() in the help file

You need the latest Beta version or search the forums where you will find many copies of the function.

[epicfail]

i dont think they do what i want tho

[Yashied]

#Include <GUIConstantsEx.au3>
#Include <WindowsConstants.au3>
#Include <WinAPIEx.au3>

$hForm = GUICreate('', 800, 600, -1, -1, $WS_POPUP)
GUICtrlCreatePic(@WindowsDir & '\Web\Wallpaper\Ascent.jpg', 0, 0, 800, 600, -1, $GUI_WS_EX_PARENTDRAG)

$hMain = GUICreate('', 800, 600, -1, -1, $WS_POPUP, $WS_EX_LAYERED, $hForm)
GUISetBkColor(0xABABAB)
GUICtrlCreateButton('OK', 365, 560, 70, 23)
GUICtrlCreateEdit('', 40, 40, 720, 503)

_WinAPI_SetLayeredWindowAttributes($hMain, 0xABABAB, 0, $LWA_COLORKEY)

GUIRegisterMsg($WM_MOVE, 'WM_MOVE')

WinSetTrans($hForm, '', 127)

GUISetState(@SW_SHOW, $hForm)
GUISetState(@SW_SHOW, $hMain)

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func WM_MOVE($hWnd, $iMsg, $wParam, $lParam)
    WinMove($hMain, '', BitAND($lParam, 0xFFFF), BitShift($lParam, 16))
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_MOVE

[Yashied]

epicfail, you could say thanks or something.

[PsaltyDS]

epicfail, you could say thanks or something.

Well, I liked your script!

Two minor changes though:

1. Requires standard WinAPI.au3 from Beta, not WinAPIEx.au3

2. $GUI_EVENT_CLOSE can't be used because there's not 'X' window control visible.

This runs (Beta) with the include fixed and the button used to close it:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

$hForm = GUICreate('', 800, 600, -1, -1, $WS_POPUP)
GUICtrlCreatePic(@WindowsDir & '\Web\Wallpaper\Ascent.jpg', 0, 0, 800, 600, -1, $GUI_WS_EX_PARENTDRAG)

$hMain = GUICreate('', 800, 600, -1, -1, $WS_POPUP, $WS_EX_LAYERED, $hForm)
GUISetBkColor(0xABABAB)
$ctrlButton = GUICtrlCreateButton('CLOSE', 365, 560, 70, 23)
GUICtrlCreateEdit('', 40, 40, 720, 503)

_WinAPI_SetLayeredWindowAttributes($hMain, 0xABABAB, 0, $LWA_COLORKEY)

GUIRegisterMsg($WM_MOVE, 'WM_MOVE')

WinSetTrans($hForm, '', 127)

GUISetState(@SW_SHOW, $hForm)
GUISetState(@SW_SHOW, $hMain)

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $ctrlButton
            Exit
    EndSwitch
WEnd

Func WM_MOVE($hWnd, $iMsg, $wParam, $lParam)
    WinMove($hMain, '', BitAND($lParam, 0xFFFF), BitShift($lParam, 16))
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_MOVE

[Yashied]

Two minor changes though:

1. Requires standard WinAPI.au3 from Beta, not WinAPIEx.au3

2. $GUI_EVENT_CLOSE can't be used because there's not 'X' window control visible.

1. As I understood the OP does not work in Beta.

2. $GUI_EVENT_CLOSE also works when you press the ESC key (it just example).

[epicfail]

how can i say thanks when im asleep? anyway thanks guys will try them out