String Split

[FinalVersion]

I've read the documentation and it didn't really help me that much. Any basically say if I have..

fistname:joe
lastname:smith

firstname:john
lastname:howard

I know how to get the information from a textfile, the hard part it splitting it up. Basically I'd like it in an array ( if possible ) like $name[1] would containt joe smith and $name[2] would contain john howard, anyway thanks.

[water]

You need something like:

#include <Array.au3>
#include <File.au3>

Global $asInFile
Global $asOutArray[1] = [0]
Global $iOutCount = 0

_FileReadToArray("C:\temp\test.txt",$asInFile)

For $i = 1 To $asInFile[0]
    $asSplit = StringSplit($asInFile[$i],":")
    If @error <> 1 Then
        If $asSplit[1] = "firstname" Then 
            ReDim $asOutArray[UBound($asOutArray)+1]
            $iOutCount = $iOutCount + 1
            $asOutArray[$iOutCount] = $asSplit[2]
        EndIf
        If $asSplit[1] = "lastname" Then 
            $asOutArray[$iOutCount] = $asOutArray[$iOutCount] & " " & $asSplit[2]
        EndIf
    EndIf
Next
$asOutArray[0] = UBound($asOutArray)-1
_ArrayDisplay($asOutArray)

Edited October 23, 2009 by water

[FinalVersion]

Thanks, but what if i got the text via _IEBodyReadText, how would I convert that into the array to start the string manipulation. Sorry, should of put this in my first post.

[Authenticity]

You need to show a sample of the format because otherwise it can be in any form such as lastname comes before firstname or there is something between them and what not.

#include <Array.au3>

Local $avMatch
Local $sText = "firstname:joe" & @CRLF & _
               "lastname:smith" & @CRLF & @CRLF & _
               "firstname:john" & @CRLF & _
               "lastname:howard"


$avMatch = StringRegExp($sText, "(?i)firstname:([^\r\n]*)\r\nlastname:([^\r\n]*)", 3)
If IsArray($avMatch) Then
    Local $avNames[UBound($avMatch)/2][2]
    
    For $i = 0 To (UBound($avMatch)/2) Step 2
        $avNames[$i/2][0] = $avMatch[$i]
        $avNames[$i/2][1] = $avMatch[$i+1]
    Next
    _ArrayDisplay($avNames)
EndIf

[FinalVersion]

Ok.

Couple paragraphs or so of text up here.

And some more, down here.

firstname:joe
lastname:smith

firstname:jack
lastname:johnson

and the list goes on. I'm getting this from _IEBodyReadText if you didn't know.