Sign in to follow this  
Followers 0
tobi2006

Get style from Gui control

5 posts in this topic

Hello AutoIt users,

I need a function that retrieves the style from gui control.

For gui there is a function (GUIGetStyle)

But there's not something like: GUICtrlGetStyle

Is there a function like that or did anyone a function like that...?

Yours,

Tobi

Share this post


Link to post
Share on other sites



tobi2006,

Here you go: ;)

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <StaticConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$hButton = GUICtrlCreateButton("Test", 10, 10, 80, 30, $BS_MULTILINE, $WS_EX_CLIENTEDGE)
$hButton_Handle = GUICtrlGetHandle($hButton)

$hLabel = GUICtrlCreateLabel("", 10, 150, 500, 300, $SS_CENTER)

GUISetState()

$oStyle   = DllCall("user32.dll", "long", "GetWindowLong", "hwnd", $hButton_Handle, "int", -16) ; get existing Style
$oExStyle = DllCall("user32.dll", "long", "GetWindowLong", "hwnd", $hButton_Handle, "int", -20) ; get existing ExStyle

GUICtrlSetData($hLabel, "Style should read 0x2000:       " & @TAB & @TAB & "0x" & Hex($oStyle[0], 4) & @CRLF  & _
        "ExStyle should read 0x00000200: " & @TAB & "0x" & Hex($oExStyle[0], 8))

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Do not forget to use the handle and not the ControlID of the control. :evil: M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Thanks!

It works very well...

Share this post


Link to post
Share on other sites

You can also use the WinApi-UDF

$oStyle   = _WinAPI_GetWindowLong($hButton_Handle, $GWL_STYLE)
$oExStyle   = _WinAPI_GetWindowLong($hButton_Handle, $GWL_EXSTYLE)

That's the same.


Programming today is a race between software engineers striving to
build bigger and better idiot-proof programs, and the Universe
trying to produce bigger and better idiots.
So far, the Universe is winning.

Share this post


Link to post
Share on other sites

You can also use the WinApi-UDF

$oStyle   = _WinAPI_GetWindowLong($hButton_Handle, $GWL_STYLE)
$oExStyle   = _WinAPI_GetWindowLong($hButton_Handle, $GWL_EXSTYLE)

That's the same.

That's along the lines I was thinking too, but I didn't get a chance to check if it supported ctrls. Good to know it does. ;)

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0