Get style from Gui control

[tobi2006]

Hello AutoIt users,

I need a function that retrieves the style from gui control.

For gui there is a function (GUIGetStyle)

But there's not something like: GUICtrlGetStyle

Is there a function like that or did anyone a function like that...?

Yours,

Tobi

[Melba23]

tobi2006,

Here you go:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <StaticConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$hButton = GUICtrlCreateButton("Test", 10, 10, 80, 30, $BS_MULTILINE, $WS_EX_CLIENTEDGE)
$hButton_Handle = GUICtrlGetHandle($hButton)

$hLabel = GUICtrlCreateLabel("", 10, 150, 500, 300, $SS_CENTER)

GUISetState()

$oStyle   = DllCall("user32.dll", "long", "GetWindowLong", "hwnd", $hButton_Handle, "int", -16) ; get existing Style
$oExStyle = DllCall("user32.dll", "long", "GetWindowLong", "hwnd", $hButton_Handle, "int", -20) ; get existing ExStyle

GUICtrlSetData($hLabel, "Style should read 0x2000:       " & @TAB & @TAB & "0x" & Hex($oStyle[0], 4) & @CRLF  & _
        "ExStyle should read 0x00000200: " & @TAB & "0x" & Hex($oExStyle[0], 8))

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Do not forget to use the handle and not the ControlID of the control. M23

[tobi2006]

Thanks!

It works very well...

[funkey]

You can also use the WinApi-UDF

$oStyle   = _WinAPI_GetWindowLong($hButton_Handle, $GWL_STYLE)
$oExStyle   = _WinAPI_GetWindowLong($hButton_Handle, $GWL_EXSTYLE)

That's the same.

[spudw2k]

You can also use the WinApi-UDF

$oStyle   = _WinAPI_GetWindowLong($hButton_Handle, $GWL_STYLE)
$oExStyle   = _WinAPI_GetWindowLong($hButton_Handle, $GWL_EXSTYLE)

That's the same.

That's along the lines I was thinking too, but I didn't get a chance to check if it supported ctrls. Good to know it does.