WinTitleMatchMode

[anixon]

This code gets the client size of the windows notification area

Local $iMode = Opt("WinTitleMatchMode", 4)
Local $hControl = ControlGetHandle("[CLASS:Shell_TrayWnd]", "", "[CLASSNN:ToolbarWindow321]")
Local $acSize = WinGetClientSize($hControl)
_arraydisplay($acSize)

Is it possible to yet the x y width and height location of a specific Icon that appears somewhere on the notification area 'Skype' for example:

Assistance is always appreciated Ant..

[Yashied]

Maybe it will be useful for you.

http://www.autoitscript.com/forum/index.php?showtopic=103871&st=0&p=735369

[anixon]

Maybe it will be useful for you.

http://www.autoitscript.com/forum/index.php?showtopic=103871&st=0&p=735369

Thanks for that I have played with the software since your response and have been unable to get the $x $y position of the Icon. Silly question but if the Return is an array how do you then display the array produced by the called function? Ant..

[PsaltyDS]

Thanks for that I have played with the software since your response and have been unable to get the $x $y position of the Icon.

The tray is just a toolbar control. You should be able to use things like _GUICtrlToolbar_GetButtonRect() on it.

Silly question but if the Return is an array how do you then display the array produced by the called function? Ant..

Very silly, since you used _ArrayDisplay() in your own code in the OP.

Edited February 2, 2010 by PsaltyDS

[anixon]

The tray is just a toolbar control. You should be able to use things like _GUICtrlToolbar_GetButtonRect() on it.

Very silly, since you used _ArrayDisplay() in your own code in the OP.

Can you give me an example of _GUICtrlToolbar_GetButtonRectEX() for Skype that appears as an Icon in the Notification Area to the Toolbar Thanks Ant..

[Melba23]

anixon,

Here is a script that finds and clicks on a systray icon that you identify by the text content of the traytip - I have found it best to use the initial words of the traytip:

expandcollapse popup

#Include <GuiToolBar.au3>

Global $hSysTray_Handle, $iSystray_ButtonNumber

Global $sToolTipTitle = "" ; <<<<<<<<<<<<<<<< Enter some tooltip text for the icon you want here

$iSystray_ButtonNumber = Get_Systray_Index($sToolTipTitle)

If $iSystray_ButtonNumber = 0 Then
    MsgBox(16, "Error", "Icon not found in system tray")
    Exit
Else
    Sleep(500)
    _GUICtrlToolbar_ClickButton($hSysTray_Handle, $iSystray_ButtonNumber, "right")
EndIf

Exit

;............

Func Get_Systray_Index($sToolTipTitle)

    ; Find systray handle
    $hSysTray_Handle = ControlGetHandle('[Class:Shell_TrayWnd]', '', '[Class:ToolbarWindow32;Instance:1]')
    If @error Then
        MsgBox(16, "Error", "System tray not found")
        Exit
    EndIf

    ; Get systray item count
    Local $iSystray_ButCount = _GUICtrlToolbar_ButtonCount($hSysTray_Handle)
    If $iSystray_ButCount = 0 Then
        MsgBox(16, "Error", "No items found in system tray")
        Exit
    EndIf

    ; Look for wanted tooltip
    For $iSystray_ButtonNumber = 0 To $iSystray_ButCount - 1
        If StringInStr(_GUICtrlToolbar_GetButtonText($hSysTray_Handle, $iSystray_ButtonNumber), $sToolTipTitle) = 1 Then ExitLoop
    Next

    If $iSystray_ButtonNumber = $iSystray_ButCount Then
        Return 0 ; Not found
    Else
        Return $iSystray_ButtonNumber ; Found
    EndIf

EndFunc

If you want the coordinates of the icon, then replace the _GUICtrlToolbar_ClickButton line with _GUICtrlToolbar_GetButtonRect or _GUICtrlToolbar_GetButtonRectEx.

I hope that helps.

M23

[anixon]

Is Get_Systray_Index($sToolTipTitle) missing from your code? Ant.. Please ignore I simply did not page down to see it must be to early in the morning.. Ant

Edited February 2, 2010 by anixon

[anixon]

This code

$Coordinates = _GUICtrlToolbar_GetButtonRect($hSysTray_Handle, $iSystray_ButtonNumber)

MsgBox(0,'',$Coordinates[0] & " " & $Coordinates[2])

Skype gives me these values for the x axis 54 Upper Left and 72 Lower Right how does that relate to Skypes position based on @DesktopWidth. In other words how would you translate

the Upper left X access of the Skype Icon X position based on desktop width because I am pretty sure it is not @desktopwidth - 54. Ant..

[Melba23]

anixon,

Those coords are relative to the systray in which it sits - so you need to get the systray position (via WingetPos - you already have the handle ) and do little maths to get the screen coords. Or you could use _WinAPI_ClientToScreen - as you have to create a struct to use this there is probably not a lot in it....

M23

[PsaltyDS]

That's the position of the button (icon) relative to the toolbar.

Edit: Out typed by the Melba-bot!

Edited February 2, 2010 by PsaltyDS

[anixon]

Thanks for the help this looks like it works I hope that the code is elegant enough this exercise has taught me heaps thanks again ...... Ant..

expandcollapse popup

#Include <GuiToolBar.au3>


Global $hSysTray_Handle, $iSystray_ButtonNumber, $xAxisNTB, $xAxisIcon

Global $sToolTipTitle = "Skype" ; <<<<<<<<<<<<<<<< Enter some tooltip text for the icon you want here

$iSystray_ButtonNumber = _Get_Systray_Index($sToolTipTitle)

If $iSystray_ButtonNumber = 0 Then
    MsgBox(16, "Error", "Icon not found in system tray")
    Exit
Else
    ;//'X' Axis Windows Notification Bar
    $xAxisNTB = WingetPos($hSysTray_Handle)
    ;//'X' Axis Icon on Notification Bar
    $xAxisIcon = _GUICtrlToolbar_GetButtonRect($hSysTray_Handle, $iSystray_ButtonNumber)
    ;//'X' Axis Skype Notification Toolbar Icon based on Desktop
    msgbox(0,"", "X Axis" & " NTB " & $xAxisNTB[0] & " Icon " & $xAxisIcon[0] & " X Pos Skype " & $xAxisNTB[0] + $xAxisIcon[0])
EndIf

Exit

Func _Get_Systray_Index($sToolTipTitle)
    ; Find systray handle
    $hSysTray_Handle = ControlGetHandle('[Class:Shell_TrayWnd]', '', '[Class:ToolbarWindow32;Instance:1]')
    If @error Then
        MsgBox(16, "Error", "System tray not found")
        Exit
    EndIf
    ; Get systray item count
    Local $iSystray_ButCount = _GUICtrlToolbar_ButtonCount($hSysTray_Handle)
    If $iSystray_ButCount = 0 Then
        MsgBox(16, "Error", "No items found in system tray")
        Exit
    EndIf
    ; Look for wanted tooltip
    For $iSystray_ButtonNumber = 0 To $iSystray_ButCount - 1
        If StringInStr(_GUICtrlToolbar_GetButtonText($hSysTray_Handle, $iSystray_ButtonNumber), $sToolTipTitle) = 1 Then ExitLoop
    Next
    If $iSystray_ButtonNumber = $iSystray_ButCount Then
        Return 0 ; Not found
    Else
        Return $iSystray_ButtonNumber ; Found
    EndIf
EndFunc