String Manipulation in Web Page

[RNM 0]

Hi All,

I have a web page that I need to pull a date from. The string in the web page shows:

(Current server time:10/20/2010 07:59:13)

I need the date... how do I find and retrieve that value?

Thanks!

[water 1,778]

Something like this:

$sString = BinaryToString(InetRead("your URL"))
;$sString = "The page shows:(Current server time:10/20/2010 07:59:13)I need the date..." ; Testdata
$iPos = StringInStr($sString, "(Current server time:")
$sDateTime = StringMid($sString, $iPos + 21, 19)
MsgBox(0, "", $sDateTime)

[saywell 2]

If the format is completely consistent, StringTrimRight and ...Left would do it, too.

William

[GEOSoft 64]

$sString = BinaryToString(InetRead("your URL"))
$sCurrentTime = StringRegExpReplace($sString, "(?i).*current\s.+time:\s?([\d/]+)\s.+", "$1")

[RNM 0]

$sString = BinaryToString(InetRead("your URL"))
$sCurrentTime = StringRegExpReplace($sString, "(?i).*current\s.+time:\s?([\d/]+)\s.+", "$1")

Perfect... thanks everyone!

[PsaltyDS 27]

If you want to work with the DOM, it might look something like this:

#include <IE.au3>

$sTimeURL = "http://www.time.gov/timezone.cgi?UTC/s/0"
$oIE = _IECreate($sTimeURL)
$colTD = _IETagNameGetCollection($oIE, "td")
For $oTD In $colTD
    If StringRegExp($oTD.innerText, "\d{2}\:\d{2}\:\d{2}", 0) Then
        $aTime = StringRegExp($oTD.innerText, "(?s)(?U)(\d{2}\:\d{2}\:\d{2}).+([[:alpha:]]+\,\s[[:alpha:]]+\s\d{2},\s\d{4})", 1)
        If IsArray($aTime) and UBound($aTime) >= 2 Then
            ConsoleWrite("Time = " & $aTime[0] & @CRLF & "Date = " & $aTime[1] & @LF)
        EndIf
        ExitLoop
    EndIf
Next