Creating a button to fire a selection from a combo box

[Simmy]

Hi guys hope you are well.

I have the following code, which I would like to add to.

What I would like to do is explained in the attached snippet, but briefly, I would like to add a button to the form, which when clicked, would fire off whatever is selected in the combo box.

Any help greatly appreciated.

expandcollapse popup

#include <Array.au3>
#include <File.au3>
#include <GUIComboBox.au3>
#include <GUIConstantsEx.au3>

_Main()


Func _Main()
    Local $hCombo, $iCombo

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Output the exe list to a text file. Skip the echo is on line, by using skip=1.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    $listpath = @ScriptDir & '\apps\*.exe'
    RunWait(@ComSpec & ' /c for /f "tokens=* delims=\ skip=1" %a in (''dir /S /B ' & $listpath & ' /A-D'') do @echo %a >> grplist.txt','',@SW_HIDE)

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Create a form.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        GUICreate('Executables', 500, 300)

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Create a combo to hold the data.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        ;$iCombo = GUICtrlCreateCombo("Select A Folder", 30, 75, 220, 200)
        ;Don't put a title in as this will create an entry in the combo box.
        ;$iCombo = GUICtrlCreateCombo("Select A Folder", 30, 75, 220, 200)
        $iCombo = GUICtrlCreateCombo("", 30, 75, 220, 200)
        $hCombo = GUICtrlGetHandle(-1)



    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Open the file in order to read it.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        $FileOpen = FileOpen('grplist.txt', 0)

        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;Add error-handling for file.
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

            If $FileOpen = -1 Then
                MsgBox(0, "Error", "Unable to open file.")
                Exit
            EndIf


    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Set the data of the combo by looping through the file.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        While 1
            $line = FileReadLine($FileOpen)
            If $line = "" Then ExitLoop
            If @error = -1 Then ExitLoop
            GUICtrlSetData($iCombo,$line)
        Wend
;_FileReadToArray

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Set the default visible entry in the combobox with this function.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    _GUICtrlComboBox_SetEditText($hCombo, "Select A Folder")

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Close the file to free resources.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        FileClose($FileOpen)

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Show the form since forms are hidden by default.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        GUISetState(@SW_SHOW)

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Keep the form open until you close it.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

[guinness]

GUICtrlRead() - Have a look at the Help File under the Example GUICtrlCreateCombo().

[sleepydvdr]

In your While statement on the button press, include something like this (modify it to fit your variables because you didn't provide enough code to list them all):

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    Case $Button
        $programLocation = GUICtrlRead($iCombo)
        Run ($programLocation)
    EndSwitch
WEnd

[Simmy]

Thanks again guinness and sleepydvdr. I will try these things out.

[Simmy]

Hi guys, I have tried to use your logic sleepy and guiness.

Thank you so much guys. The code working is below.

expandcollapse popup

#include <Array.au3>
#include <File.au3>
#include <GUIComboBox.au3>
#include <GUIConstantsEx.au3>

_Main()


Func _Main()
    Local $hCombo, $iCombo

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Output the exe list to a text file. Skip the echo is on line, by using skip=1.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    $listpath = @ScriptDir & '\apps\*.exe'
    RunWait(@ComSpec & ' /c for /f "tokens=* delims=\ skip=1" %a in (''dir /S /B ' & $listpath & ' /A-D'') do @echo %a >> grplist.txt','',@SW_HIDE)

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Create a form.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        GUICreate('Executables', 500, 300)

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Create a combo to hold the data.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        ;$iCombo = GUICtrlCreateCombo("Select A Folder", 30, 75, 220, 200)
        ;Don't put a title in as this will create an entry in the combo box.
        ;$iCombo = GUICtrlCreateCombo("Select A Folder", 30, 75, 220, 200)
        $iCombo = GUICtrlCreateCombo("", 30, 75, 220, 200)
        $hCombo = GUICtrlGetHandle(-1)


    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Create a button to press.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        $Button1 = GUICtrlCreateButton("Run ", 10, 30, 100)

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Open the file in order to read it.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        $FileOpen = FileOpen('grplist.txt', 0)

        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;Add error-handling for file.
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

            If $FileOpen = -1 Then
                MsgBox(0, "Error", "Unable to open file.")
                Exit
            EndIf


    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Set the data of the combo by looping through the file.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        While 1
            $line = FileReadLine($FileOpen)
            If $line = "" Then ExitLoop
            If @error = -1 Then ExitLoop
            GUICtrlSetData($iCombo,$line)
        Wend
;_FileReadToArray

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Set the default visible entry in the combobox with this function.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    _GUICtrlComboBox_SetEditText($hCombo, "Select A Folder")

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Close the file to free resources.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        FileClose($FileOpen)

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Show the form since forms are hidden by default.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        GUISetState(@SW_SHOW)

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;Keep the form open until you close it.
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

        ;Do
        ;Until GUIGetMsg() = $GUI_EVENT_CLOSE



        While 1
            $nMsg = GUIGetMsg()
            Switch $nMsg
                Case $GUI_EVENT_CLOSE
                    Exit
            Case $Button1
                $programLocation = GUICtrlRead($iCombo)
                MsgBox(0, "Error", $programLocation)
                ;Run ("Notepad")
                Run ($programLocation)
            EndSwitch
        WEnd




EndFunc   ;==>_Main