_GetSystemPaths() - Retrieve details about the system paths from HKEY_CURRENT_USER\Volatile Environment\.

[guinness]

I came across a situation the other day where I had to find a file in "LOCALAPPDATA", now the obvious solution was to use @UserProfileDir & "AppDataLocal" and this was fine. But being the curious type I was interested to know if there was a way of extracting "LOCALAPPDATA" from the Registry (Vista above) and this is when I came across HKEY_CURRENT_USERVolatile Environment.

The Function will enumerate through the Registry Key (HKEY_CURRENT_USERVolatile Environment) adding the values to an Array. Because the final size of the Array is unknown, I've started to use ReDim in an efficent way! Check out >_ReDim() for more details.

Note: This will work on XP and above, but it should be noted that "LOCALAPPDATA" can't be found on XP!

Function: Save as _GetSystemPaths.au3

; #FUNCTION# ====================================================================================================================
; Name ..........: _GetSystemPaths
; Description ...: Retrieve details about the system paths from HKEY_CURRENT_USER\Volatile Environment\.
; Syntax ........: _GetSystemPaths()
; Parameters ....: None
; Return values .: Success - Returns a 2 dimensional array where element[n][0] is the key and element[n][1] is the value.
;                  The number of elements can be determined by using UBound($aArray).
;                  Failure - None
; Author ........: guinness
; Example .......: Yes
; ===============================================================================================================================
Func _GetSystemPaths()
    Local Enum $GSP_KEY, $GSP_VALUE, $GSP_COLUMNS
    Local $iSize = 10
    Local $aReturn[$iSize][$GSP_COLUMNS], _
            $iIndex = 0, $iInstance = 1, _
            $sRegistryKey = 'HKEY_CURRENT_USER\Volatile Environment\', $sRegistryValue = ''
    While 1
        $sRegistryValue = RegEnumVal($sRegistryKey, $iInstance)
        If @error Then
            ExitLoop
        EndIf
        If $iIndex = $iSize Then
            $iSize = Ceiling(($iSize + 1) * 1.3)
            ReDim $aReturn[$iSize][$GSP_COLUMNS]
        EndIf
        $aReturn[$iIndex][$GSP_KEY] = $sRegistryValue
        $aReturn[$iIndex][$GSP_VALUE] = RegRead($sRegistryKey, $sRegistryValue)
        $iIndex += 1
        $iInstance += 1
    WEnd
    ReDim $aReturn[$iIndex][$GSP_COLUMNS]
    Return $aReturn
EndFunc   ;==>_GetSystemPaths

Example use of Function:

#include <Array.au3>

#include '_GetSystemPaths.au3'

Local $aArray = _GetSystemPaths()
_ArrayDisplay($aArray)

Note: @LocalAppData is available in AutoIt v3.3.10.0+. Edited October 11, 2014 by guinness

[Ascend4nt]

Also check out 'SHGetFolderPath' and 'SHGetKnownFolderPath' API functions.

[guinness]

I know of those API's (I use SHGetKnownFolderPath in _SendTo()) but didn't think to check for LOCALAPPDATA!! Thanks Ascend4nt

Edit: Just checked WinAPIEx.au3 and found it >> _WinAPI_ShellGetSpecialFolderPath($CSIDL_LOCAL_APPDATA), don't I look like a fool . Oh well it only took me 5mins to create. I always forget to check APIConstant.au3 and opt for the Help File instead, now I know.

Edited June 23, 2011 by guinness

[BrewManNH]

You could also use the environment variables to get them, might be easier if running under a non-admin account.

[guinness]

I could have done that too BrewManNH . But the most important thing was I was looking for alternative routes too.

MsgBox(64, "Get %LOCALAPPDATA%", EnvGet("LOCALAPPDATA"))

[wakillon]

MsgBox(64, "Get %LOCALAPPDATA%", EnvGet("LOCALAPPDATA"))

What's the difference between %LOCALAPPDATA% and %APPDATA% who works on XP ?

MsgBox(64, "Get %APPDATA%", EnvGet("APPDATA"))

[guinness]

%LOCALAPPDATA% doesn't exist on XP but its a folder that stores data for local (non-roaming).

For more details: http://www.vistaonwindows.com/environment_variables.php

[guinness]

Fixed code above.

[guinness]

The count has been removed from the first index. To determine the size use UBound().

See the first post for improved code. Thanks.