Network Interface Info, Statistics, and Traffic

[Ascend4nt 137]

Network Interface Info, Statistics, and Traffic (incl. IP, TCP, UDP and ICMP)

---

This is an example of getting and displaying Network Interface Information, Statistics and Traffic.  Previously this was just a means to getting Network statistics (specifically IP, TCP, UDP, and ICMP), but now it includes Internet Interface information, as well as Interface-specific statistics.

Since this UDF can be used in different ways, let me cover Statistics first:

Network Statistics Information

Stats example output

 

To retrieve Statistics information, you can call one of the four _Network_xxxxStatistics() functions for IP, TCP, UDP, or ICMP Statistics.  These functions accept 1 argument which specifies which protocol to use.  Basically, zero is IPv4 and non-zero is IPv6.  It defaults to IPv4 if no arguments.  Here's the functions:

Protocol Statistics Functions:
_Network_IPStatistics() -> receives IP statistics
_Network_TCPStatistics() -> TCP statistics
_Network_UDPStatistics() -> UDP statistics
_Network_ICMPStatistics() -> ICMP statistics

-

To get per-interface statistics requires 2 calls.  One call is required to collect information on adapters into an array. Once this information is retrieved, multiple calls to _Network_InterfaceEntryInfo() can be made for each indexed network interface.  Note that _Network_IPv4AdaptersInfo() is the only adapter/interface information function which doesn't get index information - so don't use it unless you want further interface information.  The main UDF functions to use are:

Network Adapter & Interface Functions:
_Network_IPv4AdaptersInfo() -> Retrieves information on Physical IPv4 adapters
_Network_IPv4AdaptersInfoEx() -> Retrieves much more info on Physical IPv4 adapters
_Network_IPv4AddressTable() -> Retrieves information on IPv4 Interfaces
_Network_IPAllAddressTable() -> Retrieves information on both IPv4 and IPv6 interfaces

Network Statistics for a Given Interface:
_Network_InterfaceEntryInfo() -> For a given interface index, retrieves statistics

-

The simplest way to get overall traffic is to use _Network_IPAllAddressTable() (or _Network_IPv4AddressTable() for IPv4 only) to collect an array of info about interfaces.  This needs to be done only once.  Then, to collect statistics, for each row in the interface array, call _Network_InterfaceEntryInfo() with $aIPAddressTable[$i][0] to get the statistics for that network interface.

IMPORTANT: Note that for all statistics, the data received/sent are represented as 32-bit numbers, and subject to wraparound after 4GBs of data has been transferred.

Network Interface Information

Regarding Network Interface Information, nearly every function except those ending in xxStatistics(), will return various info regarding the network adapters or interfaces.

Currently, IPv4 and IPv6 addresses are retrieved for the interface, as well as for Gateway, DHCP, DNS and WINS servers (there's some XP issues here as to which functions to use - see UDFs).  The number of IP addresses (since there can be more than one assigned to each interface) is controlled via a parameter $bGetAllIPs.  If this value is non-zero, multiple IP addresses are returned in a string separated by "|" (pipe symbol).

Also note that the MAC/Physical Address is returned by most functions as well.  These are properly formatted into a hex string in the form "01-23-45-67-89-ab".

There is one issue with converting IPv6 addresses - on pre-Vista O/S's (Win XP I'm looking at you) WSAStartup must be called by the code.  This is all handled internally, but if you have code that relies on WSAStartup/Cleanup, keep it in mind and let me know if I can better accommodate any potential conflicts.

Further notes:

- The TCP Statistics gives information about the number of segments sent/received, rather than the # of packets.  I'm not totally clear on the association, however here's some links:

 What's the difference between a TCP segment and a TCP packet?

 Whats the difference between a Packet, Segment and Frame?

   

- I'm not sure how segments, packets, or datagrams map to # of bytes, or what API functions I might use to figure this out. Any help there would be appreciated.

Alternatives:

While I have opened access to a lot of detailed network and performance information, there are alternatives - check out Netstat (-e for performance stats) or my >Performance Counters UDF's, which has a lot of varied stats (one example of these: >Network Usage).

Following is the example, included in the ZIP file.  Note there's a cr@pload of info dumped to the console, so you'll probably want to redirect output or copy-and-paste from the output console:

expandcollapse popup

; ========================================================================================================
; <NetworkStatsExample.au3>
;
; Example of reading and displaying Network Interface Information and Statistics
; (using <NetworkStatistics.au3> UDF)
; Statistics information, including IP, TCP*, UDP, and ICMP and internet interface traffic,
; are displayed in a 'Splash' window - with both IPv4 and IPv6 data separated
;
; Author: Ascend4nt
; ========================================================================================================

#include "_NetworkStatistics.au3"


;   --------------------    HOTKEY FUNCTION & VARIABLE --------------------

Global $bHotKeyPressed = False

Func _EscPressed()
    $bHotKeyPressed=True
EndFunc

;   --------------------    MAIN PROGRAM CODE   --------------------

HotKeySet("{Esc}", "_EscPressed")

Local $hSplash, $sSplashText
; Network Stats
Local $aUDPStats, $aTCPStats, $aIPStats, $aICMPStats
Local $aUDPv6Stats, $aTCPv6Stats, $aIPv6Stats, $aICMPv6Stats
Local $aIPv4Adapters, $nAdapters
Local $aIPv4AddrTable, $aIPAllAddrTable, $nInterfaces, $aNIEntryInfo
Local $sSeparator = "-----------------------------------------"

; IP Stats: IPv4 and IPv6
For $i = 0 To 1
    $aIPStats = _Network_IPStatistics($i)
    If @error Then
        ConsoleWrite("_Network_IPStatistics("&$i&") error: "&@error&", @extended="&@extended&@CRLF)
        ContinueLoop
    EndIf
    If $i Then
        ConsoleWrite("IP [IPv6] Stats:")
    Else
        ConsoleWrite("IP [IPv4] Stats:")
    EndIf

    ConsoleWrite( _
        " [0]  = IP Forwarding Status: [1 = Enabled, 2 = Disabled] : " & $aIPStats[0] & _
        ", [1]  = Default initial time-to-live (TTL) for datagrams : " & $aIPStats[1] & @CRLF & _
        ", [2]  = # Received Datagrams : " & $aIPStats[2] & _
        ", [3]  = # Received Datagrams w/Header errors : " & $aIPStats[3] & _
        ", [4]  = # Received Datagrams w/Address errors : " & $aIPStats[4] & @CRLF & _
        ", [5]  = # Forwarded Datagrams : " & $aIPStats[5] & _
        ", [6]  = # Received Datagrams w/Unknown Protocol : " & $aIPStats[6] & _
        ", [7]  = # Received Datagrams Discarded : " & $aIPStats[7] & @CRLF & _
        ", [8]  = # Received Datagrams Delivered : " & $aIPStats[8] & _
        ", [9]  = # Requested Outgoing Datagrams : " & $aIPStats[9] & _
        ", [10] = # Outgoing Datagrams Discarded : " & $aIPStats[10] & @CRLF & _
        ", [11] = # Transmitted Datagrams Discarded : " & $aIPStats[11] & _
        ", [12] = # Datagrams w/o Routes that were Discarded : " & $aIPStats[12] & _
        ", [13] = TimeOut for Reassembling Incoming Fragmented Datagrams : " & $aIPStats[13] & @CRLF & _
        ", [14] = # Datagrams Requiring Reassembly : " & $aIPStats[14] & _
        ", [15] = # Datagrams Successfully Reassembled : " & $aIPStats[15] & _
        ", [16] = # Datagrams that Failed to be Reassembled : " & $aIPStats[16] & @CRLF & _
        ", [17] = # Datagrams that were Fragmented Successfully : " & $aIPStats[17] & _
        ", [18] = # Datagrams not Fragmented, and Discarded : " & $aIPStats[18] & _
        ", [19] = # Fragments created (for Datagrams) : " & $aIPStats[19] & @CRLF & _
        ", [20] = # of Interfaces : " & $aIPStats[20] & _
        ", [21] = # of IP addresses associated with PC : " & $aIPStats[21] & _
        ", [22] = # of Routes in the Routing table : " & $aIPStats[22] & _
        @CRLF)
    ConsoleWrite($sSeparator & @CRLF)
Next

; TCP Stats: IPv4 and IPv6
For $i = 0 To 1
    $aTCPStats = _Network_TCPStatistics($i)
    If @error Then
        ConsoleWrite("_Network_TCPStatistics("&$i&") error: "&@error&", @extended="&@extended&@CRLF)
        ContinueLoop
    EndIf
    If $i Then
        ConsoleWrite("TCP [IPv6] Stats:")
    Else
        ConsoleWrite("TCP [IPv4] Stats:")
    EndIf

    ConsoleWrite( _
        "[0] Rto Algorithm = " & $aTCPStats[0] & _
        ",[1] Rto Min = " & $aTCPStats[1] & _
        ",[2] Rto Max = " & $aTCPStats[2] & _
        ",[3] #Max Connections = " & $aTCPStats[3] & _
        ",[4] #Active Opens = " & $aTCPStats[4] & _
        ",[5] #Passive Opens = " & $aTCPStats[5] & @CRLF & _
        " [6] #Failed Connection Attempts = " & $aTCPStats[6] & _
        ",[7] #Established Connections that were Reset = " & $aTCPStats[7] & _
        ",[8] #Established Connections [current] = " & $aTCPStats[8] & @CRLF & _
        " [9] #Recvd Segments = " & $aTCPStats[9] & _
        ",[10] #Sent Segments = " & $aTCPStats[10] & _
        ",[11] #Retransmitted Segments = " & $aTCPStats[11] & @CRLF & _
        " [12] #Receive Errors = " & $aTCPStats[12] & _
        ",[13] #Sent Segments with Reset Flag = " & $aTCPStats[13] & _
        ",[14] #Connections = " & $aTCPStats[14] & _
        @CRLF)
    ConsoleWrite($sSeparator & @CRLF)
Next

; UDP Stats: IPv4 and IPv6
For $i = 0 To 1
    $aUDPStats = _Network_UDPStatistics($i)
    If @error Then
        ConsoleWrite("_Network_UDPStatistics("&$i&") error: "&@error&", @extended="&@extended&@CRLF)
        ContinueLoop
    EndIf
    If $i Then
        ConsoleWrite("UDP [IPv6] Stats:")
    Else
        ConsoleWrite("UDP [IPv4] Stats:")
    EndIf
    ConsoleWrite( _
        " [0] #Recvd Datagrams = " & $aUDPStats[0] & _
        ",[1] #Discarded Datagrams [invalid port] = " & $aUDPStats[1] & _
        ",[2] #Erroneous Datagrams = " & $aUDPStats[2] & @CRLF & _
        " [3] #Sent Datagrams = " & $aUDPStats[3] & _
        ",[4] #UDP Listener Entries = " & $aUDPStats[4] & _
        @CRLF)
    ConsoleWrite($sSeparator & @CRLF)
Next

; ICMP Stats: IPv4 and IPv6
For $i = 0 To 1
    $aICMPStats = _Network_ICMPStatistics($i)
    If @error Then
        ConsoleWrite("_Network_ICMPStatistics("&$i&") error: "&@error&", @extended="&@extended&@CRLF)
        ContinueLoop
    EndIf

    ConsoleWrite("ICMP [IPv"&4+($i*2)&"] Stats:" & _
        " [0] = # Incoming ICMP Messages : " & $aICMPStats[0] & _
        ", [1] = # Incoming ICMP Errors : " & $aICMPStats[1] & _
        ", [2] = # Outgoing ICMP Messages : " & $aICMPStats[2] & _
        ", [3] = # Outgoing ICMP Errors : " & $aICMPStats[3] & _
        @CRLF)
    ConsoleWrite($sSeparator & @CRLF)
Next

; IPv4 Adapters Info (very basic info)
_Network_IPv4AdaptersInfo()
ConsoleWrite($sSeparator & @CRLF)

; IPv4 Adapters Info (comprehensive info)
$aIPv4Adapters = _Network_IPv4AdaptersInfoEx()
$nAdapters = @extended
ConsoleWrite("# of Adapters: "&$nAdapters&@CRLF)
For $i = 0 To $nAdapters - 1
    ConsoleWrite("Adapter #"&$i+1&":" & _
        "  [0] Index #"& $aIPv4Adapters[$i][0] & _
        ", [1] Type = " & $aIPv4Adapters[$i][1] & _
        ", [2] DHCP Enabled Flag = " & $aIPv4Adapters[$i][2] & _
        ", [3] WINS Enabled Flag = " & $aIPv4Adapters[$i][3] & _
        ", [4] Physical [MAC] Address: " & $aIPv4Adapters[$i][4] & _
        ", [5] (0) =  " & $aIPv4Adapters[$i][5] & @CRLF & _
        ", [6] Description: "& $aIPv4Adapters[$i][6] & _
        ", [7] [Empty '']: " & $aIPv4Adapters[$i][7] & _
        ", [8] Adapter/Service Name [GUID] = " & $aIPv4Adapters[$i][8] & _
        ", [9]  [Empty] =  " & $aIPv4Adapters[$i][9] & _
        ", [10] [Empty] =  " & $aIPv4Adapters[$i][10] & @CRLF & _
        ", [11] IPv4 Address(es): "& $aIPv4Adapters[$i][11] & _
        ", [12] IP Address Mask(s): "& $aIPv4Adapters[$i][12] & @CRLF & _
        ", [13] Gateway IPv4 Address(es): "& $aIPv4Adapters[$i][13] & _
        ", [14] Gateway Address Mask(s) : "& $aIPv4Adapters[$i][14] & @CRLF & _
        ", [15] DHCP IPv4 Address(es) = " & $aIPv4Adapters[$i][15] & _
        ", [16] DHCP Address Mask(s)  = " & $aIPv4Adapters[$i][16] & _
        ", [17] DHCP LeaseObtained Time = " & $aIPv4Adapters[$i][17] & _
        ", [18] DHCP LeaseExpires Time = " & $aIPv4Adapters[$i][18] & @CRLF & _
        ", [19] Primary WINS Server IP = " & $aIPv4Adapters[$i][19] & _
        ", [20] Primary WINS Server Address Mask = " & $aIPv4Adapters[$i][20] & _
        ", [21] Secondary WINS Server IP(s) = " & $aIPv4Adapters[$i][21] & _
        ", [22] Secondary WINS Server Address Mask(s) = " & $aIPv4Adapters[$i][22] & @CRLF)
    ConsoleWrite($sSeparator & @CRLF)
Next

; IPv4 Interface Info alt #2
$aIPv4AddrTable = _Network_IPv4AddressTable()
$nInterfaces = @extended
ConsoleWrite(@CRLF)
For $i = 0 To $nInterfaces - 1
    ConsoleWrite("Adapter #"&$i+1&": [0] Interface Index # = " & $aIPv4AddrTable[$i][0] & _
        ", [1] IPv4 Address = " & $aIPv4AddrTable[$i][1] & _
        ", [2] Subnet Mask = " & $aIPv4AddrTable[$i][2] & _
        ", [3] Broadcast Address = " & $aIPv4AddrTable[$i][3] & @CRLF & _
        "  [4] Max Reassembly Size = " & $aIPv4AddrTable[$i][4] & _
        ", [5] Address Type/State = " & $aIPv4AddrTable[$i][5] & @CRLF)
Next
ConsoleWrite($sSeparator & @CRLF)

; IPv4 and IPv6 Interface Info (includes everything except Address Masks)
;  params: 0 (IPv4 AND IPv6), 0 (don't get all IP's), 0 (don't include down-status interfaces)
$aIPAllAddrTable = _Network_IPAllAddressTable(0, 0, 0)
$nInterfaces = @extended

ConsoleWrite($sSeparator & @CRLF)

For $i = 0 To $nInterfaces - 1
    ConsoleWrite("Interface #"&$i+1&": [0] Index #"& $aIPAllAddrTable[$i][0] & _
        ", [1] Type = " & $aIPAllAddrTable[$i][1] & _
        ", [2] Operational Status = " & $aIPAllAddrTable[$i][2] & _
        ", [3] Flags = 0x" & Hex($aIPAllAddrTable[$i][3], 8) & _
        ", [4] Physical [MAC] Address: " & $aIPAllAddrTable[$i][4] & _
        ", [5] MTU =  " & $aIPAllAddrTable[$i][5] & @CRLF & _
        ", [6] Description: "& $aIPAllAddrTable[$i][6] & _
        ", [7] Friendly Name: " & $aIPAllAddrTable[$i][7] & _
        ", [8] Adapter/Service Name [GUID] = " & $aIPAllAddrTable[$i][8] & @CRLF & _
        ", [9] Max Receive Speed [Vista+] = " & $aIPAllAddrTable[$i][9] & _
        ", [10] Max Transmit Speed [Vista+] = " & $aIPAllAddrTable[$i][10] & @CRLF & _
        ", [11] IPv4 Address(es): "& $aIPAllAddrTable[$i][11] & _
        ", [12] IPv6 Address(es): "& $aIPAllAddrTable[$i][12] & @CRLF & _
        ", [13] DNS IPv4 Address(es): "& $aIPAllAddrTable[$i][13] & _
        ", [14] DNS IPv6 Address(es): "& $aIPAllAddrTable[$i][14] & @CRLF & _
        ", [15] Gateway IPv4 Address(es) [Vista+]: "& $aIPAllAddrTable[$i][15] & _
        ", [16] Gateway IPv6 Address(es) [Vista+]: "& $aIPAllAddrTable[$i][16] & @CRLF & _
        ", [17] DHCP IPv4 Address(es) [Vista+]: "& $aIPAllAddrTable[$i][17] & _
        ", [18] DHCP IPv6 Address(es) [Vista+]: "& $aIPAllAddrTable[$i][18] & @CRLF & _
        ", [19] WINS IPv4 Address(es) [Vista+]: "& $aIPAllAddrTable[$i][19] & _
        ", [20] WINS IPv6 Address(es) [Vista+]: "& $aIPAllAddrTable[$i][20] & @CRLF & _
        ", [21] Connection Type [Vista+] = " & $aIPAllAddrTable[$i][21] & _
        ", [22] Tunnel Type [Vista+] = " & $aIPAllAddrTable[$i][22] & @CRLF)

    ; Interface Statistics & Info for Given index
    $aNIEntryInfo = _Network_InterfaceEntryInfo($aIPAllAddrTable[$i][0])
;~     ConsoleWrite("_Network_InterfaceEntryInfo return, @error = " & @error & ", @extended = " & @extended & @CRLF)
    ConsoleWrite("Interface #"&$i+1&" Entry Info: [0] Interface Index = " & $aNIEntryInfo[0] & _
        ", [1] Interface Type = " & $aNIEntryInfo[1] & _
        ", [2] Operational Status = " & $aNIEntryInfo[2] & _
        ", [3] Admin Status = " & $aNIEntryInfo[3] & _
        ", [4] Physical Address = " & $aNIEntryInfo[4] & _
        ", [5] MTU [Max Trans. Unit] in bytes = " & $aNIEntryInfo[5] & @CRLF & _
        ", [6] Description = " & $aNIEntryInfo[6] & _
        ", [7] Interface Name = " & $aNIEntryInfo[7] & @CRLF & _
        ", [8] Last change [1/100th second] = " & $aNIEntryInfo[8] & _
        ", [9] Interface Speed [bps] = " & $aNIEntryInfo[9] & @CRLF & _
        ", [10] # Recvd Data [in Octets] = " & $aNIEntryInfo[10] & _
        ", [11] # Recvd Unicast Packets = " & $aNIEntryInfo[11] & _
        ", [12] # Recvd Non-Unicast Packets = " & $aNIEntryInfo[12] & _
        ", [13] # Recvd Packets Discarded [no error] = " & $aNIEntryInfo[13] & _
        ", [14] # Recvd Packets Discarded [error] = " & $aNIEntryInfo[14] & _
        ", [15] # Recvd Packets Discarded [unk. protocol] = " & $aNIEntryInfo[15] & @CRLF & _
        ", [16] # Sent Data [in Octets] = " & $aNIEntryInfo[16] & _
        ", [17] # Sent Unicast Packets = " & $aNIEntryInfo[17] & _
        ", [18] # Sent Non-Unicast Packets = " & $aNIEntryInfo[18] & _
        ", [19] # Sent Packets Discarded [no error] = " & $aNIEntryInfo[19] & _
        ", [20] # Sent Packets Discarded [error] = " & $aNIEntryInfo[20] & @CRLF & _
        ", [21] Transmit Queue Length [n/a] = " & $aNIEntryInfo[21] & @CRLF)
    ConsoleWrite($sSeparator & @CRLF)
Next

$hSplash=SplashTextOn("Network Usage Information", "", 520, 24 + (19 * 15) + ($nInterfaces * (5.5 * 15)), Default, Default, 16+4, "Lucida Console", 11)

; Start loop
Do
    $aIPStats   = _Network_IPStatistics()
    $aTCPStats  = _Network_TCPStatistics()
    $aUDPStats  = _Network_UDPStatistics()
    $aICMPStats = _Network_ICMPStatistics()

    $aIPv6Stats   = _Network_IPStatistics(1)
    $aTCPv6Stats  = _Network_TCPStatistics(1)
    $aUDPv6Stats  = _Network_UDPStatistics(1)
    $aICMPv6Stats = _Network_ICMPStatistics(1)

    $sSplashText  = StringFormat("%35s", "== TCP Stats ==") & @CRLF
    $sSplashText &= StringFormat("IPv4: [Segments] Recvd   = %10u | Sent = %10u", $aTCPStats[9], $aTCPStats[10]) & @CRLF
    $sSplashText &= StringFormat("IPv6: [Segments] Recvd   = %10u | Sent = %10u", $aTCPv6Stats[9], $aTCPv6Stats[10]) & @CRLF
    $sSplashText &= StringFormat("<Total Connections> IPv4:  %10u | IPv6:  %10u", $aTCPStats[14], $aTCPv6Stats[14]) & @CRLF

    $sSplashText &= @CRLF & StringFormat("%35s", "== UDP Stats ==") & @CRLF
    $sSplashText &= StringFormat("IPv4: [Datagrams] Recvd  = %10u | Sent = %10u", $aUDPStats[0], $aUDPStats[3]) & @CRLF
    $sSplashText &= StringFormat("IPv6: [Datagrams] Recvd  = %10u | Sent = %10u", $aUDPv6Stats[0], $aUDPv6Stats[3]) & @CRLF
    $sSplashText &= StringFormat("<Total Listeners>   IPv4:  %10u | IPv6:  %10u", $aUDPStats[4], $aUDPv6Stats[4]) & @CRLF

    $sSplashText &= @CRLF & StringFormat("%35s", "== IP Stats ==") & @CRLF
    $sSplashText &= StringFormat("IPv4: [Datagrams] Recvd  = %10u | Sent = %10u", $aIPStats[2], $aIPStats[9]) & @CRLF
    $sSplashText &= StringFormat("IPv6: [Datagrams] Recvd  = %10u | Sent = %10u", $aIPv6Stats[2], $aIPv6Stats[9]) & @CRLF

    $sSplashText &= @CRLF & StringFormat("%35s", "== ICMP Stats ==") & @CRLF
    $sSplashText &= StringFormat("IPv4: [Messages]  Recvd  = %10u | Sent = %10u", $aICMPStats[0], $aICMPStats[2]) & @CRLF
    $sSplashText &= StringFormat("IPv6: [Messages]  Recvd  = %10u | Sent = %10u", $aICMPv6Stats[0], $aICMPv6Stats[2]) & @CRLF


    For $i = 0 To $nInterfaces - 1

;~         $aNIEntryInfo = _Network_InterfaceEntryInfo($aIPv4AddrTable[$i][0])
;~         $sSplashText &= @CRLF & StringFormat("%35s", "== IP " & $aIPv4AddrTable[$i][1] & " ==" ) & @CRLF

        $aNIEntryInfo = _Network_InterfaceEntryInfo($aIPAllAddrTable[$i][0])
        If @error Then
            ConsoleWrite("_Network_InterfaceEntryInfo return, @error = " & @error & ", @extended = " & @extended & @CRLF)
            ExitLoop
        EndIf

        If $aIPAllAddrTable[$i][11] <> "" Then
            $sSplashText &= @CRLF & StringFormat("%40s", "== IPv4 " & $aIPAllAddrTable[$i][11] & " ==" ) & @CRLF
        Else
            $sSplashText &= @CRLF & StringFormat("%52s", "== IPv6 " & $aIPAllAddrTable[$i][12] & " ==" ) & @CRLF
        EndIf
        $sSplashText &= StringFormat("%45.56s", $aNIEntryInfo[6]) & @CRLF

        ; Octet *should* be the same as Bytes..
        $sSplashText &= StringFormat("Data (Octets/Bytes): Recvd = %10u | Sent = %10u", $aNIEntryInfo[10], $aNIEntryInfo[16]) & @CRLF
        $sSplashText &= StringFormat("Unicast Packets:     Recvd = %10u | Sent = %10u", $aNIEntryInfo[11], $aNIEntryInfo[17]) & @CRLF
        $sSplashText &= StringFormat("Non-Unicast Packets: Recvd = %10u | Sent = %10u", $aNIEntryInfo[12], $aNIEntryInfo[18]) & @CRLF
    Next

    $sSplashText &= @CRLF & StringFormat("%35s", "[ESC] Exits") & @CRLF

    ControlSetText($hSplash, "", "[CLASS:Static; INSTANCE:1]", $sSplashText)

    Sleep(500)
Until $bHotKeyPressed

NetworkStatistics.zip ~prev version. downloads: >100

Updates:

2013-07-11:

 Changed: _Network_IPv4AdaptersInfoEx() now returns all IP's (if requested) and Address Masks

 Fixed: WSALastError call possible crash with non-array variable

 Changed: _Network_IPAllAddressTable() now allows 'down' status interfaces to be returned

 Added: Some comments on development, info on getting additional stats in the UDF

2013-07-06:

 Added: Much more Adapter Information

 Changed: Example is now separate from the UDF

 Fixed some minor issues here and there

 Changed: Global Handle to IPHLPAPI.DLL is now contained in the UDF and used to speed up function calls

 Misc. Other fixes I didn't keep track of!

2013-07-02:

 Hotfix: Ipv6 indexing error

 Fixed: indexing, updated and enhanced output

 Changed: Various functions return arrays even if failure - this is to make XP pre-SP1 and also collection of IPv6 less troublesome. @error should still be checked on return though!

 Added: Adapter and Interface information and statistics collection

2013-06-20:

 Now covers all the 'p's - IP and ICMP now added

Edited July 12, 2013 by Ascend4nt

[guinness 1,543]

Works on 7 x64. Thanks for sharing.

[Ascend4nt 137]

Thanks for the tests.  Btw, my 'splash window' height calculations aren't very scientific as you've seen from my other thread.

[Ascend4nt 137]

Ok, fine.  I'm never happy leaving things looking halfway done.  Now I've added IP and ICMP statistics.  See 1st post. Oh, and ICMP doesn't change that often - to force an increase, do a 'ping' from the command prompt.

[ptrex 185]

@Ascend4nt

Great very usefull !!

Thanks for sharing

ptrex

[UEZ 1,435]

Thx for sharing!

Br,

UEZ

[guinness 1,543]

The splash screen is OK this time. I tested the new version and pinged a machine, it registered the packet being sent with your UDF.

[Ascend4nt 137]

I've update this UDF with a bunch of more information.  Network adapters and interfaces are now queryable. Arrays of information about each network interface are now returned from certain functions.  Inside the arrays are indexes which can be used to query network statistics for each network interface.

This is a pretty big change from my first version of Network Statistics (I call it version 2!), so if anyone inquires about it, I could upload the old version again.  However, I plan to split the main UDF from the example in the future.

Updates:

2013-07-02:

 Fixed: indexing, updated and enhanced output

 Changed: Various functions return arrays even if failure - this is to make XP pre-SP1 and also collection of IPv6 less troublesome. @error should still be checked on return though!

 Added: Adapter and Interface information and statistics collection

See the first post

[UEZ 1,435]

I'm getting an error:

C:\_Downloads\NetworkStatistics.au3 (1267) : ==> Subscript used with non-Array variable.:
ConsoleWrite("Interface #"&$i+1&" Entry Info: [0] Interface Index = " & $aNIEntryInfo[0] & ", [1] Interface Type = " & $aNIEntryInfo[1] & ", ...
ConsoleWrite("Interface #"&$i+1&" Entry Info: [0] Interface Index = " & $aNIEntryInfo^ ERROR

Br,

UEZ

[Ascend4nt 137]

UEZ, thanks.. can you insert this line after the call to _Network_InterfaceInfo() and tell me what it reports?:

ConsoleWrite("_Network_InterfaceEntryInfo return, @error = " & @error & ", @extended = " & @extended & @CRLF)

Also, is there information reported to the console from the call to _Network_IPAllAddressTable() on?  I've tested this so far in 3 different VM environments, so I was hopeful..

[UEZ 1,435]

Sure.

Output:

_Network_InterfaceEntryInfo return, @error = 3, @extended = 2

Br,

UEZ

[Ascend4nt 137]

That is really really peculiar.  There's nothing in the documentation for GetIfEntry that mentions ERROR_FILE_NOT_FOUND (2), and in light of what the function does it really makes no sense to give that specific error.

I also asked if you had any console output from the call to _Network_IPAllAddressTable() onwards.  It seems it must return an array if it doesn't crash until _Network_InterfaceInfo()..  does the data look valid? Perhaps adding that ConsoleWrite() debug message after a call to that function could help as well.

The only thing I can guess right now is that there's an index # that isn't matching up somewhere..

thanks again for your help

[UEZ 1,435]

This is the complete output:

expandcollapse popup

IP [IPv4] Stats: [0]  = IP Forwarding Status: [1 = Enabled, 2 = Disabled] : 2, [1]  = Default initial time-to-live (TTL) for datagrams : 64
, [2]  = # Received Datagrams : 97579, [3]  = # Received Datagrams w/Header errors : 0, [4]  = # Received Datagrams w/Address errors : 14
, [5]  = # Forwarded Datagrams : 0, [6]  = # Received Datagrams w/Unknown Protocol : 0, [7]  = # Received Datagrams Discarded : 366
, [8]  = # Received Datagrams Delivered : 99864, [9]  = # Requested Outgoing Datagrams : 79017, [10] = # Outgoing Datagrams Discarded : 0
, [11] = # Transmitted Datagrams Discarded : 0, [12] = # Datagrams w/o Routes that were Discarded : 0, [13] = TimeOut for Reassembling Incoming Fragmented Datagrams : 60
, [14] = # Datagrams Requiring Reassembly : 0, [15] = # Datagrams Successfully Reassembled : 0, [16] = # Datagrams that Failed to be Reassembled : 0
, [17] = # Datagrams that were Fragmented Successfully : 0, [18] = # Datagrams not Fragmented, and Discarded : 0, [19] = # Fragments created (for Datagrams) : 0
, [20] = # of Interfaces : 6, [21] = # of IP addresses associated with PC : 43, [22] = # of Routes in the Routing table : 14
-----------------------------------------
IP [IPv6] Stats: [0]  = IP Forwarding Status: [1 = Enabled, 2 = Disabled] : 2, [1]  = Default initial time-to-live (TTL) for datagrams : 128
, [2]  = # Received Datagrams : 0, [3]  = # Received Datagrams w/Header errors : 0, [4]  = # Received Datagrams w/Address errors : 0
, [5]  = # Forwarded Datagrams : 0, [6]  = # Received Datagrams w/Unknown Protocol : 0, [7]  = # Received Datagrams Discarded : 111
, [8]  = # Received Datagrams Delivered : 0, [9]  = # Requested Outgoing Datagrams : 800, [10] = # Outgoing Datagrams Discarded : 0
, [11] = # Transmitted Datagrams Discarded : 0, [12] = # Datagrams w/o Routes that were Discarded : 8, [13] = TimeOut for Reassembling Incoming Fragmented Datagrams : 60
, [14] = # Datagrams Requiring Reassembly : 0, [15] = # Datagrams Successfully Reassembled : 0, [16] = # Datagrams that Failed to be Reassembled : 0
, [17] = # Datagrams that were Fragmented Successfully : 0, [18] = # Datagrams not Fragmented, and Discarded : 0, [19] = # Fragments created (for Datagrams) : 0
, [20] = # of Interfaces : 10, [21] = # of IP addresses associated with PC : 30, [22] = # of Routes in the Routing table : 13
-----------------------------------------
TCP [IPv4] Stats:[0] Rto Algorithm = 3,[1] Rto Min = 10,[2] Rto Max = 4294967295,[3] #Max Connections = 4294967295,[4] #Active Opens = 1656,[5] #Passive Opens = 17
 [6] #Failed Connection Attempts = 1508,[7] #Established Connections that were Reset = 359,[8] #Established Connections [current] = 26
 [9] #Recvd Segments = 95689,[10] #Sent Segments = 73938,[11] #Retransmitted Segments = 3735
 [12] #Receive Errors = 0,[13] #Sent Segments with Reset Flag = 2058,[14] #Connections = 87
-----------------------------------------
TCP [IPv6] Stats:[0] Rto Algorithm = 3,[1] Rto Min = 10,[2] Rto Max = 4294967295,[3] #Max Connections = 4294967295,[4] #Active Opens = 0,[5] #Passive Opens = 0
 [6] #Failed Connection Attempts = 0,[7] #Established Connections that were Reset = 0,[8] #Established Connections [current] = 0
 [9] #Recvd Segments = 0,[10] #Sent Segments = 0,[11] #Retransmitted Segments = 0
 [12] #Receive Errors = 0,[13] #Sent Segments with Reset Flag = 0,[14] #Connections = 59
-----------------------------------------
UDP [IPv4] Stats: [0] #Recvd Datagrams = 9163,[1] #Discarded Datagrams [invalid port] = 359,[2] #Erroneous Datagrams = 7
 [3] #Sent Datagrams = 4827,[4] #UDP Listener Entries = 27
-----------------------------------------
UDP [IPv6] Stats: [0] #Recvd Datagrams = 0,[1] #Discarded Datagrams [invalid port] = 111,[2] #Erroneous Datagrams = 0
 [3] #Sent Datagrams = 657,[4] #UDP Listener Entries = 7
-----------------------------------------
ICMP [IPv4] Stats: [0] = # Incoming ICMP Messages : 10, [1] = # Incoming ICMP Errors : 0, [2] = # Outgoing ICMP Messages : 13, [3] = # Outgoing ICMP Errors : 0
-----------------------------------------
ICMP [IPv6] Stats: [0] = # Incoming ICMP Messages : 0, [1] = # Incoming ICMP Errors : 0, [2] = # Outgoing ICMP Messages : 35, [3] = # Outgoing ICMP Errors : 0
-----------------------------------------
# of adapters: 5
Adapter Index #13, Name = \DEVICE\TCPIP_{F5C17D50-4BE2-4008-BA0A-76067ABE7DE2}
Adapter Index #849, Name = \DEVICE\TCPIP_{4CD51587-472C-41E3-B0FD-C92CDA50FB20}
Adapter Index #786, Name = \DEVICE\TCPIP_{B73941B0-2376-4882-B70B-76B0F0ED8209}
Adapter Index #787, Name = \DEVICE\TCPIP_{B08246C5-DAC4-4823-A0A2-BD3F077BF4CC}
Adapter Index #15, Name = \DEVICE\TCPIP_{D2D5B3E5-1958-4C19-A719-BC16A5ABB6C5}
-----------------------------------------
+ Added Interface (index #0), Intel(R) 82577LM Gigabit Network Connection
+ Added Interface (index #786), VMware Virtual Ethernet Adapter for VMnet1
+ Added Interface (index #787), VMware Virtual Ethernet Adapter for VMnet8
+ Added Interface (index #849), VirtualBox Host-Only Ethernet Adapter
+ Added Interface (index #862), Microsoft 6to4 Adapter
Interface #1: [0] Index #0, [1] Type = 6, [2] Operational Status = 1, [3] Flags = 0x000000C5, [4] Physical [MAC] Address: 88-AE-1D-B1-08-30, [5] MTU =  1500
, [6] Description: Intel(R) 82577LM Gigabit Network Connection, [7] Friendly Name: Local Area Connection, [8] Adapter/Service Name [GUID] = {F5C17D50-4BE2-4008-BA0A-76067ABE7DE2}
, [9] Max Receive Speed [Vista+] = 100000000, [10] Max Transmit Speed [Vista+] = 100000000
, [11] IPv4 Address(es): 168.185.212.21, [12] IPv6 Address(es): 
, [13] Connection Type [Vista+] = 1, [14] Tunnel Type [Vista+] = 0
_Network_InterfaceEntryInfo return, @error = 3, @extended = 2
C:\_Downloads\NetworkStatistics.au3 (1268) : ==> Subscript used with non-Array variable.:
ConsoleWrite("Interface #"&$i+1&" Entry Info: [0] Interface Index = " & $aNIEntryInfo[0] & ", [1] Interface Type = " & $aNIEntryInfo[1] & ", [2] Operational Status = " & $aNIEntryInfo[2] & ", [3] Admin Status = " & $aNIEntryInfo[3] & ", [4] Physical Address = " & $aNIEntryInfo[4] & ", [5] MTU [Max Trans. Unit] in bytes = " & $aNIEntryInfo[5] & @CRLF & ", [6] Description = " & $aNIEntryInfo[6] & ", [7] Interface Name = " & $aNIEntryInfo[7] & @CRLF & ", [8] Last change [1/100th second] = " & $aNIEntryInfo[8] & ", [9] Interface Speed [bps] = " & $aNIEntryInfo[9] & @CRLF & ", [10] # Recvd Data [in Octets] = " & $aNIEntryInfo[10] & ", [11] # Recvd Unicast Packets = " & $aNIEntryInfo[11] & ", [12] # Recvd Non-Unicast Packets = " & $aNIEntryInfo[12] & ", [13] # Recvd Packets Discarded [no error] = " & $aNIEntryInfo[13] & ", [14] # Recvd Packets Discarded [error] = " & $aNIEntryInfo[14] & ", [15] # Recvd Packets Discarded [unk. protocol] = " & $aNIEntryInfo[15] & @CRLF & ", [16] # Sent Data [in Octets] = " & $aNIEntryInfo[16] & ", [17] # Sent Unicast Packets = " & $aNIEntryInfo[17] & ", [18] # Sent Non-Unicast Packets = " & $aNIEntryInfo[18] & ", [19] # Sent Packets Discarded [no error] = " & $aNIEntryInfo[19] & ", [20] # Sent Packets Discarded [error] = " & $aNIEntryInfo[20] & @CRLF & ", [21] Transmit Queue Length [n/a] = " & $aNIEntryInfo[21] & @CRLF)
ConsoleWrite("Interface #"&$i+1&" Entry Info: [0] Interface Index = " & $aNIEntryInfo^ ERROR
->11:51:04 AutoIt3.exe ended.rc:1

Br,

UEZ

Edited July 3, 2013 by UEZ

[Ascend4nt 137]

Thanks, I'm gonna review it and see if there's something askew.  I haven't seen an index # 0 yet, so that's curious..

[Ascend4nt 137]

Okay, apparently that 0 index is wrong and should be 13.  I *believe* this is due to my checks against IPv6Index.  Could you possibly locate the line

               " If $nIPAAStSize > 108 Then    ; XP SP1+ O/S Structure?"

and change that and the whole IF-Endif to read this:

                If $nIPAAStSize > 108 Then    ; XP SP1+ O/S Structure?
                    ; If IPv6 index is different than IPv4 Index, AND non-zero, use the latter
                    $nTemp = DllStructGetData($stIP_ADAPTER_ADDRESSES, "Ipv6IfIndex")
                    If $nTemp And $nTemp <> $aIPAddrTableEntries[$nNumEntries][0] Then
                        $aIPAddrTableEntries[$nNumEntries][0] = $nTemp
                    EndIf
                EndIf

Hopefully that would fix the problem.  I'm still not even sure if its worth checking Ipv6IfIndex yet, so I may modify that in the future.  However, the above code at least tests for a 0 condition, and won't change an index if Ipv6IfIndex is 0.

Thanks!

[UEZ 1,435]

Cool, no em anymore. 

Br,

UEZ

[Ascend4nt 137]

nice!  New version uploaded!  Thx for the help spotting the error

Edited July 3, 2013 by Ascend4nt

[setengahgila 0]

I Got Eror..

When I'm Disconnect Modem..

LINE 1340

$sSplashText &=StringFormat("%45,56s", $aNIEntryInfo[6] & @CRLF
$sSplashText &=StringFormat("%45,56s", $aNIEntryInfo^ ERROR
     
Error: Subscript used with non-Array variable

Edited July 4, 2013 by setengahgila

[Ascend4nt 137]

I Got Eror..

When I'm Disconnect Modem..

....

 

A modem?! Really?    I thought those were all gone by now haha..

But anyway.. to the problem.  If you disconnect or disable a network interface, the index # assigned to it will fail to work, or possibly be reassigned when the device is reenabled.  But, just to be thorough here.. could you please insert this code and let me know what it reports when you disconnect the modem:

        $aNIEntryInfo = _Network_InterfaceEntryInfo($aIPAllAddrTable[$i][0])
        If @error Then
            ConsoleWrite("_Network_InterfaceEntryInfo return, @error = " & @error & ", @extended = " & @extended & @CRLF)
            ExitLoop
        EndIf

That goes in the For $i = 0 To $nIPs - 1 loop, line 1334.  It *should* return error code ERROR_NOT_FOUND (1168), if I understand it correctly.

The only way to get around the problem of disconnected devices is to rescan for devices using _Network_IPAllAddressTable().  But before we go there, it'd be good to see what kind of error code is returned.

Thanks for your help

[Ascend4nt 137]

Updated today - version 3 (by my reckoning)!  This is now a full fledged Network Interface Information and Statistics UDF module.

2013-07-06:

 Added: Much more Adapter Information

 Changed: Example is now separate from the UDF

 Fixed some minor issues here and there

 Changed: Global Handle to IPHLPAPI.DLL is now contained in the UDF and used to speed up function calls

 Misc. Other fixes I didn't keep track of!

See 1st post, which is now a bit more detailed