VBS to Auto-IT

[Reekod 1]

Hi all,

is someone have the knowledge (and the time) to convert this vbs in auto-it ? a lot of people will learn a lot with this example.

expandcollapse popup

SET objRootDSE = GETOBJECT("LDAP://RootDSE") 
strExportFile = "C:\temp\MyExport.xls"  
 
strRoot = objRootDSE.GET("DefaultNamingContext") 
strfilter = "(&(objectCategory=Person)(objectClass=User))" 
strAttributes = "sAMAccountName,userPrincipalName,givenName,sn," & _ 
                                "initials,displayName,physicalDeliveryOfficeName," & _ 
                                "telephoneNumber,mail,wWWHomePage,profilePath," & _ 
                                "scriptPath,homeDirectory,homeDrive,title,department," & _ 
                                "company,manager,homePhone,pager,mobile," & _ 
                                "facsimileTelephoneNumber,ipphone,info," & _ 
                                "streetAddress,postOfficeBox,l,st,postalCode,c" 
strScope = "subtree" 
SET cn = CREATEOBJECT("ADODB.Connection") 
SET cmd = CREATEOBJECT("ADODB.Command") 
cn.Provider = "ADsDSOObject" 
cn.Open "Active Directory Provider" 
cmd.ActiveConnection = cn 
 
cmd.Properties("Page Size") = 1000 
 
cmd.commandtext = "<LDAP://" & strRoot & ">;" & strFilter & ";" & _ 
                                   strAttributes & ";" & strScope 
 
SET rs = cmd.EXECUTE 
 
SET objExcel = CREATEOBJECT("Excel.Application") 
SET objWB = objExcel.Workbooks.Add 
SET objSheet = objWB.Worksheets(1) 
 
FOR i = 0 To rs.Fields.Count - 1 
                objSheet.Cells(1, i + 1).Value = rs.Fields(i).Name 
                objSheet.Cells(1, i + 1).Font.Bold = TRUE 
NEXT 
 
objSheet.Range("A2").CopyFromRecordset(rs) 
objWB.SaveAs(strExportFile) 
 
 
rs.close 
cn.close 
SET objSheet = NOTHING 
SET objWB =  NOTHING 
objExcel.Quit() 
SET objExcel = NOTHING 
 
Wscript.echo "Script Finished..Please See " & strExportFile

[water 2,384]

No need to convert the code

Please have a look at my Active Directory UDF (for download please see my signature).

Have a look at example script _AD_GetObjectsInOU.au3 and help file _AD_GetObjectsInOU.html. That should give you an idea how it works.

If you have questions there is a "Help & Support thread" for the UDF (please see my signature).

Edited July 5, 2011 by water

[Reekod 1]

Great Job

Thx a lot !

have nice day