Change/Merge Array

[goss34]

Hi Guys,

I am hoping someone can help me merge 2 arrays or more precisely change 1 array to another type but honestly i havent grasped the full concept of how it all fits together yet so am struggling.

My current code relies on me setting variables in the script for the computers i want to process the full script against but this means i will need to re-write it to add additional PC's as and when required. See below:

Global $oErrorHandler = ObjEvent("AutoIt.Error", "ObjErrorHandler")
Global $aComputer[3][2] =[["LocalHost", ""], ["PC44444", ""],["PC66666", ""]] ;2D array whereas 1st entry is the hostname and 2nd entry is for the status
Global $status, $result
For $i = 0 To UBound($aComputer) - 1
    $status = WMI_ProcessExits($aComputer[$i][0], "explorer.exe")
    Switch $status
        Case 0
            $aComputer[$i][1] = "Available"
        Case 1
            $aComputer[$i][1] = "Busy"
        Case Else
            $aComputer[$i][1] = "Unknown"
    EndSwitch
    _GUICtrlListView_AddItem($hListview, $aComputer[$i][0], $i)
    _GUICtrlListView_AddSubItem($hListview, $i, $aComputer[$i][1], 1)
Next

Here is the snippet i found in the help files where it reads a text file into an array:

#include <file.au3>
Dim $aRecords
_FileReadToArray("C:\temp\Error.log",$aRecords)
For $x = 1 to $aRecords[0]
Msgbox(0,'Record:' & $x, $aRecords[$x])
Next

Can someone write me a little example of how i can replace the array with this?

Thank you

[water]

To make your script more flexible I would do the following:

• Put the names of the PCs to check in an INI file. So you can easily add/remove PCs
• With IniReadSection you can read all of them into an array
• Create a second array with the size of the first array. This second array holds the status

Ini File:

[PC]

PC=LocalHost

PC=PC44444

PC=PC66666

Code:

$aPCs = InIReadSection("PC.ini", "PC")
$aStatus[$aPCs[0][0]]
For $iIndex = 1 to $aPCs[0][0]
  $aStatus[$iIndex] = Status of PC as stored in $aPCs[$iIndex][1]
Next

Edited November 2, 2011 by water

[Melba23]

goss34,

Unfortunately you cannot use ReDim to increase the number of dimensions of an array, so you have to use a loop.

I used this text file saved to the script folder:

LocalHost
PC44444
PC66666

and then this script to get the names into a 2D array:

#include <Array.au3> ; Just for display later

#include <File.au3>

; Read in the text list of PCs
Global $aPCs
_FileReadToArray("List.txt",$aPCs)

; Create the 2D array to match the number of PCs in the list
Global $aComputer[$aPCs[0] + 1][2]

; Transfer the PC names to the 2D array
For $i = 1 To $aPCs[0]
    $aComputer[$i][0] = $aPCs[$i]
Next

; And this is what you get
_ArrayDisplay($aComputer)

All clear? Please ask if not.

M23

[goss34]

Hi Melba,

I have had a look and tried to adjust my script and it almost seems to work but the listview doesnt show the status in the "Status" Column. I think this could have something to do wiith the UBound line but i honestly dont know what this line is doing so am unsure how to correct it.

Here is the code:

Global $aPCs
_FileReadToArray("\\psn001\transfer\list.txt",$aPCs) ; Read in the text list of PCs
Global $aComputer[$aPCs[0] + 1][2] ; Create the 2D array to match the number of PCs in the list
For $i = 1 To $aPCs[0] ; Transfer the PC names to the 2D array
    $aComputer[$i][0] = $aPCs[$i]
;Next
;Global $aComputer[15][2] =[[$PC1, ""], [$PC2, ""],[$PC3, ""], [$PC4, ""], [$PC5, ""], [$PC6, ""], [$PC7, ""], [$PC8, ""], [$PC9, ""], [$PC10, ""], [$PC11, ""], [$PC12, ""], [$PC13, ""], [$PC14, ""], [$PC15, ""]] ;2D array whereas 1st entry is the hostname and 2nd entry is for the status
;For $i = 0 To UBound($aComputer) -1
    $status = WMI_ProcessExits($aComputer[$i][0], "explorer.exe")
    Switch $status
        Case 0
            $aComputer[$i][1] = "Available"
        Case 1
            $aComputer[$i][1] = "Busy"
        Case Else
            $aComputer[$i][1] = "Unknown"
EndSwitch
    _GUICtrlListView_AddItem($hListview, $aComputer[$i][0], $i)
    _GUICtrlListView_AddSubItem($hListview, $i, $aComputer[$i][1], 1)
Next
Do

I have followed the snippet you added but it is going way over my head, with your explanations i know what each line (or almost all) is doing but what i am lacking is the knowledge of how the commands work for example this section:

Global $aComputer[$aPCs[0] + 1][2]

And this section:

For $i = 1 To $aPCs[0]
    $aComputer[$i][0] = $aPCs[$i]
Next

What i am missing is what exactly the $i = 1 means? and the [0] at the end of the For line.

Hopefully you can see why i am struggling but i havent found any help in the help section that actually explains how all the variables work - this is what is causing me issues as i dont fully understand how the array works.

Thank you

Edited November 2, 2011 by goss34

[Melba23]

goss34,

I see no reason why the code should not work - try putting in some errorchecking to see if you are getting the correct values returned. Add this line after the EndSwitch:

ConsoleWrite($aComputer[$i][0] & " - " & $aComputer[$i][1] & @CRLF)

Then you will be able to see what values you are getting into your array.

what i am lacking is the knowledge of how the commands work

That is why we are here!

Global $aComputer[$aPCs[0] + 1][2]

_FileReadToArray returns the number of items read in the [0] element - quite a lot of AutoIt functions do this. When we create a 2D array to hold the PC name and status we need to make it big enough - we can use this counter to do so. But the array is actually 1 element longer than the count as we need to add in the count as well. So we size the array to the count + 1 - as the code above shows.

For $i = 1 To $aPCs[0]
    $aComputer[$i][0] = $aPCs[$i]
Next

This is a simple For...Next loop. The For line sets the beginning and end values of the variable which will be used as a count. You can give the variable any name you like - by convention most people use $i as the variable itself serves no purpose outside the loop and so there is no requirement to save it.

Once the loop starts the code inside it is actioned (unless the end value you set is already less than the start value). When the Next line is reached the count variable $i is increased (by 1 unless you define a different Step value in the For line) and compared to the end value. If it is greater than the end value the loop stops and the code continues - if not then the code inside the loop is run again with the new value of the count variable.

As you can see, a For...Next loop lets you action the elements of an array very simply - just use the count variable as the array index.

All clear?

M23

[goss34]

Hi Melba,

I am not going to say its all clear but i think once i have finished or corrected this script how i want it i will start another completely fresh and work using the help file and your explanations here and i think it will begin to make a bit more sense.

Adding the below line:

ConsoleWrite($aComputer[$i][0] & " - " & $aComputer[$i][1] & @CRLF)

Works lovely and returns:

LocalHost - Busy

PC55555 - Busy

PC55556 - Available

So it is still working just not writing the lines into the listview like it should. Any ideas?

Here is the full code i am using/writing: (shows where i create the list view etc)

expandcollapse popup

#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListView.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <ButtonConstants.au3>
#include <TreeviewConstants.au3>
#include <GuiButton.au3>
#include <Array.au3>
#include <File.au3>

AutoItSetOption("TrayAutoPause", 0)                                                                                                                            ; Disables pause option

FileInstall("C:\remote-desktop-client.ico", @TempDir & "\remote-desktop-client.ico")                                                                        ; Install required files
TraySetIcon (@TempDir & "\remote-desktop-client.ico")                                                                                                        ; Set tray icon
FileInstall("C:\System-Restore-Icon.bmp", @TempDir & "\System-Restore-Icon.bmp")

;SplashImageOn("Checking available connections...", @TempDir & "\System-Restore-Icon.bmp", 256, 256)                                                             ; Show splash screen while hosts are queried

$PC1 = "PC32574"                                                                                                                                             ; Specify hosts to query
$PC2 = "PC55555"
$PC3 = "PC55556"
$PC4 = "Localhost"
$PC5 = "Localhost"
$PC6 = "Localhost"
$PC7 = "Localhost"
$PC8 = "pc44444"
$PC9 = "Localhost"
$PC10 = "Localhost"
$PC11 = "Localhost"
$PC12 = "Localhost"
$PC13 = "Localhost"
$PC14 = "Localhost"
$PC15 = "Localhost"

$font = "Comic Sans MS"                                                                                                                                     ; Specify font to be called



$hGUI = GUICreate("RDP Broker", 1264, 810, -1, -1,  $WS_OVERLAPPEDWINDOW + $WS_CLIPSIBLINGS, $WS_EX_ACCEPTFILES)                                            ; Create gui window



GUISetHelp("notepad")                                                                                                                                         ; Write a help file for the application - currently set to launch notepad
GUISetFont(9, 600, 0, $font)                                                                                                                                ; Set font in GUI
GUICtrlSetDefColor(0xFF0000)                                                                                                                                ; Set default text colour
GUICtrlCreateLabel("Select an available PC " & @LF & _                                                                                                        ; Create text label
                                "**BlankSpace**", 10, 10)
GUICtrlSetColor(-1, 0x000000)                                                                                                                                ; Set colour of text
$oRDP = ObjCreate("MsTscAx.MsTscAx.2")                                                                                                                         ; http://msdn.microsoft.com/en-us/library/aa381344(v=VS.85).aspx
$oRDP_Ctrl = GUICtrlCreateObj($oRDP, 230, 20, 1024, 768)

GUICtrlSetStyle($oRDP_Ctrl , $WS_VISIBLE)
GUISetFont(9, 500, 0, $font)



$listview =  GUICtrlCreateListView("PC Name|Status            ", 10, 46, 210, 343, BitOR($LVS_REPORT, $LVS_SINGLESEL, $LVS_NOSORTHEADER, $TVS_NOSCROLL))    ; Remove scroll bar in list view
;GUICtrlCreateListView("Header", 10, 10, 125, 307, BitOR($LVS_REPORT, $LVS_SINGLESEL, $LVS_NOSORTHEADER, $TVS_NOSCROLL))
_GUICtrlListView_SetColumnWidth($listview, 0, 108)                                                                                                             ; Set column width in list view
ControlDisable($hGUI, "", HWnd(_GUICtrlListView_GetHeader($ListView)))                                                                                         ; Disables resizing colums in list view



$hListview = GUICtrlGetHandle($listview)
GUISetFont(9, 600, 0, $font)

$rdp = GUICtrlCreateButton("Connect", -1, 400, 210, 40, $BS_BITMAP)

GUICtrlSetColor(-1, 0x000000)
GUICtrlCreatePic("C:\System-Restore-Icon.bmp", -1, 600, 200, 200)
;GUISetState()


Global $oErrorHandler = ObjEvent("AutoIt.Error", "ObjErrorHandler")
Global $status, $result
Global $aPCs
_FileReadToArray("\\psn001\transfer\list.txt",$aPCs)                                         ; Read in the text list of PCs
Global $aComputer[$aPCs[0] + 1][2]                                                             ; Create the 2D array to match the number of PCs in the list
For $i = 1 To $aPCs[0]                                                                         ; Transfer the PC names to the 2D array
    $aComputer[$i][0] = $aPCs[$i]
;Next

;Global $aComputer[15][2] =[[$PC1, ""], [$PC2, ""],[$PC3, ""], [$PC4, ""], [$PC5, ""], [$PC6, ""], [$PC7, ""], [$PC8, ""], [$PC9, ""], [$PC10, ""], [$PC11, ""], [$PC12, ""], [$PC13, ""], [$PC14, ""], [$PC15, ""]] ;2D array whereas 1st entry is the hostname and 2nd entry is for the status
;For $i = 0 To UBound($aComputer) -1
    $status = WMI_ProcessExits($aComputer[$i][0], "explorer.exe")
    Switch $status
        Case 0
            $aComputer[$i][1] = "Available"
        Case 1
            $aComputer[$i][1] = "Busy"
        Case Else
            $aComputer[$i][1] = "Unknown"
        EndSwitch
        ConsoleWrite($aComputer[$i][0] & " - " & $aComputer[$i][1] & @CRLF)
    _GUICtrlListView_AddItem($hListview, $aComputer[$i][0], $i)
    _GUICtrlListView_AddSubItem($hListview, $i, $aComputer[$i][1], 1)
Next
Do
    SplashOff()    
    GUISetState(@SW_SHOW, $hGui)
    $msg =   GUIGetMsg()
    Switch $msg
        Case $rdp
            $selection = _GUICtrlListView_GetSelectedIndices($hListview, False)
            $host = _GUICtrlListView_GetItemText($hListview, $selection)
            $status = _GUICtrlListView_GetItemText($hListview, $selection, 1)
            If $status <> "Unknown" And $status <> "Busy" Then
                $oRDP.DesktopWidth = 1024
                $oRDP.DesktopHeight = 768
                $oRDP.Fullscreen = False
                $oRDP.ColorDepth = 16
                $oRDP.AdvancedSettings3.SmartSizing = True
                $oRDP.Server = $host
                $oRDP.UserName = @Username ;<<<<<<< enter here the user name
                $oRDP.Domain = @LogonDomain
                $oRDP.AdvancedSettings2.ClearTextPassword = ""
                $oRDP.ConnectingText = "Connecting to " & $host
                $oRDP.DisconnectedText = "Disconnected from " & $host
                $oRDP.StartConnected = True
                $oRDP.Connect()
            Else
                MsgBox(48, "Information", $host & " is busy or unknown")
            EndIf
    EndSwitch
Until $msg = $GUI_EVENT_CLOSE
$oRDP.Disconnect()
Exit

Func WMI_ProcessExits($host, $processname, $usr = "", $pass = "") ;coded by UEZ 2011
    If $host = "." Or $host = "localhost" Or $host = @IPAddress1 Or $host = @ComputerName Then
        If ProcessExists($processname) Then Return 1
        Return 0
    Else
        Local $ping = Ping($host, 1000)
        If @error Then Return SetError(1, 0, -1) ; Host not pingable
        Local $objWMILocator = ObjCreate("WbemScripting.SWbemLocator")
        Local $objWMIService = $objWMILocator.ConnectServer($host, "\root\cimv2", $usr, $pass, "", "", "&H80")
        If @error Then Return SetError(3, 0, -1)
        Local $colItems = $objWMIService.ExecQuery("SELECT Name FROM Win32_Process WHERE Name='" & $processname & "'", "WQL", 0x30)
        If IsObj($colItems) Then
            For $objItem In $colItems
                If $objItem.Name <> "" Then Return 1
            Next
        Else
            Return SetError(4, 0, -1)
        EndIf
        Return 0
    EndIf
EndFunc   ;==>WMI_ProcessExits

Func ObjErrorHandler()
    ConsoleWrite("A COM Error has occured!" & @CRLF & @CRLF & _
            "err.description is: " & @TAB & $oErrorHandler.description & @CRLF & _
            "err.windescription:" & @TAB & $oErrorHandler & @CRLF & _
            "err.number is: " & @TAB & Hex($oErrorHandler.number, 8) & @CRLF & _
            "err.lastdllerror is: " & @TAB & $oErrorHandler.lastdllerror & @CRLF & _
            "err.scriptline is: " & @TAB & $oErrorHandler.scriptline & @CRLF & _
            "err.source is: " & @TAB & $oErrorHandler.source & @CRLF & _
            "err.helpfile is: " & @TAB & $oErrorHandler.helpfile & @CRLF & _
            "err.helpcontext is: " & @TAB & $oErrorHandler.helpcontext & @CRLF _
            )
EndFunc   ;==>ObjErrorHandler

Thank you

Edited November 2, 2011 by goss34

[Melba23]

goss34,

You are mixing native and UDF functions when writing to your ListView - usually a recipe for tears.

As you create the ListView with the native function, use the native function to fill it as well:

GUICtrlCreateListViewItem($aComputer[$i][0] & "|" & $aComputer[$i][1], $listview)
;_GUICtrlListView_AddItem($hListview, $aComputer[$i][0], $i)
;_GUICtrlListView_AddSubItem($hListview, $i, $aComputer[$i][1], 1)

I get the 2 values displayed when I do that.

M23

[goss34]

Thank you Melba you are a superstar!

Unfortunately whenever i am scripting it is a massive recipe for tears

With that adjustment it works exactly like it should. One more question you may know the answer to while i have your attention.

The whole GUI this script creates can be resized but if you resize it the embedded object stays the same size and it completely messes it up. I have been scouring the forums for a way to fix the GUI size so it cannot be adjusted in as few lines of code as possible (this way i should understand it). Ideally the resize feature would resize every item but i think that would be far too much trouble for me to write as i have no idea where to begin - obviously preferred because at the moment the default size could be too big for someones screen resolution.

Can you help with that?

Thank you

[Melba23]

goss34,

The whole GUI this script creates can be resized

...

a way to fix the GUI size so it cannot be adjusted

Just create the GUI to be non-resizable.

Post the GUICreate line you are using and we will see what styles you need to omit/add.

M23

[goss34]

HI Melba,

O believe me i have tried just didnt get anywhere unfortunately.

Here is the GuiCreate:

$hGUI = GUICreate("RDP Broker", 1264, 810, -1, -1,  $WS_OVERLAPPEDWINDOW + $WS_CLIPSIBLINGS, $WS_EX_ACCEPTFILES)                                            ; Create gui window

Thank you

[Melba23]

goss34,

Rsizing must be something inherent in the combnation of styles you are using. So we need to get rid of it like this:

$hGUI = GUICreate("RDP Broker", 1264, 810, -1, -1,  BitOr($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS, BitNOT($WS_SIZEBOX)), $WS_EX_ACCEPTFILES)
;

That works for me.

Note the use of BitOR to combine styles - read the Setting Styles tutorial in the Wiki to find out why.

M23

[goss34]

Hi Melba,

As i expected it worked first time so thank you very much!

All i need now if your direct contact details for next time i have a problem

Thank you so much for everything, i now just need to tidy the GUI up and make it a bit nicer looking.

Thanks again

P.S. Thank you "Water" for your response to my initial issue.

[Melba23]

goss34,

All i need now if your direct contact details for next time i have a problem

This will usually find me.

M23