GUICtrlSetData not update the control

[hezi]

Hello All,

Im trying to update the date control using "GUICtrlSetData (-1,"19:00:00")" (line 10)

but somehow it ignore and not updating the control data.

what im doing wrong?

Thanks in advance.

#include <GUIConstantsEx.au3>
#include <DateTimeConstants.au3>
Opt('MustDeclareVars', 1)

Example4()
Func Example4()
Local $n, $msg ,$gui ,  $y
$gui= GUICreate("My GUI get time", 200, 200, 800, 200)
$n = GUICtrlCreateDate("20:20:21", 20, 20, 100, 20, $DTS_TIMEFORMAT)
$y = GUICtrlSetData (-1,"19:00:00")
MsgBox(0,@error,$y) ; Debug
GUISetState()
; Run the GUI until the dialog is closed
Do
  $msg = GUIGetMsg()
Until $msg = $GUI_EVENT_CLOSE
MsgBox(0, "Time", GUICtrlRead($n))
GUIDelete()
EndFunc   ;==>Example4

Edited November 30, 2011 by hezi

[water]

You have to specify date AND time:

#include <GUIConstantsEx.au3>
#include <DateTimeConstants.au3>
Opt('MustDeclareVars', 1)

Example4()
Func Example4()
    Local $n, $msg, $gui, $y
    $gui = GUICreate("My GUI get time", 200, 200, 800, 200)
    $n = GUICtrlCreateDate("20:20:01", 20, 20, 100, 20, $DTS_TIMEFORMAT)
    $y = GUICtrlSetData($n, "2011/11/30 19:00:00")
    GUISetState()
    ; Run the GUI until the dialog is closed
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example4

Edited November 30, 2011 by water

[hezi]

Thanks!

it works for me.

still dont understand why create and get commands are working with time only. and update require date.

[water]

Maybe because the style ($DTS_TIMEFORMAT) only applies to the way the data is displayed and returned but internally the control works with date AND time and the update function has to update the internal representation.

[hezi]

got it!

Thanks...