A simple window

[Dazzler]

People,

I have had no success with the Windowsconstants.

I need a tiny, teeny GUI. No minimize, maximise, captions etc. Just a 3 by 3.

Failing that. Is it possible to have a GUI where the GUI background is transparent ie anything behind shows through?

Thank you.

[water]

Maybe is a starting point?

[Melba23]

Dazzler,

Not that difficult:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

HotKeySet("{ESC}", "On_Exit")

; Invisible GUI
$hGUI_1 = GUICreate("Invisible", 200, 200, -1, -1, $WS_POPUP, $WS_EX_LAYERED)
GUISetBkColor(0xABCDEF)
GUICtrlCreateLabel("Click on the text to drag this transparent GUI" & @CRLF & "Press ESC to exit", 10, 10)
_WinAPI_SetLayeredWindowAttributes($hGUI_1, 0xABCDEF, 250)
GUISetState()

; Very small GUI
$hGUI_2 = GUICreate("Small", 3, 3, -1, -1, $WS_POPUP)
GUISetBkColor(0xFF0000) ; Colour red so you can see it
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_PRIMARYDOWN
            _SendMessage($hGUI_1, $WM_SYSCOMMAND, 0xF012, 0)
    EndSwitch
WEnd

Func On_Exit()
    Exit
EndFunc

I would suggest a white background to see them clearly.

Is that what you wanted?

M23