Anyway to make ProgressOn work for adding users into AD from a csv file

[xinx]

Hi all.

The following script gets a list of users from a csv file and then adds them into Active Directory.

$SelectedFile = "C:\Temp\Users.csv"
$csv = 0
_FileReadToArray($SelectedFile, $csv)
ProgressOn("Csv import", "Adding and creating users", "Please wait...", 16)
For $i=1 to Ubound($csv)-1
  Sleep(200)
  $record=StringSplit($csv[$i],",")
  $sCommonName = $record[3] & " " & $record[2]
  $sUser = $record[1]
  _AD_Open()
    $iValue = _AD_CreateUser($sOU, $record[1], $sCommonName)
  _AD_Close()
  ProgressSet($i, "User: " & $record[1] & " successfully added")
  Sleep(200)
Next
  ProgressSet(100, "Users imported successfully.")
  Sleep(750)
  ProgressOff()

This works, however what I am trying to achieve is a more accurate percentage bar. Somehow, the script should work out the amount of lines in the csv file, turn the number of lines into 100% and for each user move the percent bar. I.e., if there were 100 users, the percent bar would move by 10% for every user added.

Any help greatly appreciated. Although all I can offer is a smiley face

[DW1]

Try and change

ProgressSet($i, "User: " & $record[1] & " successfully added")

to

ProgressSet($i/(UBound($csv) - 1) * 100, "User: " & $record[1] & " successfully added")

[xinx]

Genius sir! Thank you. And love the profile pic btw.

Edit: I know it probably seemed like a simple math equation, but math is not my strong point. Nor is anything really!

Edited March 13, 2012 by xinx

[UEZ]

I wrote some time ago some AD Tools. Might be useful for you!

Br,

UEZ

[water]

To enhance performance I would move some of the code outside of the loop. Plus some error checking might be helpful.

#include <AD.au3>
#include <file.au3>
Global $SelectedFile = "C:TempUsers.csv"
Global $sOU = "", $csv
_FileReadToArray($SelectedFile, $csv)
If @error Then Exit MsgBox(16, "Adding and creating users", "Error " & @error & " reading file " & $SelectedFile)
_AD_Open()
If @error Then Exit MsgBox(16, "Adding and creating users", "Error " & @error & " opening conection to Active Directory")
ProgressOn("Csv import", "Adding and creating users", "Please wait...", 16)
For $i = 1 To UBound($csv) - 1
    ; Sleep(200) ; Not needed
    $record = StringSplit($csv[$i], ",")
    $sCommonName = $record[3] & " " & $record[2]
    $sUser = $record[1]
    $iValue = _AD_CreateUser($sOU, $record[1], $sCommonName)
    If @error Then MsgBox(16, "Adding and creating users", "Error " & @error & " when creating user " & $record[1] & " - " & $sCommonName)
    ProgressSet($i, "User: " & $record[1] & " successfully added")
    ; Sleep(200) ; Not needed
Next
_AD_Close()
ProgressSet(100, UBound($csv) - 1 & " users imported successfully.")
Sleep(750)
ProgressOff()

Edited March 14, 2012 by water

[xinx]

Wow thanks all. Exactly what I needed!