SOLVED Help getting $variable = "" in to a dropdown list using GUICtrlCreateCombo and GUICtrlSetData

[mdcastle]

Please could someone help!

I'm creating a GUI Script that allows a user to match a drop-down list of address fields to the corresponding field in a system I manage (see sample script below).

The problem is that some of the options in the drop-down list may be blank. When the script creates the drop-down lists in the GUI, if the variable is blank that option and the one above do not show. As soon as I declare some text in the variable the GUI shows the options correctly

expandcollapse popup

#include <GUIconstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIcoordMode", 2)
;****************************************************************************************
;* The 5 lines below will not form part of final script                              *
;* $rAddress1, 2, 3, 4, $rPostCode will be populated by cells from an Excel spreadsheet *
;****************************************************************************************
Global $rAddress1 = "1 Some Street"
Global $rAddress2 = "" ; <----- If some text between the quotes here, the GUI Shows the drop-down options correctly.
Global $rAddress3 = "ATown"
Global $rAddress4 = "ACounty"
Global $rPostCode = "AA1 1AA"
Global $add1 = $rAddress1
Global $add2 = $rAddress2
Global $add3 = $rAddress3
Global $add4 = $rAddress4
Global $pc = $rPostCode
Global $array[5]
$array[0] = $add1
$array[1] = $add2
$array[2] = $add3
$array[3] = $add4
$array[4] = $pc
GUICreate("Address Selecter", 280, 230)
GUIStartGroup()
Global $widthCell = 125
; Address 1 option
GUICtrlCreateLabel("Marketplace Address 1", 10, 10, $widthCell)
Global $sAddress1 = GUICtrlCreateCombo("", 0, -1)
For $i=0 to ubound($array) -1
    GUICtrlSetData(-1, $array[$i])
NEXT
; Address 2 option
GUICtrlCreateLabel("Marketplace Address 2", -2 * $widthCell, 10)
Global $sAddress2 = GUICtrlCreateCombo("", 0, -1)
For $i=0 to ubound($array) -1
    GUICtrlSetData(-1, $array[$i])
NEXT
; City option
GUICtrlCreateLabel("Marketplace City", -2 * $widthCell, 10)
Global $sCity = GUICtrlCreateCombo("", 0, -1)
For $i=0 to ubound($array) -1
    GUICtrlSetData(-1, $array[$i])
NEXT
; County option
GUICtrlCreateLabel("Marketplace County", -2 * $widthCell, 10)
Global $sCounty = GUICtrlCreateCombo("", 0, -1)
For $i=0 to ubound($array) -1
    GUICtrlSetData(-1, $array[$i])
NEXT
; Post Code option
GUICtrlCreateLabel("Marketplace Post Code", -2 * $widthCell, 10)
Global $sPostCode = GUICtrlCreateCombo("", 0, -1)
For $i=0 to ubound($array) -1
    GUICtrlSetData(-1, $array[$i], $array[4])
NEXT
Global $button_1 = GUICtrlCreateButton ("Ok", -1, 20, 120, 35)
GUISetState()
While 1
$msg = GUIGetMsg()
Select
  Case $msg = $GUI_EVENT_CLOSE
  SplashTextOn("Exiting", "Exiting the script.  Please re-run", 190, 100, -1, -1, 4, "", -1, 1000)
  Sleep(1500)
  SplashOff()
  Exit
  Case $msg = $button_1
   ExitLoop
EndSelect
WEnd
msgbox(0, "Selected Address", "Address1: " & GUICtrlRead($sAddress1) & " | Address2: " & GUICtrlRead($sAddress2) & " | City: " & GUICtrlRead($sCity) & " | County: " & GUICtrlRead($sCounty) & " | Post Code: " & GUICtrlRead($sPostCode))
GUIDelete()

Many thanks in advance.

Edited May 16, 2012 by mdcastle

[water]

Try

Global $rAddress2 = " " ; <----- If some text between the quotes here, the GUI Shows the drop-down options correctly.

[Melba23]

mdcastle,

What a complicated way to fill your combos!

Anyway, if you want a blank element in your combo list, you need to fill it all in one go like this:

expandcollapse popup

#include <guiconstants.au3>
#include <comboconstants.au3>
#include <editconstants.au3>
#include <windowsconstants.au3>

Opt("GUIcoordMode", 2)
;****************************************************************************************
;* The 5 lines below will not form part of final script                           *
;* $rAddress1, 2, 3, 4, $rPostCode will be populated by cells from an Excel spreadsheet *
;****************************************************************************************
Global $rAddress1 = "1 Some Street"
Global $rAddress2 = "" ; <----- If some text between the quotes here, the GUI Shows the drop-down options correctly.
Global $rAddress3 = "ATown"
Global $rAddress4 = "ACounty"
Global $rPostCode = "AA1 1AA"
Global $add1 = $rAddress1
Global $add2 = $rAddress2
Global $add3 = $rAddress3
Global $add4 = $rAddress4
Global $pc = $rPostCode

Global $array[5]
$array[0] = $add1
$array[1] = $add2
$array[2] = $add3
$array[3] = $add4
$array[4] = $pc

; Create a single string to fill the combo <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
Global $sFullList = ""
For $i = 0 To UBound($array) - 1
    $sFullList &= "|" & $array[$i]
Next

GUICreate("Address Selecter", 280, 230)
GUIStartGroup()
Global $widthCell = 125
; Address 1 option
GUICtrlCreateLabel("Marketplace Address 1", 10, 10, $widthCell)
Global $sAddress1 = GUICtrlCreateCombo("", 0, -1)
GUICtrlSetData(-1, $sFullList) ; And load it in a single operation ; <<<<<<<<<<<<<<<<<<<<<<<<<<
; Address 2 option
GUICtrlCreateLabel("Marketplace Address 2", -2 * $widthCell, 10)
Global $sAddress2 = GUICtrlCreateCombo("", 0, -1)
GUICtrlSetData(-1, $sFullList); City option
GUICtrlCreateLabel("Marketplace City", -2 * $widthCell, 10)
Global $sCity = GUICtrlCreateCombo("", 0, -1)
GUICtrlSetData(-1, $sFullList); County option
GUICtrlCreateLabel("Marketplace County", -2 * $widthCell, 10)
Global $sCounty = GUICtrlCreateCombo("", 0, -1)
GUICtrlSetData(-1, $sFullList); Post Code option
GUICtrlCreateLabel("Marketplace Post Code", -2 * $widthCell, 10)
Global $sPostCode = GUICtrlCreateCombo("", 0, -1)
GUICtrlSetData(-1, $sFullList)
Global $button_1 = GUICtrlCreateButton("Ok", -1, 20, 120, 35)
GUISetState()
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            SplashTextOn("Exiting", "Exiting the script.  Please re-run", 190, 100, -1, -1, 4, "", -1, 1000)
            Sleep(1500)
            SplashOff()
            Exit
        Case $msg = $button_1
            ExitLoop
    EndSelect
WEnd
MsgBox(0, "Selected Address", "Address1: " & GUICtrlRead($sAddress1) & " | Address2: " & GUICtrlRead($sAddress2) & " | City: " & GUICtrlRead($sCity) & " | County: " & GUICtrlRead($sCounty) & " | Post Code: " & GUICtrlRead($sPostCode))
GUIDelete()

Now you get yoru blank line.

M23</windowsconstants.au3></editconstants.au3></comboconstants.au3></guiconstants.au3>

[mdcastle]

What a complicated way to fill your combos!

I'm not surprised that i found the most complicated way to do this! I'm very much a beginner at all things scripting so please be gentle .

Many thanks for your help.