how to check if a GuiCtrlCreateLabel exists?

[kor]

somewhat strange. I have some labels that I am using in a GUI that will report a value.

I have a button that essentially "clears" all the values and resets the gui back to blank. I am using GUiCtrlDelete($handle)

However if the user presses the "clear" button before they run the program then $handle doesn't exist yet.

Is there a way to somehow check if a gui label exists?

[water]

You could use function IsDeclared to check if the variable has been declared.

[kor]

I have found I can do this.. but not sure if it's the correct way

I declare the handle as a global variable at the top

Global $handle

$handle = GuiCtrlCreateLabel("test")

If $handle Then GuiCtrlDelete($handle)

[Melba23]

kor,

If the ControlID (not handle) of your label is undefined or unused then using GUICtrlDelete on it does not crash AutoIt:

#include <GUIConstantsEx.au3>

Global $cLabel

$hGUI = GUICreate("Test", 500, 500)

GUISetState()

Sleep(1000)
MsgBox(0, "Ready?", "Deleting label")
GUICtrlDelete($cLabel)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

But you must reset the variable to 0 if you delete it or the value remains valid and you might get errors like this:

#include <GUIConstantsEx.au3>

; Declare a variable
Global $cLabel

$hGUI = GUICreate("Test", 500, 500)

; Create a label and assing the ControlID to the variable
$cLabel = GUICtrlCreateLabel("Label", 10, 10, 200, 20)

GUISetState()

Sleep(1000)
MsgBox(0, "Ready?", "Deleting label")
GUICtrlDelete($cLabel)

MsgBox(0, "And now:", "Create a new label")
; Note that we do not assign this ControlID to $cLabel
GUICtrlCreateLabel("New label", 10, 100, 200, 20)

MsgBox(0, "Oops", "Look what happens now!")
GUICtrlDelete($cLabel)
; But that the ControlID is reused and so the new label is deleted

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

If you add a $cLabel = 0 line after the first GUICtrlDelete($cLabel) then all will happen as you think it should:

#include <GUIConstantsEx.au3>

; Declare a variable
Global $cLabel

$hGUI = GUICreate("Test", 500, 500)

; Create a label and assing the ControlID to the variable
$cLabel = GUICtrlCreateLabel("Label", 10, 10, 200, 20)

GUISetState()

Sleep(1000)
MsgBox(0, "Ready?", "Deleting label")
GUICtrlDelete($cLabel)
$cLabel = 0 ; Reset the variable to a non-existent control <<<<<<<<<<<<<<<<<<<<<<<<<<<

MsgBox(0, "And now:", "Create a new label")
; Note that we do not assign this ControlID to $cLabel
GUICtrlCreateLabel("New label", 10, 100, 200, 20)

MsgBox(0, "Oops", "Look what happens now!")
GUICtrlDelete($cLabel)
; But that the ControlID is reused and so the new label is deleted

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

All clear? Please ask if not.

M23