InputBox as password

[RedneckTech]

Using it like this currently:

$Password = InputBox ( "Login", "Please input the password" , "" , "*M" , "" , "" , "" , "" , "30" )

If $Password = "Test" Then

MsgBox ("0", "", "Correct")

Else

MsgBox ("0", "Failed", "Incorrect Password")

EndIf

2 questions. How can i make it case sensitive? it currently is not.

any way to keep the box at the center of the screen and stil have a 30 second timeout without getting pixels? Sorry if this is a nooby question. Been scripting for a while with autoIT now, but the whole GUI portion is starting to get tricky

If im missing a different command please feel free to express your vet-rage at my noobness

[Melba23]

RedneckTech,

If $Password == "Test" Then

will make the comparison case sensitive.

any way to keep the box at the center of the screen and stil have a 30 second timeout without getting pixels?

Would you care to explain in more detail as I do not understand - this works fine for me:

InputBox ( "title", "prompt", "", "", Default, Default, Default, Default, 30)

If you want the GUI to be undraggable then you need to create your own version of it using GUICreate - InputBox is produced by the API and you cannot really interact with it.

M23

[water]

For a case sensitive compare replace

If $Password = "Test" Then

with

If $Password == "Test" Then

or

if StringCompare($Password, "Test", 1) = 0 Then

Edit: Too sloooooooowwwww!

Edited August 3, 2012 by water

[RedneckTech]

I tried, but the password is not case sensitive. and i did not know about the "Default" parameter. Thanks M23, and to you too water. i like the stringcompare function. i will have to use that actually

any way to keep the box at the center of the screen and stil have a 30 second timeout without getting pixels? = i wanted a 30 sec timeout, but wanted the box to stay centered. was not using the "Default" parameter

Edit: missed the 2nd = in your statement M23

Edited August 3, 2012 by RedneckTech

[Melba23]

RedneckTech,

So are you happy with the code now?

M23

[RedneckTech]

Heres what I ended up writing. Sensitive information replaced with *** of course:

expandcollapse popup

#include <Timers.au3>

If FileExists ( @WorkingDir & "Diconnect.bat" ) = 0 Then
   FileOpen ( @WorkingDir & "Disconnect.bat", 1)
   FileWriteLine ( @WorkingDir & "Disconnect.bat" , "taskkill /im openvpn.exe /f" )
   FileWriteLine ( @WorkingDir & "Disconnect.bat" , "taskkill /im openvpn-gui.exe /f")
   FileClose ( @WorkingDir & "Disconnect.bat" )
   Sleep (100)
EndIf

$Password = InputBox ( "Login to ****", "Please input the password to connect to *********** , "" , "*M" , Default , Default , Default , Default , "30" )
If $Password == "*****" Then
   Run ( @WorkingDir & "Disconnect.bat" )
   Sleep ( 2000 )
   $Startup = TimerInit()
   While ProcessExists ( "openvpn-gui.exe") <> 0
      If TimerDiff($Startup) > 10000 Then
         MsgBox ( "0", "Error" , "ERROR" & @CRLF & "If this is the first time you have seen this error, please try rerunning the program again" & @CRLF & "If not please Contact email@email.com" )
         Exit
      EndIf
      Sleep (20)
   WEnd
   Run (@comspec & " /c " & Chr(34) & "C:Program FilesOpenVPNbinopenvpn-gui.exe" & Chr(34) & " --connect *****************.ovpn")
Else
   MsgBox ("0", "Failed", "Password Invalid")
   Run ( @WorkingDir & "Disconnect.bat" )
EndIf

$openvpn = TimerInit()

While ProcessExists ("openvpn.exe") <> 0
   If TimerDiff($openvpn) > 14400000 Then
      Run ( @WorkingDir & "Disconnect.bat" )
   EndIf
   If _Timer_GetIdleTime() >= 1200000 Then
      Run ( @WorkingDir & "Disconnect.bat" )
   EndIf
   Sleep (10000)
WEnd

We have a user that is computer retarded and needs a vpn connection to our server. rather than have just the standard openvpn gui which is open to her kids we figured this was better. Thanks guys!

Edit: added M23's code tags as per request

Edited August 3, 2012 by RedneckTech

[Mechaflash]

how are you choosing to store the password? hard coded, in a file, or off the network?

[RedneckTech]

its specifically written for her and no ones getting on her computer so it is just hardcoded at this point. it is not her network password, just something to keep anyone from fuddling around

[Melba23]

RedNeckTech,

Glad we could help.

And when you post code, please use Code tags - put [autoit] before and [/autoit] after your posted code - then you get the nice scrolling box and syntax colouring.

M23

[RedneckTech]

ah. ive just been copying from my notepad docs . thanks for the tip

[Mechaflash]

its specifically written for her and no ones getting on her computer so it is just hardcoded at this point. it is not her network password, just something to keep anyone from fuddling around

I see. If you ever wanted to make it a bit more secure, you can encrypt the password, and store it encrypted (even hard coded) so no one can read it without decrypting it first.You can use this to encrypt any password. It also outputs the command you should paste into the script for a simple login prompt.

Had to dig around for this...

expandcollapse popup

#include <Crypt.au3>

$vData = InputBox(@ScriptName, "Enter a password to encrypt.")
$sOutFile = FileSelectFolder("Select folder to output your encrypted key to.", "", 6)
If @error Then Exit
$sOutFile&="\EncryptedPass.txt"
_AutoMD5_Data_Create($vData, $sOutFile)
If msgbox(4 + 32 + 262144, @ScriptName, "Do you wish to view your encrypted key?") = 6 Then ShellExecute($sOutFile)
Exit

Func _AutoMD5_Data_Create($vData, $sOutFile)
    _Crypt_StartUp()
    $sEncryptedString = _Crypt_HashData($vData, $CALG_MD5)
    If $sEncryptedString = -1 Then
        msgbox(16 + 262144, @ScriptName, "Failed to create MD5 hash. Error in command. " & @error)
        Exit
    Else
        $hFile = FileOpen($sOutFile, 2)
        FileWrite($hFile, String($sEncryptedString) & @CRLF)
        FileClose($hFile)
    EndIf
    _Crypt_Shutdown()
    If msgbox(4 + 32 + 262144, @ScriptName, "Do you wish to test the output?") = 6 Then
        $sInput = InputBox(@ScriptName, "Enter your password...")
        _AutoMD5_Test_Decryption($sInput, $sEncryptedString, $sOutFile)
    EndIf
    _AutoMD5_Create_Commands($sOutFile)
    Return $sEncryptedString
EndFunc

Func _AutoMD5_Test_Decryption($sInput, $sEncryptedString, $sOutFile)
    _Crypt_Startup()
    $sInputEncryptedString = _Crypt_HashData($sInput, $CALG_MD5)
    _Crypt_Shutdown()
    If String($sInputEncryptedString) = String($sEncryptedString) Then
        msgbox(64 + 262144, @ScriptName, "WORKS!" &@LF&@LF& _
            "Encrypted Password Shows As: " & @TAB & $sEncryptedString &@LF&@LF& _
            "The Input Password Shows As: " & @TAB & $sInputEncryptedString)
    Else
        msgbox(64 + 262144, @ScriptName, "FAILED!" &@LF&@LF& _
        "Encrypted Password Shows As: " & @TAB & $sEncryptedString &@LF&@LF& _
            "The Input Password Shows As: " & @TAB & $sInputEncryptedString)
    EndIf
EndFunc

Func _AutoMD5_Create_Commands($sOutFile)
    $hFile = FileOpen($sOutFile, 1)
    FileWrite($hFile,  @CRLF & '#include <Crypt.au3>' & @CRLF & @CRLF & _
        '$sInput = InputBox(@ScriptName, "Enter your password...")' & @CRLF & @CRLF & _
        'Func _AutoMD5_Data_Decrypt($sInput) ; Returns true if passwords match, or false if they don''t.' & @CRLF & @TAB & _
        '$sPass = _Get_Stored_Encrypted_Password() ; Retrieve the password via whatever method you choose to store it.' & @CRLF & @TAB & _
        '_Crypt_Startup()' & @CRLF & @TAB & _
        '$sEncryptedInput = _Crypt_HashData($sInput, $CALG_MD5)' & @CRLF & @TAB & _
        '_Crypt_Shutdown()' & @CRLF & @TAB & _
        'If String($sInputEncryptedString) = String($sEncryptedString) Then' & @CRLF & @TAB & @TAB & _
        'Return True' & @CRLF & @TAB & _
        'Else' & @CRLF & @TAB & @TAB & _
        'Return False' & @CRLF & @TAB & _
        'EndIf' & @CRLF & _
        'EndFunc')
    FileClose($hFile)
EndFunc

Edited August 3, 2012 by mechaflash213