GUI TreeView with checkboxes help

[kgreer]

I am writing a script to dynamically create a TreeView control with checkboxes from a INI file containing a list of items. I do not see a function to get the items selected from the treeview. I might be overcomplicating this, but is there an example on how to get the selected items from the treeview?

[Melba23]

kgreer,

Loop through the items by index (remember they are 0-based) and use _GUICtrlTreeView_GetChecked to see which ones are checked.

M23

[kgreer]

Thanks! However I'm missing something. Here is what I'm working with. Once I figure out the functions I will modify this to my needs. I'm not getting a True prompt for the 3rd checked item and instead of 4 msg boxes, there is 5 in the loop. What am I missing?

#RequireAdmin
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <TreeViewConstants.au3>
#include <GuiTreeView.au3>
$Form1 = GUICreate("Form1", 615, 438, 192, 124)
GUISetState(@SW_SHOW)
Local $iTreeView_2 = GUICtrlCreateTreeView(30, 30, 200, 160, $TVS_CHECKBOXES)
GUICtrlCreateTreeViewItem("TreeView", $iTreeView_2)
GUICtrlCreateTreeViewItem("With", $iTreeView_2)
GUICtrlCreateTreeViewItem("$TVS_CHECKBOXES", $iTreeView_2)
GUICtrlSetState(-1, $GUI_CHECKED)
GUICtrlCreateTreeViewItem("Style", $iTreeView_2)

$count = _GUICtrlTreeView_GetCount($iTreeView_2)
for $i=1 to $count
msgbox(0,"ischecked",_GUICtrlTreeView_GetChecked($iTreeView_2,$i))
Next

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
EndSwitch
WEnd

[Melba23]

kgreer,

The Help file says you need to pass the handle of the TreeViewItem to that function - so we need to collect them as the items are created:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTreeView.au3>

Global $aItems[4]

$Form1 = GUICreate("Form1", 500, 500)
GUISetState(@SW_SHOW)

Local $iTreeView_2 = GUICtrlCreateTreeView(30, 30, 200, 160, $TVS_CHECKBOXES)
$aItems[0] = GUICtrlGetHandle(GUICtrlCreateTreeViewItem("TreeView", $iTreeView_2))
$aItems[1] = GUICtrlGetHandle(GUICtrlCreateTreeViewItem("With", $iTreeView_2))
$aItems[2] = GUICtrlGetHandle(GUICtrlCreateTreeViewItem("TVS_CHECKBOXES", $iTreeView_2))
_GUICtrlTreeView_SetChecked($iTreeView_2, $aItems[2])
$aItems[3] = GUICtrlGetHandle(GUICtrlCreateTreeViewItem("Style", $iTreeView_2))

$cButton = GUICtrlCreateButton("Read", 10, 450, 80, 30)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            $count = _GUICtrlTreeView_GetCount($iTreeView_2)
            For $i = 0 To $count - 1
                MsgBox(0, "ischecked", $i & " = " & _GUICtrlTreeView_GetChecked($iTreeView_2, $aItems[$i]))
            Next
    EndSwitch
WEnd

All clear?

[kgreer]

Ahh I see. Thanks. You got me a jump start. I'll work on my project and chime in again if I need help. Thanks!

[spudw2k]

This post might give you some ideas too.