How to GUICtrlSetTip on a _GUICtrlSlider_Create

[careca]

What is the alternative tip to the _GUICtrlSlider_Create?

$Slider2 = _GUICtrlSlider_Create($GUI, 440, 382, 24, 92, $TBS_VERT)
GUICtrlSetTip($Slider2, 'Drag or press V + Arrows Up OR Down To change value', "Tip", 1)

[BrewManNH]

Don't use the UDF version and use the standard version of the slider control?

Or you have to resort to using the _GUIToolTip_Create tooltips, which are a bit harder to implement.

Or, you try _WinAPI_GetDlgCtrlID to get the control ID of the slider and see if you can do it with that.

Edited May 8, 2013 by BrewManNH

[careca]

Thank you, i had to use the udf version because of the way i wanted things to work, and believe me, i tried with the regular version.

[AZJIO]

#include <GUIConstantsEx.au3>
#include <GuiSlider.au3>
#include <GuiToolTip.au3>

$Debug_S = False

_Main()

Func _Main()
    Local $hWndTT, $hSlider

    $hGUI = GUICreate("Устанавливает дескриптор ToolTips", 400, 296)
    $hSlider = _GUICtrlSlider_Create($hGUI, 2, 2, 396, 35, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
    GUISetState()

    $hToolTip = _GUICtrlSlider_GetToolTips($hSlider)
    _GUIToolTip_SetTipBkColor($hToolTip, 0x395A00)
    _GUIToolTip_SetTipTextColor($hToolTip, 0x1EBFFF)
    _GUIToolTip_SetMaxTipWidth($hToolTip, 400)

    _GUIToolTip_AddTool($hToolTip, 0, "String 1" & @CRLF & "String 2", $hSlider, 0, 0, 0, 0, 9)
    _GUICtrlSlider_SetToolTips($hSlider, $hToolTip)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

#include <GUIConstantsEx.au3>
#include <GuiSlider.au3>
#include <GuiToolTip.au3>

$Debug_S = False

_Main()

Func _Main()
    Local $hWndTT, $hSlider

    $hGUI = GUICreate("Устанавливает дескриптор ToolTips", 400, 296)
    $hSlider = _GUICtrlSlider_Create($hGUI, 2, 2, 396, 35, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
    ; $iSlider = GUICtrlCreateSlider(2, 2, 396, 35, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
    ; $hSlider = GUICtrlGetHandle(-1)
    GUISetState()

    $hToolTip = _GUIToolTip_Create($hGUI, $TTS_BALLOON)
    _GUIToolTip_SetTipBkColor($hToolTip, 0x395A00)
    _GUIToolTip_SetTipTextColor($hToolTip, 0x1EBFFF)
    _GUIToolTip_SetMaxTipWidth($hToolTip, 400)

    _GUIToolTip_AddTool($hToolTip, 0, "String 1" & @CRLF & "String 2", $hSlider, 0, 0, 0, 0, 9)
    _GUICtrlSlider_SetToolTips($hSlider, $hToolTip)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

[careca]

I will check that, thank you.

[careca]

You the man! Tested, works perfect! Thanks