how to catch error when database query failed?

[Chann]

I'm making a accdb query in this function.

Func Get_meaning($adoRs1,$adoCon1,$word1)

$query = "select Sinhala from words where English='"&$word1&"'"

$adoRs1.Open($query, $adoCon1)

$word=$adoRs1.Fields("Sinhala").Value

$adoRs1.Close 

return $word

EndFunc

 

 

When the $word1 is not in the database, i want to do some modification to the $word1 and recheck in the database. But when the $word1 is not found in the database, script gives an error and exit. Please give me some help

Edited September 24, 2013 by Chann

[jchd]

Welcome to the forum.

Try this:

Func Get_meaning($adoRs1, $adoCon1, $word1)
    Local $word
    Local $query = "select Sinhala from words where English = " & _String_Escape($word1)
    $adoRs1.Open($query, $adoCon1)
    If Not $adoRs1.EOF Then
        $word = $adoRs1.Fields(0).Value
        $adoRs1.Close
    Else
        $adoRs1.Close
        ; from here try again with something different
    EndIf
    Return $word
EndFunc   ;==>Get_meaning

Func _String_Escape($sString)
    If IsNumber($sString) Then $sString = String($sString) ; don't raise error if passing a numeric parameter
    If Not IsString($sString) Then Return SetError(1, 0, "")
    Return ("'" & StringReplace($sString, "'", "''", 0, 1) & "'")
EndFunc   ;==>_String_Escape

Please use code tags (the blue square icon in editor) around code next time.

[Chann]

Thank you jchd for your nice answer and for the advice.

[water]

Another good idea when working with COM is to add a COM error handler. Please have a look at ObjEvent for an example.

In the 3.3.9.x version a script no longer crashes when a COM error occurres but simply continues. So you need to add error checking to your script to handle such errors.

Like:

$adoRs1.Open($query, $adoCon1)
If @error Then ...

[jchd]

A COM error handler is always a good idea, well, until the beta turns into a release and COM errors become @error non-fatal events.

Notice however that a COM error handler will not help in this case: an SQL query returning an empty set is not an error.