Problem using menu

[GeekIT]

Hi everyone 

I have a quick question about menus in autoit:

Is it normal that I can't use menu's in forms that don't have sub-menu's?

example:

$Form = GUICreate("Test.", 300, 200)

$Menu = GUICtrlCreateMenu("Menu")

While 1

Switch GUIGetMsg()

    Case $Menu

        MsgBox(0,'never works','never works!');    <--- why won't this work?

EndSwitch

[water]

Welcome to AutoIt and the forum!

Did you check the example that can be found in the help file for function GUICtrlCreateMenu?

At least line

GUISetState()

is missing.

[water]

BTW: Could you please enclose your code in AutoIt code tags (the blue "A" icon in the editor). Enhances readability

[kylomas]

GeekIT,

You're also missing the WEND stmt to close the while loop.  Try it like this...

#include <GUIConstantsEx.au3>

$Form = GUICreate("Test.", 300, 200)

$Menu = GUICtrlCreateMenu("Menu")
$Menumsg1 = GUICtrlCreateMenuItem('Message # 1', $Menu)
$Menumsg2 = GUICtrlCreateMenuItem('Message # 2', $Menu)
GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Menumsg1
            MsgBox(0, 'never works', 'never works!');    <--- why won't this work?
        Case $Menumsg2
            MsgBox(0, '', 'Of course it works' & @crlf & 'Read the HELP file.');    <--- why won't this work?
    EndSwitch

WEnd

See the Help file for explanation...

kylomas

edit: spelling

Edited December 1, 2013 by kylomas

[water]

I assume the missing WEnd statement is just a copy&paste mistake

[Melba23]

GeekIT,

I can get as far as recognising the click on the menu bar. But as yet I cannot get out of the blocking menu loop - you need to press {ESCAPE} to reenter the script and get the dummy to fire:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Constants.au3>
#Include <GuiMenu.au3>

$hGUI = GUICreate("Test", 500, 500)

$mFilemenu = GUICtrlCreateMenu("File")
$mExititem = GUICtrlCreateMenuItem("Exit", $mFilemenu)
$mSpecialitem = GUICtrlCreateMenu("Special")
$mHelpmenu = GUICtrlCreateMenu("?")
$mAboutitem = GUICtrlCreateMenuItem("About", $mHelpmenu)

$cMenuDummy = GUICtrlCreateDummy()

GUISetState()

$hMenu = _GUICtrlMenu_GetMenu($hGUI)
$iCount = _GUICtrlMenu_GetItemCount($hMenu) - 1

GUIRegisterMsg(0x0211,"_WM_ENTERMENULOOP") ; WM_ENTERMENULOOP

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mExititem
            Exit
        Case $cMenuDummy
            MsgBox($MB_SYSTEMMODAL, "Hi", "I can be actioned!")
        Case $mAboutitem
            MsgBox($MB_SYSTEMMODAL, "Solved", "That was hard work!")
    EndSwitch

WEnd

Func _WM_ENTERMENULOOP($hWnd, $iMsg, $wParam, $lParam)

    If $hWnd = $hGUI Then
        For $i = 0 To $iCount

            Local $tRect = _GUICtrlMenu_GetItemRectEx($hGUI, $hMenu, $i)
            Local $aMousePos = MouseGetPos()
            Local $aRes = DllCall("User32.dll", "int", "PtInRect", "ptr", DllStructGetPtr($tRect), "int", $aMousePos[0], "int", $aMousePos[1])
            If Not @error And $aRes[0] Then
                ConsoleWrite("You clicked: " & _GUICtrlMenu_GetItemText($hMenu, $i) & @CRLF)
                GUICtrlSendToDummy($cMenuDummy)
                ExitLoop
            EndIf
        Next
    EndIf

EndFunc

I will keep working on it this afternoon. In the mean time if you have any questions, please ask.

M23

[GeekIT]

Welcome to AutoIt and the forum!

Did you check the example that can be found in the help file for function GUICtrlCreateMenu?

At least line

GUISetState()

is missing.

yes and i know, is just an example. thanks for the reply (: 

[GeekIT]

GeekIT,

You're also missing the WEND stmt to close the while loop.

 

I know, was just explaining my problem. I want to use a menu without sub menu's.

I want it so that you just have to click on the menu button itself and then do something...

Edited December 1, 2013 by GeekIT
Fixed tags

[GeekIT]

GeekIT,

I can get as far as recognising the click on the menu bar. But as yet I cannot get out of the blocking menu loop - you need to press {ESCAPE} to reenter the script and get the dummy to fire:

I will keep working on it this afternoon. In the mean time if you have any questions, please ask.

 

Thanks but you don't have to do all that for me (:

I just wanted to know if this was normal. thanks for the help!

Edited December 1, 2013 by Melba23
Fixed tags

[Melba23]

GeekIT,

Jos came up with a solution:

#include <GUIConstantsEx.au3>
#include <Constants.au3>
#Include <GuiMenu.au3>

$hGUI = GUICreate("Test", 500, 500)

$mFilemenu = GUICtrlCreateMenu("File")
$mExititem = GUICtrlCreateMenuItem("Exit", $mFilemenu)
$mSpecialitem = GUICtrlCreateMenuItem("Special", -1)
$mHelpmenu = GUICtrlCreateMenu("?")
$mAboutitem = GUICtrlCreateMenuItem("About", $mHelpmenu)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mExititem
            Exit
        Case $mSpecialitem
            MsgBox($MB_SYSTEMMODAL, "Hi", "I can be actioned!")
        Case $mAboutitem
            MsgBox($MB_SYSTEMMODAL, "Solved", "Thank Jos for that!")
    EndSwitch

WEnd

M23

Edit: And so did wraithdu:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Constants.au3>
#Include <GuiMenu.au3>

$hGUI = GUICreate("Test", 500, 500)

$mFilemenu = GUICtrlCreateMenu("File")
$mExititem = GUICtrlCreateMenuItem("Exit", $mFilemenu)
$mSpecialitem = GUICtrlCreateMenu("Special")
$mHelpmenu = GUICtrlCreateMenu("?")
$mAboutitem = GUICtrlCreateMenuItem("About", $mHelpmenu)

$cMenuDummy = GUICtrlCreateDummy()

GUISetState()

$hMenu = _GUICtrlMenu_GetMenu($hGUI)
$iCount = _GUICtrlMenu_GetItemCount($hMenu) - 1

GUIRegisterMsg(0x0211,"_WM_ENTERMENULOOP") ; WM_ENTERMENULOOP

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mExititem
            Exit
        Case $cMenuDummy
            MsgBox($MB_SYSTEMMODAL, "Hi", "I can be actioned!")
        Case $mAboutitem
            MsgBox($MB_SYSTEMMODAL, "Solved", "That was hard work!")
    EndSwitch

WEnd

Func _WM_ENTERMENULOOP($hWnd, $iMsg, $wParam, $lParam)

    If $hWnd = $hGUI Then
        For $i = 0 To $iCount

            Local $tRect = _GUICtrlMenu_GetItemRectEx($hGUI, $hMenu, $i)
            Local $aMousePos = MouseGetPos()
            Local $tPOINT = DllStructCreate($tagPOINT)
            $tPOINT.x = $aMousePos[0]
            $tPOINT.y = $aMousePos[1]
            Local $aRes = DllCall("User32.dll", "int", "PtInRect", "struct*", $tRect, "struct", $tPOINT)
            If Not @error And $aRes[0] Then
                ConsoleWrite("You clicked: " & _GUICtrlMenu_GetItemText($hMenu, $i) & @CRLF)
                GUICtrlSendToDummy($cMenuDummy)
                ControlClick($hGUI, "", $hGUI)
                Return 0
            EndIf
        Next
    EndIf

EndFunc

Edited December 1, 2013 by Melba23

[GeekIT]

Ah, I see.   

Thanks for all the help guys!