when show second GUI it's not responding

[MAS]

Hello all

I want to create 2 or more GUI displayed one after the other

here's my example code

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <ColorConstants.au3>
#include <GuiConstants.au3>


Global $GUI1, $GUI2


Opt("GUIOnEventMode", 1) ; Change to OnEvent mode


GUI1()


Func GUI1()
$GUI1 = GUICreate("title 1",600, 500, -1, -1, $ws_popup+$ws_caption)
GUISetOnEvent($GUI_EVENT_CLOSE, "_CloseButton")
GUISetState()
$Button = GUICtrlCreateButton("Next Step", 414, 446, 142,32)
GUICtrlSetOnEvent($Button, "GUI2")
While 1
Sleep(100)
WEnd
EndFunc


Func GUI2()
GUISetState(@SW_HIDE, $GUI1)
$GUI2 = GUICreate("title 2",600, 500, -1, -1)
GUISetState()
$Button2 = GUICtrlCreateButton("Next Step", 414, 446, 142,32)
GUICtrlSetOnEvent($Button2, "button2")
While 1
Sleep(100)
WEnd
EndFunc


Func _CloseButton()
    Exit
 EndFunc



Func Button2() 
MsgBox(0,'','gui2 working') 
EndFunc

 

the button on GUI 2 is not responding when click it

how I fix this

thanks

Edited January 21, 2014 by MAS

[water]

The wiki has a very good tutorial that explains how to handle multiple GUIs.

[Melba23]

MAS,

You are stuck in the loops within the functions - you need to return to a central idle loop or the Event functions are never called:

Global $GUI1, $GUI2

Opt("GUIOnEventMode", 1) ; Change to OnEvent mode

GUI1()

While 1
    Sleep(10)
WEnd

Func GUI1()
    $GUI1 = GUICreate("title 1", 600, 500, -1, -1, $ws_popup + $ws_caption)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_CloseButton")
    $Button = GUICtrlCreateButton("Next Step", 414, 446, 142, 32)
    GUICtrlSetOnEvent($Button, "GUI2")
    GUISetState()
EndFunc   ;==>GUI1

Func GUI2()
    GUISetState(@SW_HIDE, $GUI1)
    $GUI2 = GUICreate("title 2", 600, 500, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_CloseButton")
    $Button2 = GUICtrlCreateButton("Next Step", 414, 446, 142, 32)
    GUICtrlSetOnEvent($Button2, "button2")
    GUISetState()
EndFunc   ;==>GUI2

Func Button2()
    MsgBox(0, '', 'gui2 working')
EndFunc   ;==>Button2

Func _CloseButton()
    Exit
EndFunc

All clear?

M23

P.S. When you post code please use Code tags - see here how to do it. Then you get a scrolling box and syntax colouring as you can see in my post.

[MAS]

wow thanks M23   

ok edited the code tag

[kylomas]

Mas,

Sooner or later you will want to know how to get back to your first gui...

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <ColorConstants.au3>
#include <GuiConstants.au3>

Global $GUI1, $GUI2

Opt("GUIOnEventMode", 1) ; Change to OnEvent mode

GUI1()

While 1
    Sleep(100)
WEnd

Func GUI1()
    $GUI1 = GUICreate("title 1", 600, 500, -1, -1, $ws_popup + $ws_caption)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_CloseButton")
    GUISetState()
    $Button = GUICtrlCreateButton("Next Step", 414, 446, 142, 32)
    GUICtrlSetOnEvent($Button, "GUI2")
EndFunc   ;==>GUI1

Func GUI2()
    GUISetState(@SW_HIDE, $GUI1)
    $GUI2 = GUICreate("title 2", 600, 500, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_CloseButton")

    $Button2 = GUICtrlCreateButton("Next Step", 414, 446, 142, 32)
    GUICtrlSetOnEvent($Button2, "button2")
    GUISetState()
EndFunc   ;==>GUI2


Func _CloseButton()
    If @GUI_WinHandle = $GUI2 Then
        GUIDelete($GUI2)
        GUISetState(@SW_SHOW, $GUI1)
    Else
        Exit
    EndIf
EndFunc   ;==>_CloseButton

Func Button2()
    MsgBox(0, '', 'gui2 working')
EndFunc   ;==>Button2

kylomas

[MAS]

k thanks "kylomas" for this addition