Need help with simple Autoit project

[8218]

I have worked with Autoit before a long time ago, and I am now returning and in the need of a script.

It would be running in the background, and every time something is copied (CTRL+C) it would use GetClip() to see if the copied string were formatted like a MAC-Address (XX-XX-XX-XX-XX-XX) and if it was, it would remove the hyphens (-) so it would be XXXXXXXXXXXX instead.

Is this possible?

[JohnOne]

Is this possible?

Yes.

[8218]

How do I identify the event of something being copied to the Clipboard then?

Edited February 4, 2014 by 8218

[JohnOne]

I don't know, but that was not your question.

[8218]

How would you know whether it is possile or not, if you don't know how?

[Andreik]

Look in help file WM_CLIPBOARDUPDATE message.

[8218]

Look in help file WM_CLIPBOARDUPDATE message.

Thanks, I will check it out

[Danyfirex]

another option

#include <Misc.au3>

local $hDLL = DllOpen("user32.dll")

While 1
      If  _IsPressed("11",$hDLL) and _IsPressed("43",$hDLL) then
          Consolewrite("CTRL+C is PRESSED" & @crlf)
        ;here some Regular Expression to check MAC format

          EndIf



    Sleep(100)
WEnd

saludos

[JohnOne]

How would you know whether it is possile or not, if you don't know how?

Because it's possible with hotkeys.

Although Andreik has given perfect answer.

[JohnOne]

Since I never new Andreik's solution, I made quick basic example.

#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $WM_CLIPBOARDUPDATE = 0x031D
    $mygui = GUICreate("GUI", 100, 100)
    DllCall("User32.dll", "bool", "AddClipboardFormatListener", "hwnd", $mygui)
    If @error Then
        Exit MsgBox(0, "Error", "DllCall")
    EndIf
    GUIRegisterMsg($WM_CLIPBOARDUPDATE, "MY_WM_CLIPBOARDUPDATE")
    GUISetState()
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Example


Func MY_WM_CLIPBOARDUPDATE($hWnd, $Msg, $wParam, $lParam)
    MsgBox(0, "Success", "Clipboard data changed")
EndFunc   ;==>MY_WM_CLIPBOARDUPDATE

[JohnOne]

Update.

Probably wise to remove listener.

#include <GUIConstantsEx.au3>

OnAutoItExitRegister("_Exit")

Global $mygui

Example()

Func Example()
    Local $WM_CLIPBOARDUPDATE = 0x031D
    $mygui = GUICreate("GUI", 100, 100)
    DllCall("User32.dll", "bool", "AddClipboardFormatListener", "hwnd", $mygui)
    If @error Then
        Exit MsgBox(0, "Error", "DllCall")
    EndIf
    GUIRegisterMsg($WM_CLIPBOARDUPDATE, "MY_WM_CLIPBOARDUPDATE")
    GUISetState()
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Example


Func MY_WM_CLIPBOARDUPDATE($hWnd, $Msg, $wParam, $lParam)
    MsgBox(0, "Success", "Clipboard data changed")
EndFunc   ;==>MY_WM_CLIPBOARDUPDATE

Func _Exit()
    DllCall("User32.dll", "bool", "RemoveClipboardFormatListener", "hwnd", $mygui)
EndFunc

[8218]

Thanks Andreik and JohnOne, I've created the script now, thanks a lot for the help.

[Andreik]

And the clipboard should be modified something like this:

Func MY_WM_CLIPBOARDUPDATE($hWnd, $Msg, $wParam, $lParam)
    Local $vData = ClipGet()
    If StringRegExp($vData,'^([0-9A-Fa-f]{2}[:-]){5}([0-9A-Fa-f]{2})$',0) Then
        ClipPut(StringUpper(StringReplace($vData,'-','')))
    EndIf
EndFunc   ;==>MY_WM_CLIPBOARDUPDATE