StringReplace help

[Madness]

Can someone show me an example of how the second parameter of this function is used if you specify a start point? I want to replace a character in a string, but only after a certain position. Not sure I can do this with StringReplace.

Edited July 14, 2014 by Madness

[mikell]

Local $sString = StringReplace("123_a_456", 5, "b")
MsgBox(0, "", $sString)

?

[Madness]

Got it. It looks like I will need to find the positions of what I want to replace, after a certain point, then loop back through with this.

Edited July 14, 2014 by Madness

[water]

You can't combine Searchstring and start.

Use something like this

$iStart = 5
$sString = "aaabacadae"
$sSearch = "a"
$sReplace = "?"
$sStringLeft = StringLeft($sString, $iStart - 1)
$sStringRight = StringMid($sString, $iStart)
ConsoleWrite($sStringLeft & StringReplace($sStringRight, $sSearch, $sReplace) & @LF)

[mikell]

An example of what is to do would be nice

[kylomas]

Madness,

You might do something like this...

local $sTestString       = 'ABCDEF_abcdef_ABCDEF_abcdef'
Local $iStartpos         = 27
local $sReplaceChar      = 'X'
local $sCharToReplace    = 'f'

for $1 = $iStartpos to stringlen($sTestString)
    if stringmid($sTestString,$1,1) = $sCharToReplace then $sTestString = stringreplace($sTestString,$1,$sReplaceChar)
Next

ConsoleWrite($sTestString & @CRLF)

kylomas

edit: Please disregard...solutions by water and mikell are much better

Edited July 14, 2014 by kylomas

[mikell]

kylomas,

local $sTestString = 'ABCDEF_abcdef_ABCDEF_abcdef_ABCDEF_abcdef'
Local $iStartpos = 25
local $sReplaceChar = 'X'
local $sCharToReplace = 'f'

Msgbox(0,"", StringRegExpReplace($sTestString, '(?i)(?<=.{' & $iStartpos & '})(.*?)' & $sCharToReplace, "$1" & $sReplaceChar) )

[kylomas]

mikell,

Thank you for your help on this.

@Madness - mikell came up with the above gem which I believe is the best solution to your issue!

edit: if this dialog seems disjointed it is because mikell and I have been discussing this offline

Edited July 14, 2014 by kylomas

[jchd]

Prompted to look at this I came up with another solution but it's ugly compared to what mikell offered:

Local $sString = 'ABCDEF_abcdef_ABCDEF_abcdef_ABCDEF_abcdef_ff'

Local $sRes = _ArrayToString(StringRegExp($sString, "(?|^(.{25}[^f]*)|f([^f]*))", 3), "X")
ConsoleWrite($sRes & @LF)

[mikell]

kylomas,

A last detail : in case of  $sCharToReplace is a special character, it's better to put the Q...E sequence

StringRegExpReplace($sTestString, '(?i)(?<=.{' & $iStartpos & '})(.*?)\Q' & $sCharToReplace & '\E', "$1" & $sReplaceChar)