Action with object has failed, how to avoid?

[Terenz 29]

Hi guys

This is a little snip of the code:

Global $oShell = ObjCreate("Shell.Application")
If Not IsObj($oShell) Then Exit

Run("explorer /e, C:\")

While 1
    $hWnd = WinActive("[REGEXPCLASS:(Explore|Cabinet)WClass]")
    If $hWnd <> 0 Then
        For $oWindow In $oShell.Windows()
            If $oWindow.HWND() = $hWnd Then ExitLoop
        Next
        $oTest = $oWindow.Document.SelectedItems()
        If IsObj($oTest) Then
            For $oItem In $oTest
                ConsoleWrite($oItem.Name() & @CR)
            Next
        EndIf
    EndIf
    Sleep(100)
WEnd

Pratically it open a folder ( C: ) and wait for the click on a item, it return the filename ( i need to add a flag for avoid the multiple ConsoleWrite but for now i don't care )

The problem is if i close the folder, i have:

: ==> The requested action with this object has failed.:
$oTest = $oWindow.Document.SelectedItems()
$oTest = $oWindow.Document.SelectedItems()^ ERROR

And i really don't know how to avoid it. I don't want to close the script, i need it to work "globally" with any folder but if no folder has found...i have the COM error.

Solution?

Edited November 5, 2014 by Terenz

[JLogan3o13 1,405]

Look at ObjEvent in the help file for how to construct an error handler.

[Terenz 29]

I'm check it out

[water 1,972]

Usually this is being avoided by waiting for events to occur (menas: wait until the suers selects a file and then process this selection).

I don't know which events (if any) the Explorer COM provides.

[Terenz 29]

Registering the error give more information but nothing else, i'll try to search if someone has the same problem with that COM function used in a loop

[water 1,972]

Remove the MsgBox with the error information. So you simply get an empty function.

This function is being called when an COM error occurrs, does nothing and returns to execute the script after the line causing the COM error.

[Inververs 14]

$oWindow is not an object when there are no open windows. Thats why $oWindow.Document.SelectedItems() can't process

Solution:

Global $oShell = ObjCreate("Shell.Application")
If Not IsObj($oShell) Then Exit

Run("explorer /e, C:\")
While 1
    $hWnd = WinActive("[REGEXPCLASS:(Explore|Cabinet)WClass]")
    If $hWnd <> 0 Then
        For $oWindow In $oShell.Windows()
            If $oWindow.HWND() = $hWnd Then ExitLoop
        Next

        If IsObj($oWindow) And IsObj($oWindow.Document.SelectedItems()) Then
            For $oItem In $oWindow.Document.SelectedItems()
                ConsoleWrite($oItem.Name() & @CR)
            Next
        EndIf

    EndIf
    Sleep(100)
WEnd