Jump to content
Sign in to follow this  
Glutch

Input placeholder instead of raw text

Recommended Posts

Hello!

I'm trying to figure out how to get a placeholder instead of raw text on the Koda inputs.

'>
$key = GUICtrlCreateInput("Keys to press (optional)", 16, 160, 145, 21)

I dont want the text to stay in the box if i click inside it. I want a solution like this in html: <input type="text" placeholder="Keys to press (optional)"/>

Would greatly appreciate some advice :)

Share this post


Link to post
Share on other sites

You can do something like this here:

 

 

#Include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Test", 300, 200)
$iLabel = GUICtrlCreateLabel("Test", 10, 10)
$iBtn = GUICtrlCreateButton("Exit", 200, 100, 60, 60)
$key = GUICtrlCreateInput("Keys to press (optional)", 16, 160, 145, 21)
ControlFocus($hGUI, "", $iLabel)
GUISetState()

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

Do
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $iBtn
            GUIDelete()
            Exit
    EndSwitch
Until False

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    Switch $hWnd
        Case $hGUI
            Switch BitAND($wParam, 0xFFFF)
                Case $key
                    Switch BitShift($wParam, 16)
                        Case $EN_KILLFOCUS
                            If GUICtrlRead($key) = "" Then GUICtrlSetData($key, "Keys to press (optional)")
                        Case $EN_SETFOCUS
                            If GUICtrlRead($key) = "Keys to press (optional)" Then GUICtrlSetData($key, "")
                    EndSwitch
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND
 

 

Br,

UEZ


Please don't send me any personal message and ask for support! I will not reply!

Selection of finest graphical examples at Codepen.io

The own fart smells best!
Her 'sikim hıyar' diyene bir avuç tuz alıp koşma!
¯\_(ツ)_/¯  ٩(●̮̮̃•̃)۶ ٩(-̮̮̃-̃)۶ૐ

Share this post


Link to post
Share on other sites

Oh... That was a tedious solution. I'll probably put a label above the input instead.
Thanks for the help though!

PS: Koda should implement this feature

Share this post


Link to post
Share on other sites

Glutch (and UEZ),

No need to be quite so complicated - use a cuebanner: ;)

#include <GUIConstantsEX.au3>
#include <EditConstants.au3>

$hGui = GUICreate("", 500, 500)

$cInput = GUICtrlCreateInput("", 10, 10, 200, 20)
GUICtrlSendMsg($cInput, $EM_SETCUEBANNER, False, "Keys to press (optional)")

$cButton = GUICtrlCreateButton("Test", 10, 100, 80, 30)
GUICtrlSetState($cButton, $GUI_FOCUS)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd
I hope that helps. :)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

  • Recently Browsing   0 members

    No registered users viewing this page.

×
×
  • Create New...