How to move all controls fast?

[algiuxas 10]

Hello, I need help, I have created couple small pictures(about 200) in one GUI, I need to move them fast about 1-5 pixels every picture somehow. There are only pictures in GUI, no other controls. I tried this, but it's too slow:

expandcollapse popup

Global Const $AC_SRC_ALPHA = 1

For $ii = 0 To $size
    For $iii = 0 To $size
        GUICtrlSetPos(_ArrayGet($data, $ii, $iii, 1), ControlGetPos($GUI, "", _ArrayGet($data, $ii, $iii, 1))[0] + 2, ControlGetPos($GUI, "", _ArrayGet($data, $ii, $iii, 1))[1] + 2)
    Next
Next

Func _ArrayGet(ByRef $aArray, $i1, $i2 = 0, $i3 = 0, $i4 = 0, $i5 = 0, $i6 = 0, $i7 = 0, $i8 = 0, $i9 = 0, $i10 = 0, $i11 = 0, $i12 = 0, $i13 = 0, $i14 = 0, $i15 = 0, $i16 = 0, $i17 = 0, $i18 = 0, $i19 = 0, $i20 = 0)
    ;Function made by ProgAndy

    Local $iDims = UBound($aArray, 0)
    #forceref $i1, $i2, $i3, $i4, $i5, $i6, $i7, $i8, $i9, $i10, $i11, $i12, $i13, $i14, $i15, $i16, $i17, $i18, $i19, $i20
    Local $NULL
    If Not IsArray($aArray) Then Return SetError(1, 1, $NULL)
    Local $sAccess = "$aArray"
    For $i = 1 To $iDims

        Local $iIndex = Int(Eval("i" & $i))
        If $iIndex >= UBound($aArray, $i) Then Return SetError(3, $i, $NULL)
        $sAccess &= '[' & $iIndex & ']'
    Next
    If @NumParams - 1 > $iDims Then
        For $i = $iDims - 1 To @NumParams

            $sAccess &= ", $i" & $i

        Next
        Local $vResult = Execute("_ArrayGet(" & $sAccess & ")")
        If @error Then SetError(@error, @extended + $iDims)
        Return $vResult

    Else
        Return Execute($sAccess)



    EndIf



EndFunc   ;==>_ArrayGet

I didn't wrote all script, becouse it's huge. It took about 1200 - 1600 milisecounds, I need that pictures would move much faster. It's possible to make it much faster, that it would took about 2-10 milisecounds? Thanks.

Edited August 12, 2015 by Melba23
Added code tags

[Melba23 2,858]

algiuxas,

Welcome to the AutoIt forums.

When you post code please use Code tags - see here how to do it.  Then you get a scrolling box and syntax colouring as you can see above now I have added the tags.

Now off to look at the code itself.

M23

[Melba23 2,858]

algiuxas,

This simplifies the data storage and runs much faster on my machine - how about yours?

expandcollapse popup

HotKeySet("{ESC}", "_Exit")

Global $aData[200][3]

$hGUI = GUICreate("Test", 500, 500)

For $ii = 0 To 19
    For $iii = 0 To 9
        $iIndex = ($ii * 10) + $iii
        $iX = 10 + ($ii * 10)
        $iY = 10 + ($iii * 10)
        $aData[$iIndex][0] = GUICtrlCreateLabel("", $iX, $iY, 8, 8)
        GUICtrlSetBkColor($aData[$iIndex][0], 0xFF0000)
        $aData[$iIndex][1] = $iX

        $aData[$iIndex][2] = $iY

    Next
Next

GUISetState()

For $j = 0 To 100

    $nBegin = TimerInit()
    For $i = 0 To 199
        $iX = $aData[$i][1] + 2
        $iY = $aData[$i][2] + 2
        GUICtrlSetPos($aData[$i][0], $iX, $iY)
        $aData[$i][1] = $iX

        $aData[$i][2] = $iY

    Next
    ConsoleWrite(TimerDiff($nBegin) & @CRLF)

Next

Func _Exit()
    Exit
EndFunc

M23

[KaFu 193]

How about using something like this in the loop (not sure in which include the function is in the current au3 release though )?

Local $hWinPosInfo
For $j = 0 To 100
    $nBegin = TimerInit()
    $hWinPosInfo = _WinAPI_BeginDeferWindowPos(200)
    For $i = 0 To 199
        $iX = $aData[$i][1] + 2
        $iY = $aData[$i][2] + 2
        _WinAPI_DeferWindowPos($hWinPosInfo, $aData[$i][3], $HWND_TOP, $iX, $iY, 0, 0, BitOR($SWP_NOSIZE, $SWP_NOACTIVATE))
        $aData[$i][1] = $iX
        $aData[$i][2] = $iY
    Next
    _WinAPI_EndDeferWindowPos($hWinPosInfo)
    ConsoleWrite(TimerDiff($nBegin) & @CRLF)
Next