GUIDelete on click

[Blueman]

Hi all,

I was wondering if it is possible to close (delete) a GUI when i click on something else rather than the GUI it self
Simple; left-mouse-click on the GUI (GUI stay alive) // left-mouse-click on the start button from Windows, or somewhere else (GUI Delete)

I have made a While loop but the GUI is still closed even if i click on the GUI itself.

 

; START GUI LOOP
While 1
    $msg = GUIGetMsg()
    Switch 1
        Case -3
            Exit

         Case _IsPressed ("01")

            If $msg == $GUI_EVENT_PRIMARYDOWN Then
            
            ; Do Nothing
            
            Else

               GUIDelete($GUI_PREVIEW)
               GUIDelete($GUI_EMBED)
            Return

            EndIf

         Case Else

            Msgbox(1,"Hi","Something Else")
    EndSwitch
WEnd

 

Thanks guys!

[water]

Why wouldn't the close button of the GUI be enough?

[Blueman]

Because my GUI doesn't have a close button
And when the GUI is active in the background i would like it to close automatically, so i would like to delete the GUI when i am doing something else rather than working in the GUI.
 

[water]

HotKeySet?

[Blueman]

Hmm, Tried that but the problem is that the GUI should not be Deleted when i am working in it.
So when i attach the left mouse button as a Hotkey it is closing my GUI even if i am pressing a button in that GUI,...

[water]

What I don't get is why you need to close the GUI while in the background?
Can't you bring it back into foreground and then click the button designed to close the application?

[Melba23]

Blueman,

Perhaps something like this?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <TrayConstants.au3>

Global $hGUI



Opt("TrayOnEventMode", 1) ; Use event trapping for tray menu
Opt("TrayMenuMode", 3) ; Default tray menu items will not be shown

$cTray_ShowGUI = TrayCreateItem("Create GUI")
TrayItemSetOnEvent($cTray_ShowGUI, "_ShowGUI")
TrayItemSetState($cTray_ShowGUI, $TRAY_DISABLE)
TrayCreateItem("")
TrayCreateItem("Exit")
TrayItemSetOnEvent(-1, "_Exit")
TraySetState()

_ShowGUI()

While 1
    If GUIGetMsg() = $GUI_EVENT_CLOSE Then Exit

    ; As soon as the GUI is not active, delete it
    If Not WinActive($hGUI) Then
        GUIDelete($hGUI)
        TrayItemSetState($cTray_ShowGUI, $TRAY_ENABLE)
    EndIf



WEnd



Func _ShowGUI()
    $hGUI = GUICreate("Test", 500, 500)
    GUISetState()
    TrayItemSetState($cTray_ShowGUI, $TRAY_DISABLE)
EndFunc



Func _Exit()
    Exit
EndFunc

Although unless your GUI is very simple and called only rarely, I would recommend creating it just the once and then hiding/showing it rather then deleting/recreating it each time.

M23

[Blueman]

Hi Melba,

Thats Brilliant!
Didn't think of checking if the Window is active,...

Will be back with the result asap

 

Yes; Works like a charm!
Thanks for the help

Edited August 13, 2015 by Blueman