Multiple Colours one Line

[RaiNote 10]

Hi,

is there a way to convert this Code to an Code which can make more than one Color in one line?

Func _GUICtrlRichEdit_WriteLine($hWnd, $sText, $iIncrement = 0, $sAttrib = "", $iColor = -1)

    ; Count the @CRLFs
    StringReplace(_GUICtrlRichEdit_GetText($hWnd, True), @CRLF, "")
    Local $iLines = @extended
    ; Adjust the text char count to account for the @CRLFs
    Local $iEndPoint = _GUICtrlRichEdit_GetTextLength($hWnd, True, True) - $iLines

    ; Add new text
    _GUICtrlRichEdit_AppendText($hWnd, $sText & @CRLF)
    ; Select text between old and new end points
    _GuiCtrlRichEdit_SetSel($hWnd, $iEndPoint, -1)
    ; Convert colour from RGB to BGR
    $iColor = Hex($iColor, 6)
    $iColor = '0x' & StringMid($iColor, 5, 2) & StringMid($iColor, 3, 2) & StringMid($iColor, 1, 2)
    ; Set colour
    If $iColor <> -1 Then _GuiCtrlRichEdit_SetCharColor($hWnd, $iColor)
    ; Set size
    If $iIncrement <> 0 Then _GUICtrlRichEdit_ChangeFontSize($hWnd, $iIncrement)
    ; Set weight
    If $sAttrib <> "" Then _GUICtrlRichEdit_SetCharAttributes($hWnd, $sAttrib)
    ; Clear selection
    _GUICtrlRichEdit_Deselect($hWnd)

EndFunc

 

[Danyfirex 391]

just simple pass string with @crlf  like  "Hola" & @CRLF & "Como estas"

 

Saludos

Edited September 7, 2015 by Danyfirex

[RaiNote 10]

ok thx~

[Melba23 2,475]

RaiNote,

Just remove the @CRLFs:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiRichEdit.au3>

$hGui = GUICreate("RichEdit Test", 320, 350)

$hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))

GUISetState()

Sleep(1000)

; Write in black
_GUICtrlRichEdit_WriteText($hRichEdit, "I am in BLACK ", Default, Default, 0x000000)

Sleep(2000)

; Write in red
_GUICtrlRichEdit_WriteText($hRichEdit, "I am in RED " & @CRLF, Default, Default, 0xFF0000)

Sleep(2000)

; And back to black
_GUICtrlRichEdit_WriteText($hRichEdit, "I am back in BLACK ", Default, Default, 0x000000)

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            GUIDelete()
            Exit
    EndSwitch



WEnd



Func _GUICtrlRichEdit_WriteText($hWnd, $sText, $iIncrement = 0, $sAttrib = "", $iColor = -1)

    ; Count the @CRLFs
    StringReplace(_GUICtrlRichEdit_GetText($hWnd, True), @CRLF, "")
    Local $iLines = @extended
    ; Adjust the text char count to account for the @CRLFs
    Local $iEndPoint = _GUICtrlRichEdit_GetTextLength($hWnd, True, True) - $iLines

    ; Add new text
    _GUICtrlRichEdit_AppendText($hWnd, $sText) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    ; Select text between old and new end points
    _GuiCtrlRichEdit_SetSel($hWnd, $iEndPoint, -1)
    ; Convert colour from RGB to BGR
    $iColor = Hex($iColor, 6)
    $iColor = '0x' & StringMid($iColor, 5, 2) & StringMid($iColor, 3, 2) & StringMid($iColor, 1, 2)
    ; Set colour
    If $iColor <> -1 Then _GuiCtrlRichEdit_SetCharColor($hWnd, $iColor)
    ; Set size
    If $iIncrement <> 0 Then _GUICtrlRichEdit_ChangeFontSize($hWnd, $iIncrement)
    ; Set weight
    If $sAttrib <> "" Then _GUICtrlRichEdit_SetCharAttributes($hWnd, $sAttrib)
    ; Clear selection
    _GUICtrlRichEdit_Deselect($hWnd)

EndFunc

M23

[RaiNote 10]

Thanks Melba~

[kylomas 367]

Another way to look at it.  Set the char/string attributes then write to the control...(as opposed to write, select, change, deselect)...

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiRichEdit.au3>

local $sString1 = 'I am a piece of text that wants to be multi-colored.  Every letter is a different color.'
local $sString2 = 'I am a piece of text that wants to be multi-colored.  Every word is a different color.'
local $aColors = [0xff0000,0x00ff00, 0x0000ff], $LastColor, $Color

$hGui = GUICreate("RichEdit Test", 320, 350)

$hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))

GUISetState()

for $i = 0 to stringlen($sString1)
    ; ensure successive unique color
    $Color = $aColors[random(0,2,1)]
    while $Color = $LastColor

        $Color = $aColors[random(0,2,1)]
    wend
    $LastColor = $Color
    _GUICtrlRichEdit_SetCharColor($hRichEdit,$Color)
    _GUICtrlRichEdit_AppendText($hRichEdit,stringmid($sString1,$i,1))
next
    _GUICtrlRichEdit_AppendText($hRichEdit,@crlf)

local $aTemp = stringsplit($sString2, ' ', 2)
for $i = 0 to ubound($aTemp) - 1
    ; ensure successive unique color
    $Color = $aColors[random(0,2,1)]
    while $Color = $LastColor

        $Color = $aColors[random(0,2,1)]
    wend
    $LastColor = $Color
    _GUICtrlRichEdit_SetCharColor($hRichEdit,$Color)
    _GUICtrlRichEdit_AppendText($hRichEdit,$aTemp[$i] & ' ')
next

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            GUIDelete()
            Exit
    EndSwitch



WEnd

kylomas