Get style of a control

[jdelaney]

I'm trying to setup a function that will return the text or checked state of a button...when the button is a checkbox or a radio, return the "ischecked", else return the button's text...I'm not seeing anything that would return the style.

[careca]

https://www.autoitscript.com/autoit3/docs/functions/GUIGetStyle.htm

What do you think?

EDIT: wait, you mean the style of the button?

Edited January 6, 2016 by careca

[jdelaney]

Yes, the style of the button...I attempted to pass the handle of the control to that function, and no good...returns 0:

Here is a slightly modified help file function...:

#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <WindowsConstants.au3>

_Main()

Func _Main()
    Local $btn, $btn2
    $h = GUICreate("Buttons", 400, 400)
    GUISetState()
    $btn = GUICtrlCreateButton("Button1", 10, 10, 90, 50)
    $btn2 = GUICtrlCreateButton("Button2", 10, 70, 90, 50)
    $btn3 = GUICtrlCreateButton("Button3", 10, 130, 90, 50)
    MsgBox(4096, "Information", "Setting Button Style")
    _GUICtrlButton_SetStyle($btn, $BS_AUTORADIOBUTTON)
    _GUICtrlButton_SetStyle($btn2, $BS_AUTOCHECKBOX)

    $hB1 = ControlGetHandle($h,"",$btn)
    $hB2 = ControlGetHandle($h,"",$btn2)
    $hB3 = ControlGetHandle($h,"",$btn3)
    $sStyleB1 = GUIGetStyle($hB1)
    $sStyleB2 = GUIGetStyle($hB2)
    $sStyleB3 = GUIGetStyle($hB3)
    ConsoleWrite($hB1 & " " & $sStyleB1 & @CRLF)
    ConsoleWrite($hB2 & " " & $sStyleB2 & @CRLF)
    ConsoleWrite($hB3 & " " & $sStyleB3 & @CRLF)

EndFunc   ;==>_Main
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop

    EndSwitch
WEnd

 

Edited January 6, 2016 by jdelaney

[Melba23]

jdelaney,

when the button is a checkbox or a radio, return the "ischecked", else return the button's text

This script will do that:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$cRadio_1 = GUICtrlCreateRadio(" Radio control 1", 10, 10, 200, 20)

$cRadio_2 = GUICtrlCreateRadio(" Radio control 2", 10, 40, 200, 20)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cRadio_1, $cRadio_2
            $sMsg = ""
            If GUICtrlRead($cRadio_1) = $GUI_CHECKED Then
                $sMsg &= "State: Radio 1 checked"
            Else
                $sMsg &= "Text: " & GUICtrlRead($cRadio_1, 1)
            EndIf

            $sMsg &= @CRLF
            If GUICtrlRead($cRadio_2) = $GUI_CHECKED Then
                $sMsg &= "State: Radio 2 checked"
            Else
                $sMsg &= "Text: " & GUICtrlRead($cRadio_2, 1)
            EndIf

            MsgBox($MB_SYSTEMMODAL, "Result", $sMsg)

    EndSwitch



WEnd

If you actually want the style, then you need to call the API as explained in the Setting Styles tutorial in the Wiki:

#include <Constants.au3> ; Do not forget these include files!
#include <WinAPI.au3>
 
$iStyle   = _WinAPI_GetWindowLong(GUICtrlGetHandle($cControlID), $GWL_STYLE)
$iExStyle = _WinAPI_GetWindowLong(GUICtrlGetHandle($cControlID), $GWL_EXSTYLE)

M23

[jdelaney]

Thanks Melba, I posted that just as an example, I'm working with a 3rd party application so the Gui* funcs won't do it for me...I'll look into _WinAPI_GetWindowLong.

[jdelaney]

Got it...thanks again Melba...just need to add a check if there is a BitAND of either $BS_RADIOBUTTON or $BS_AUTORADIOBUTTON...if not, it's a button.:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <WindowsConstants.au3>

_Main()

Func _Main()
    Local $btn, $btn2
    $h = GUICreate("Buttons", 400, 400)
    GUISetState()
    $btn = GUICtrlCreateButton("Button1", 10, 10, 90, 50)
    $btn2 = GUICtrlCreateButton("Button2", 10, 70, 90, 50)
    $btn3 = GUICtrlCreateButton("Button3", 10, 130, 90, 50)

    _GUICtrlButton_SetStyle($btn, $BS_AUTORADIOBUTTON)
    _GUICtrlButton_SetStyle($btn2, $BS_AUTOCHECKBOX)

    $hB1 = ControlGetHandle($h,"",$btn)
    $hB2 = ControlGetHandle($h,"",$btn2)
    $hB3 = ControlGetHandle($h,"",$btn3)

    $sStyleB1 = _WinAPI_GetWindowLong(GUICtrlGetHandle($btn), $GWL_STYLE)
    $sStyleB2 = _WinAPI_GetWindowLong(GUICtrlGetHandle($btn2), $GWL_STYLE)
    $sStyleB3 = _WinAPI_GetWindowLong(GUICtrlGetHandle($btn3), $GWL_STYLE)

    If BitAND($sStyleB1,$BS_CHECKBOX)=$BS_CHECKBOX Or BitAND($sStyleB1,$BS_AUTOCHECKBOX)=$BS_AUTOCHECKBOX Then
        ConsoleWrite("Button 1 is a checkbox" & @CRLF)
    ElseIf BitAND($sStyleB1,$BS_RADIOBUTTON)=$BS_RADIOBUTTON Or BitAND($sStyleB1,$BS_AUTORADIOBUTTON)=$BS_AUTORADIOBUTTON Then
        ConsoleWrite("Button 1 is a radio" & @CRLF)
    Else
        ConsoleWrite("Button 1 is only a button" & @CRLF)
    EndIf



    If BitAND($sStyleB2,$BS_CHECKBOX)=$BS_CHECKBOX Or BitAND($sStyleB2,$BS_AUTOCHECKBOX)=$BS_AUTOCHECKBOX Then
        ConsoleWrite("Button 2 is a checkbox" & @CRLF)
    ElseIf BitAND($sStyleB2,$BS_RADIOBUTTON)=$BS_RADIOBUTTON Or BitAND($sStyleB2,$BS_AUTORADIOBUTTON)=$BS_AUTORADIOBUTTON Then
        ConsoleWrite("Button 2 is a radio" & @CRLF)
    Else
        ConsoleWrite("Button 2 is only a button" & @CRLF)
    EndIf



    If BitAND($sStyleB3,$BS_CHECKBOX)=$BS_CHECKBOX Or BitAND($sStyleB3,$BS_AUTOCHECKBOX)=$BS_AUTOCHECKBOX Then
        ConsoleWrite("Button 3 is a checkbox" & @CRLF)
    ElseIf BitAND($sStyleB3,$BS_RADIOBUTTON)=$BS_RADIOBUTTON Or BitAND($sStyleB3,$BS_AUTORADIOBUTTON)=$BS_AUTORADIOBUTTON Then
        ConsoleWrite("Button 3 is a radio" & @CRLF)
    Else
        ConsoleWrite("Button 3 is only a button" & @CRLF)
    EndIf

EndFunc   ;==>_Main
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop

    EndSwitch
WEnd

 

Edited January 6, 2016 by jdelaney

[jdelaney]

Well, the above works on the simple controls created by autoit, but not for my 3rd party app.

Is there a way to get the actual size of the button within the controlgetpos area?