_IEEmbedded2! UDF

[tarretarretarre]

Yet another IE UDF, but this time I "covered all angels" to make it as close to "embedded" as possible, the biggest inspiration came from Dale

Anyway, one of the issues with the other "snipplets\UDF's" is that $WS_POPUP style will cause other Windows to overlap, even though you clicked on the GUI's "Embedded window". see picture:

This issue is solved, but there is an option to disable it, if the user want

One more small issue with others IE Embedded UDF's is that implementation should not be so much different than the original implementation was. I am not ranting, I am just speaking for my mind.

So here we go:

This is how the classic _IeCreateEmbedded() implementation goes down

#include <IE.au3>

Local $hGUI = GUICreate("_IECreateEmbedded", 800, 600)

Local $oIE = _IECreateEmbedded()
GUICtrlCreateObj($oIE, 0, 0, 800, 600)

GUISetState()

_IENavigate($oIE, "https://www.google.se")

While GUIGetMsg() <> - 3
wend

and this is how _IeCreateEmbedded2() is implemented

#include <IE.au3>
#include <_IECreateEmbedded2.au3>

Local $hGUI = GUICreate("_IECreateEmbedded", 800, 600)

Local $oIE = _IEEmbedded2_Create($hGUI, 0, 0, 800, 600)

GUISetState()

_IENavigate($oIE, "https://www.google.se")

While GUIGetMsg() <> - 3
wend

The only downside with this implementation is that _IECreateEmbedded2() is not an GUI control, it only has our Com Object, so I added basic manipulation.

I will change \ add more options based on user requests or if I feel like it.

_IEEmbedded2_Move($iLeft, $iTop, $iWidth = Default, $iHeight = Default) ;Similar to AutoIT's WinMove
_IEEmbedded2_Hide()
_IEEmbedded2_Show()

Here is a GUI example with different options, so you can test some of the functionality

 Example.au3

expandcollapse popup

#include <_IEEmbedded2.au3>

Local $hGUI = GUICreate("_IEEmbedded2 Example Gui", 1575, 600)
Local $iDMove = GUICtrlCreateButton("Move", 0, 0, 225, 50)
Local $iDHide = GUICtrlCreateButton("Hide", 225, 0, 225, 50)
Local $iDShow = GUICtrlCreateButton("Show", 450, 0, 225, 50)
Local $iDnav = GUICtrlCreateButton("Navigate", 675, 0, 225, 50)
Local $iDestroy = GUICtrlCreateButton("Destroy", 900, 0, 225, 50)
Local $iDCreate = GUICtrlCreateButton('Create with ($iCmdLine = "-extoff -private")', 1125, 0, 225, 50)
Local $iDCreateNoWsChildOnBlur = GUICtrlCreateButton("Create with ($iWsChildOnBlurMS = 0)", 1350, 0, 225, 50)

Local $oIE = _IEEmbedded2_Create($hGUI, 0, 50, 1575, 550, "http://www.google.se/", Default, Default, Default)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            _IEQuit($oIE)
            Exit
        Case $iDMove
            _IEEmbedded2_Move(Random(0, 10, 1), Random(50, 60, 1))
            If @error Then MsgBox(0, "Error", "Failed to move window")
        Case $iDHide
            _IEEmbedded2_Hide()
            If @error Then MsgBox(0, "Error", "Failed to hide window")
        Case $iDShow
            _IEEmbedded2_Show()
            If @error Then MsgBox(0, "Error", "Failed to show window")
        Case $iDnav
            If IsObj($oIE) Then
                _IENavigate($oIE, "https://www.autoitscript.com/site/")
            Else
                MsgBox(0, "Error", "Failed to navigate")
            EndIf
        Case $iDestroy
            If IsObj($oIE) Then
                _IEQuit($oIE)
                 ___IEEmbedded2_Data(0, 0, 0, 0); only required if $iWsChildOnBlurMS = 0
            Else
                MsgBox(0, "Error", "Failed to destroy object.")
            EndIf
        Case $iDCreate
            Local $tmpOie = _IEEmbedded2_Create($hGUI, 0, 50, 1575, 550, "https://www.google.com/", "-extoff -private", Default, Default)
            If Not @error Then
                $oIE = $tmpOie
            Else
                MsgBox(0, "Error", "Failed to _IEEmbedded2_Create, error code: "&@error)
            EndIf
        Case $iDCreateNoWsChildOnBlur
            Local $tmpOie = _IEEmbedded2_Create($hGUI, 0, 50, 1575, 550, Default, Default, Default, 0)
            If Not @error Then
                $oIE = $tmpOie
            Else
                MsgBox(0, "Error", "Failed to _IEEmbedded2_Create, error code: "&@error)
            EndIf
    EndSwitch
WEnd

 _IEEmbedded2.au3

expandcollapse popup

#include-once
#include <IE.au3>
#include <WinAPI.au3>
#include <GuiConstants.au3>
Opt("WinWaitDelay", 1)

; #FUNCTION# ====================================================================================================================
; Name ..........: _IEEmbedded2_Create
; Description ...: Creates an "embedded Internet Explorer window" for a parent window (E.ex GuiCreate), and returns a webbrowser object refrence which can be used with _IE* Functions
; Syntax ........: _IEEmbedded2_Create($hWndParent, $iLeft, $iTop, $iWidth, $iHeight, $iCmdLine = Default, $iTimeoutMS = Default, $iWsChildOnBlurMS = Default)
; Parameters ....: $hWndParent         - The handle of the window you would like to embed internet explorer in
;                  $iLeft             - X1
;                  $iTop              - Y1
;                  $iWidth            - X2
;                  $iHeight           - Y2
;                  $iDefaultPage      - [optional] Default page on launch, _IeNavigate will be used as soon as the object exists and the script does not wait for the page to load (Default = about:blank)
;                  $iCmdLine          - [optional] Parameters passed when starting Iexplore, see remarks. (Default = "")
;                  $iTimeoutMS        - [optional] Max wait time in milliseconds before SetError, se @error 5 and 6. (Default = 30000 ms)
;                  $iWsChildOnBlurMS  - [optional] How often in milliseconds we want to make sure $hParrent does not get overlapped by other Windows gui's, set 0 to disable (Default = 100 ms)
; Return values .: Success      - a Webbrowser object reference.
;                  Failure      - 0 and sets @error to non zero.
; Author ........: TarreTarreTarre
; Modified.......:
; Remarks .......: Max 1 instance is allowed.
;
;                  Set $iWsChildOnBlurMS to 0 if you do not wish to have $hWndChild altered when the $hWndParent is not active, this will however cause other windows to overlap your Gui and more.
;                  Also, if $iAdlibCalltime is 0, you have to manually reset _IEEmbedded2_Createdata's data if you want to invoke _IEEmbedded2_Create again.
;                  Use ___IEEmbedded2_Data(0, 0, 0, 0) to reset data
;
;                  For $iCmdLine, these commands are avilable -extoff, -framemerging, -noframemerging, -nohangrecovery, -private, -nosessionmerging And -sessionmerging
;                  Read more about Command-Line Options at https://msdn.microsoft.com/en-us/library/hh826025(v=vs.85).aspx
; Link ..........:
; Example .......:
; @error ........: 1 - $hWndParent is not a valid window handle.
;                  2 - Iexplore.exe not found.
;                  3 - Another instance of _IEEmbedded2_ is already running.
;                  4 - $iCmdLine is provided with invalid parameters
;                  5 - Load Wait Timeout, was not able to retrive Iexplore.exe window handle.
;                  6 - (IE >= 10 only) Load Wait Timeout, failed to force $hWndChild into a minimized state.
;                  7 - Windows API error, check @extended for more information
Func _IEEmbedded2_Create($hWndParent, $iLeft, $iTop, $iWidth, $iHeight, $iDefaultPage = Default, $iCmdLine = Default, $iTimeoutMS = Default, $iWsChildOnBlurMS = Default)

    $iDefaultPage = ($iDefaultPage == Default ? "about:blank" : $iDefaultPage)
    $iCmdLine = ($iCmdLine == Default ? "" : StringRegExpReplace($iCmdLine, "([a-zA-Z]*)\s*[-]{1}", "$1 -"))
    $iTimeoutMS = ($iTimeoutMS == Default ? 30000 : $iTimeoutMS)
    $iWsChildOnBlurMS = ($iWsChildOnBlurMS == Default ? 100 : $iWsChildOnBlurMS)

    Local $sIexplorePath = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\IEXPLORE.EXE", "")
    Local $sUrl = StringFormat("about:blank#%s", Chr(Random(65, 90, 1)) & Random(1, 100, 1))

    If Not IsHWnd($hWndParent) Then Return SetError(1, 0, 0)
    If Not FileExists($sIexplorePath) Then Return SetError(2, 0, 0)
    If ___IEEmbedded2_IsInited() Then Return SetError(3, 0, 0)
    If Not StringRegExp($iCmdLine, _
            "^((|-extoff|-framemerging|-noframemerging|-nohangrecovery|-private|-nosessionmerging|-sessionmerging)\s*){1,}+$") Then Return SetError(4, 0, 0)

    Local $Pid = Run(StringFormat("%s -k %s %s", $sIexplorePath, $iCmdLine, $sUrl), "", @SW_HIDE)
    Local $Timeout = TimerInit()
    Local $_IEErrorNotify = _IEErrorNotify(False)

    Do
        Local $oIE = _IEAttach($sUrl, "url")

        If TimerDiff($Timeout) > $iTimeoutMS Then
            _IEErrorNotify($_IEErrorNotify)
            ProcessClose($Pid)
            Return SetError(5, 0, 0)
        EndIf

        Sleep(0)
    Until IsObj($oIE)
    _IEErrorNotify($_IEErrorNotify)

    Local $hWndChild = _IEPropertyGet($oIE, "hwnd")

    _WinAPI_MoveWindow($hWndChild, -1000, -1000, -1000, -1000, True)
    _IENavigate($oIE, $iDefaultPage, 0)

    ;IEVer >= 10 needs to be minimized or it will not disappear from the taskbar @ windows 7 32\64 bit & mby other win vers.
    If Int(FileGetVersion($sIexplorePath)) >= 10 Then
        Do
            WinActivate($hWndChild, "")
            WinSetState($hWndChild, "", @SW_MINIMIZE)
            If TimerDiff($Timeout) > $iTimeoutMS Then
                ProcessClose($Pid)
                Return SetError(6, 0, 0)
            EndIf
        Until WinGetState($hWndChild) == 23 ; $WIN_STATE_EXISTS + $WIN_STATE_VISIBLE + $WIN_STATE_MINIMIZED
    EndIf

    _WinAPI_SetParent($hWndChild, $hWndParent)
    _WinAPI_MoveWindow($hWndChild, $iLeft, $iTop, $iWidth, $iHeight, True)
    _WinAPI_SetWindowLong($hWndChild, $GWL_STYLE, $WS_POPUP + $WS_VISIBLE)

    If @error Then
        SetExtended(1, _WinAPI_GetLastError())
        ProcessClose($Pid)
        Return SetError(7, 1, 0)
    EndIf

    Local $aDimensions = [$iLeft, $iTop, $iWidth, $iHeight]

    ___IEEmbedded2_Data($hWndParent, $hWndChild, $aDimensions, $iWsChildOnBlurMS)

    If $iWsChildOnBlurMS Then
        AdlibRegister("___IEEmbedded2_WsChildOnBlur", $iWsChildOnBlurMS)
    EndIf

    Return $oIE
EndFunc   ;==>_IEEmbedded2_Create

; #FUNCTION# ====================================================================================================================
; Name ..........: _IEEmbedded2_Move
; Description ...: Moves a previously created _IEEmbedded2_Create window
; Syntax ........: _IEEmbedded2_Move($iLeft, $iTop, $iWidth = Default, $iHeight = Default)
; Parameters ....: $iLeft           - X1
;                  $iTop            - Y1
;                  $iWidth          - X2 [optional] (Default = Original value)
;                  $iHeight         - Y2 [optional] (Default = Original value)
; Return values .: Success      - True
;                  Failure      - 0 and sets @error to non zero.
; Author ........: TarreTarreTarre
; Modified.......:
; Remarks .......: Similar to AutoIt's WinMove
;                  Do not use this to "hide" objects, use _IEEmbedded2_Hide() instead
; Link ..........:
; Example .......:
; @error ........: 1 - _IEEmbedded2_Create is not invoked
Func _IEEmbedded2_Move($iLeft, $iTop, $iWidth = Default, $iHeight = Default)

    Local $e = ___IEEmbedded2_Data()
    Local $hc = $e[1]
    Local $d = $e[2]
    Local $alr = $e[3]

    If Not IsHWnd($hc) Then Return SetError(1, 0, 0)

    $iWidth = ($iWidth == Default ? $d[2] : $iWidth)
    $iHeight = ($iHeight == Default ? $d[3] : $iHeight)

    _WinAPI_MoveWindow($hc, $iLeft, $iTop, $iWidth, $iHeight, True)
    Local $nd = [$iLeft, $iTop, $iWidth, $iHeight]
    ___IEEmbedded2_Data(Null, Null, $nd)

    If $alr Then AdlibRegister("___IEEmbedded2_WsChildOnBlur", $alr)

    Return True
EndFunc   ;==>_IEEmbedded2_Move

; #FUNCTION# ====================================================================================================================
; Name ..........: _IEEmbedded2_Hide
; Description ...: Hides a previously created _IEEmbedded2_Create window
; Syntax ........: _IEEmbedded2_Hide()
; Parameters ....:
; Return values .: Success      - True
;                  Failure      - 0 and sets @error to non zero.
; Author ........: TarreTarreTarre
; Modified.......:
; Remarks .......:
; Link ..........:
; Example .......:
; @error ........: 1 - _IEEmbedded2_Create is not invoked
Func _IEEmbedded2_Hide()

    Local $e = ___IEEmbedded2_Data()
    Local $hc = $e[1]

    If Not IsHWnd($hc) Then Return SetError(1, 0, 0)

    _WinAPI_MoveWindow($hc, 0, 0, 0, 0, True)

    AdlibUnRegister("___IEEmbedded2_WsChildOnBlur")

    Return True
EndFunc   ;==>_IEEmbedded2_Hide

; #FUNCTION# ====================================================================================================================
; Name ..........: _IEEmbedded2_Show
; Description ...: Restore the window to its original size, a counter to _IEEmbedded2_Move() \ _IEEmbedded2_Hide()
; Syntax ........: _IEEmbedded2_Show()
; Parameters ....:
; Return values .: Success      - True
;                  Failure      - 0 and sets @error to non zero.
; Author ........: TarreTarreTarre
; Modified.......:
; Remarks .......:
; Link ..........:
; Example .......:
; @error ........: 1 - _IEEmbedded2_Create is not invoked
Func _IEEmbedded2_Show()

    Local $e = ___IEEmbedded2_Data()
    Local $hc = $e[1]

    If Not IsHWnd($hc) Then Return SetError(1, 0, 0)

    Local $d = $e[2]
    Local $alr = $e[3]

    _WinAPI_MoveWindow($hc, $d[0], $d[1], $d[2], $d[3], True)

    If $alr Then AdlibRegister("___IEEmbedded2_WsChildOnBlur", $alr)

    Return True
EndFunc   ;==>_IEEmbedded2_Show

#Region  IECreateEmbedded2 Internals functions
Func ___IEEmbedded2_Data($_hWndParent = Null, $_hWndChild = Null, $_aDimensions = Null, $_iWsChildOnBlurMS = Null)
    Local Static $hWndParent = 0
    Local Static $hWndChild = 0
    Local Static $aDimensions = 0
    Local Static $iWsChildOnBlurMS = 0

    If $_hWndParent <> Null Then $hWndParent = $_hWndParent
    If $_hWndChild <> Null Then $hWndChild = $_hWndChild
    If IsArray($_aDimensions) Then $aDimensions = $_aDimensions
    If $_iWsChildOnBlurMS <> Null Then $iWsChildOnBlurMS = $_iWsChildOnBlurMS

    Local $aRet = [$hWndParent, $hWndChild, $aDimensions, $iWsChildOnBlurMS]
    Return $aRet
EndFunc   ;==>___IEEmbedded2_Data

Func ___IEEmbedded2_IsInited()
    Local $e = ___IEEmbedded2_Data()
    Return IsHWnd($e[1])
EndFunc   ;==>___IEEmbedded2_IsInited

Func ___IEEmbedded2_WsChildOnBlur()
    Local Static $p
    Local $c = 0
    Local $e = ___IEEmbedded2_Data()
    Local $hp = $e[0]
    Local $hc = $e[1]

    If Not IsHWnd($hc) Then
        ___IEEmbedded2_Data(0, 0, 0, 0)
        Return AdlibUnRegister("___IEEmbedded2_WsChildOnBlur")
    EndIf

    If WinActive($hp) Or WinActive($hc) Then $c = 1

    If $c And $p <> $c Then

        Local $gmp = _WinAPI_GetMousePos()
        Local $wfp = _WinAPI_WindowFromPoint($gmp)
        Local $gp = _WinAPI_GetParent($wfp)

        _WinAPI_SetWindowLong($hc, $GWL_STYLE, $WS_POPUP + $WS_VISIBLE)
        _WinAPI_UpdateWindow($hp)

        If $wfp <> $hp And $gp <> $hp Then
            WinActivate($hc)
        EndIf

        $p = $c
    ElseIf Not $c And $p <> $c Then

        _WinAPI_SetWindowLong($hc, $GWL_STYLE, $WS_CHILD + $WS_VISIBLE)
        _WinAPI_UpdateWindow($hp)

        $p = $c
    EndIf
EndFunc   ;==>___IEEmbedded2_WsChildOnBlur
#EndRegion IECreateEmbedded2 Internals functions

This is currently tested with (AutoIt v3.3.14.0):
Windows 7 x86: Ie 8-9-10-11
Windows 7 x64: Ie 8-9-10-11

Error-report on this thread: IE version, @error code, Operationg system ex: (Windowx 10 64 bit)

 

Trevlig Helg /Tarre

Edited March 28, 2016 by tarretarretarre
Visual updates

[JohnOne]

If you are looking to improve this for general use, you might replace the following line, to get the path ti IE from the registry.

Local $sIexplorePath = @ProgramFilesDir & "\Internet Explorer\Iexplore.exe"

 

[tarretarretarre]

9 minutes ago, JohnOne said:

If you are looking to improve this for general use, you might replace the following line, to get the path ti IE from the registry.

Local $sIexplorePath = @ProgramFilesDir & "\Internet Explorer\Iexplore.exe"

 

You are correct, but before I change my code, I want to know if its possible for non admin users to still obtain this value

RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\IEXPLORE.EXE", "")

/Tarre

[coffeeturtle]

Hello Tarre,

Excellent job! I am grateful that I don't have to change much of my code to implement your new UDF!

However, in your example, when it starts or if I launch a newly created 'embedded' window, the first thing I see is a big white screen covering my entire display. It appears to shrink down into the parent window and display the correct page, but is there a way to prevent the initial Full-Screen 'embedded' browser window?

Thank you!

[coffeeturtle]

The initial Full-Screen 'embedded' browser window is by design, or am I just missing something? Anyone else?

[tarretarretarre]

Hello @coffeeturtle, the big window you see is the iexplore in kioskmode. The udf tries to minimize it as soon as possible to hide it on ie11>. Is it stuck for a long time? Or does it disappear after a while?

I will see if its possible to make it silent on creation

/tarre

Edited March 27, 2016 by tarretarretarre

[tarretarretarre]

On 3/21/2016 at 5:01 PM, coffeeturtle said:

The initial Full-Screen 'embedded' browser window is by design, or am I just missing something? Anyone else?

I have updated the UDF to hide the iexplore window as soon as it shows up.

 

/Tarre