Winmove GUI moves buttons

[FMS]

Hello,

Below is a code whish i made for this problem i've. (code 1)
The problem is that iff i try Winmove to to show the hidden button it's not working as i tought.
What i try to do is just simple expand the GUI to make the hidden button visible. (code 2)
I've already looked into GUICoordMode but don't think that's the problem.(or I don't understand it properly)
Also tried to look into the forum but din't find anything around this subject but could't find anything around this subject.

Does somebody knows what I'm doing wrong?
 

Code 1 (winmove prblem) :

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 134, 103, 192, 124)
$Button1 = GUICtrlCreateButton("1", 8, 8, 75, 25)
$Button2 = GUICtrlCreateButton("2", 8, 40, 75, 25)
$Button3 = GUICtrlCreateButton("3", 8, 72, 75, 25)
$expand_button = GUICtrlCreateButton("EXP", 96, 40, 27, 25)
$hidden_button = GUICtrlCreateButton("Hidden", 160, 40, 75, 25)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
         Case $GUI_EVENT_CLOSE
            Exit
         Case $expand_button
            WinMove($Form1, "From1", 192, 124, 300, 103)
    EndSwitch
WEnd

 

Code 2 What I'm trying to expand to :

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 265, 114, 192, 124)
$Button1 = GUICtrlCreateButton("1", 8, 8, 75, 25)
$Button2 = GUICtrlCreateButton("2", 8, 40, 75, 25)
$Button3 = GUICtrlCreateButton("3", 8, 72, 75, 25)
$expand_button = GUICtrlCreateButton("EXP", 96, 40, 27, 25)
$hidden_button = GUICtrlCreateButton("Hidden", 160, 40, 75, 25)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

 

[water]

Melba23 has written a great UDF to do exactly what you want to do.

 

[AutoBert]

Your code will work using the correct resizing mode and valid window-sizes:

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIResizeMode", $GUI_DOCKALL) ;0=no resizing, <1024 special resizing

$Form1 = GUICreate("Form1", 134, 103, 192, 124)
$Button1 = GUICtrlCreateButton("1", 8, 8, 75, 25)
$Button2 = GUICtrlCreateButton("2", 8, 40, 75, 25)
$Button3 = GUICtrlCreateButton("3", 8, 72, 75, 25)
$expand_button = GUICtrlCreateButton("EXP", 96, 40, 27, 25)
$hidden_button = GUICtrlCreateButton("Hidden", 160, 40, 75, 25)
;GUICtrlSetState($hidden_button,BitOR($GUI_HIDE,$GUI_DISABLE ))
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
         Case $GUI_EVENT_CLOSE
            Exit
        Case $expand_button
            $aWin=WinGetPos($Form1)
            WinMove($Form1, "", $aWin[0], $aWin[1], 265, $aWin[3])
            ;GUICtrlSetState($hidden_button,BitOR($GUI_SHOW,$GUI_ENABLE ))
        Case $hidden_button
            $aWin=WinGetPos($Form1)
            WinMove($Form1, "", $aWin[0], $aWin[1], 134, $aWin[3])
            ;GUICtrlSetState($hidden_button,BitOR($GUI_HIDE,$GUI_DISABLE ))
            MsgBox(64,'Test','Hidden Button clicked')
    EndSwitch
WEnd

Test above script:

1. use the tab to tab to hidden button, yes button work also when he isn't visible
2. test the expand button. if isn't espected result post again

Remove the semicolons in lines: 12, 23 and 27 and test again.

[FMS]

YESSS totaly what I was looking for.
Thanks @AutoBert for the good explanation.
also credits to @water , Ive looked into it and think the solution Autobert proposed is little bit simpler to have the same.

 

[water]

I'm sure AutoBert's solution perfectly fits your needs whereas Melba's UDF is more of a swiss army knife and does much more