Help with the error function

[CaptainBeardsEyesBeard]

Hi Guys/gals,

 

I'm using this function and trying to utilise the error function in a try/catch situation

 

Func InputMatterNumber($MatterNumber)
   Local $hWnd1 = WinWait("[CLASS:ThunderRT6FormDC]", "", 10)
ControlSend($hWnd1, "", "ThunderRT6TextBox22", $MatterNumber)
     FileWrite($hFilehandle, @CRLF & $MatterNumber)
If @error = 1 Then
   MsgBox(($MB_ICONINFORMATION, "", "Cannot enter Matter number")
EndIf
Sleep(4000)
EndFunc

However I just ran it and it didn't send the matter number to the box but I didn't get the MsgBox which should've been triggered by the error function?

 

Cheers

[water]

According to the help file: FileWrite does not set @error but the return value tells you if the command was successful or not

[water]

If you want to check if ControlSend did work or not then the check needs to be done immediately after ControlSend. Because each AutoIt function call resets @error.

[AutoBert]

16 minutes ago, CaptainBeardsEyesBeard said:

FileWrite($hFilehandle, @CRLF & $MatterNumber)

The handle is realy existing! No error occurs.

Edited August 9, 2018 by AutoBert

[water]

Sure you get an error!

Global $handle
$iReturnvalue = FileWrite($handle, "Text")
If $iReturnvalue = 1 Then
    MsgBox(0, "Success!", "Data written to file!")
Else
    MsgBox(0, "Error!", "Data NOT written to file!")
EndIf

 

[ternal]

@water is there a reason why you need to assign a variable? can't you just use:

Global $handle 
If FileWrite($handle, "Text") = 1 Then
    MsgBox(0, "Success!", "Data written to file!")
Else
    MsgBox(0, "Error!", "Data NOT written to file!")
EndIf

 

 

[water]

No, there's no reason except readability

Your code can even be shortened to:

Quote

Global $handle 
If FileWrite($handle, "Text") Then
    MsgBox(0, "Success!", "Data written to file!")
Else
    MsgBox(0, "Error!", "Data NOT written to file!")
EndIf

 

 

[water]

Or even shorter

Global $handle
MsgBox(0, "Result", (FileWrite($handle, "Text") = 1) ? "Success!" : "Error!")

 

[pixelsearch]

On 09/08/2018 at 10:19 AM, water said:

 Because each AutoIt function call resets @error.

@water : Hello. May I use this thread for a specific question related to this "@error reset when entering any Autoit function". Please have a look at the two following scripts  :

#include <MsgBoxConstants.au3>
Local $sFileRead = FileRead("C:\temp\this file name doesn't exist.txt")
If @error Then
   MsgBox(BitOR($MB_ICONERROR, $MB_TOPMOST), "1st script", "@error = " & @error)
Endif

#include <MsgBoxConstants.au3>
Local $sFileRead = FileRead("C:\temp\this file name doesn't exist.txt")
If @error Then
   MsgBox($MB_ICONERROR + $MB_TOPMOST, "2nd script", "@error = " & @error)
Endif

The 2nd script is correct (@error = 1) because the file to be read doesn't exist. So could we say that the MsgBox function in the 2nd script didn't reset @error to 0, but the BitOr() function in the 1st script did ?

I noticed Melba23 using a few times the + sign instead of BitOr(), so I tried his way and it works. My question : can we do this kind of thing with BitAnd() too ? I mean replacing BitAnd() by a mathematical operator that wont interfere with @error, as shown in the precedent scripts ?

Edited August 11, 2018 by pixelsearch

[water]

In your case BitOr resets @error to 0 because statements are evaluated from left to right (this is true for BitAnd as well).

BitAnd won't work because:
BitOr($MB_ICONERROR, $MB_TOPMOST) returns 262160
BitAnd($MB_ICONERROR, $MB_TOPMOST) returns 262144

You could solve this problem with the approach you use in your 2nd script or by:

#include <MsgBoxConstants.au3>
Local $bFlag = BitOR($MB_ICONERROR, $MB_TOPMOST)
Local $sFileRead = FileRead("C:\temp\this file name doesn't exist.txt")
If @error Then MsgBox($bFlag, "1st script", "@error = " & @error)

or by

#include <MsgBoxConstants.au3>
Local $sFileRead = FileRead("C:\temp\this file name doesn't exist.txt")
Local $iError = @error
If $iError Then MsgBox(BitOR($MB_ICONERROR, $MB_TOPMOST), "1st script", "@error = " & $iError)

 

Edited August 9, 2018 by water

[pixelsearch]

Thanks for your quick reply !

I started using your 2nd suggestion a few weeks ago, always keeping @error in a variable asap, like this (non runnable script) :

$iKeyIndex = _ArrayBinarySearch($aArray, $CheckSum, 0 ,0 ,1)
$iKeep_error = @error   ; important (+++) because any function (BitOr() in the following code) would reset @error to 0 when executed +++

If $iKeep_error = 0 Then
    MsgBox($MB_SYSTEMMODAL, 'Entry found', ' Index: ' & $iKeyIndex & "     @error = " & $iKeep_error)
Else    ; $iKeep_error <> 0
    MsgBox(BitOR($MB_ICONERROR, $MB_TOPMOST), 'Entry NOT found', ' Index: ' & $iKeyIndex & "     @error = " & $iKeep_error)
EndIf

And to make sure MsgBox resets @error to 0 even without BitOr() in it, here we go :

#include <MsgBoxConstants.au3>
Local $sFileRead = FileRead("C:\temp\this file name doesn't exist.txt")
If @error Then
   MsgBox($MB_ICONERROR + $MB_TOPMOST, "2nd script", "@error = " & @error)
   MsgBox($MB_ICONERROR + $MB_TOPMOST, "2nd script", "@error = " & @error)
Endif

It will show @error = 1 in 1st MsgBox.... immediately followed by @error = 0 in 2nd MsgBox 

Thanks water !

 

[water]

Glad I could shed some light onto the subject