How do I get the output of the matching pattern?

[BlueBandana]

 Is there a way to output the regex matches into a file?

I have a script to compare two files and check for regex matches.

I want to output the matching regex of 'testexample.txt' to another file.

#include <MsgBoxConstants.au3>
#include <Array.au3>

$Read = FileReadToArray("C:\Users\admin\Documents\testexample.txt")
$Dictionary = FileReadToArray("C:\Users\admin\Documents\example.txt")

For $p = 0 To UBound($Dictionary) - 1 Step 1
    $pattern = $Dictionary[$p]
        For $i = 0 To UBound($Read) - 1 Step 1
        $regex = $Read[$i]

            If StringRegExp($regex, $pattern, 0) Then
                MsgBox(0, "ResultsPass", "The string is in the file, highlighted strings: " )
            Else
                MsgBox(0, "ResultsFail", "The string isn't in the file.")
            EndIf
        Next
Next

 

[Nine]

If StringRegExp($regex, $pattern, 0) Then
  FileWriteLine ("Output.txt",$regex)
EndIf

This ?

[seadoggie01]

It sounds like you're looking for just the matching section to be written to the file, if so, check out the help page for StringRegExp and read up on the flag parameter.

Edit: I would guess you're looking for Flag 3, but you can use this to check... I wrote this because I couldn't understand the what the flags did. Hope it helps

#include <Array.au3>

RegExpExample()

Func RegExpExample()

    Local $sTest = '<test>a</test> <test>b</test> <test>c</Test>'
    Local $sPattern = '(?i)<test>(.*?)</test>'
    Local $vResult

    For $iFlag = 0 To 4
        $vResult = StringRegExp($sTest, $sPattern, $iFlag)
        If @error Then
            ConsoleWrite("!    StringRegExp Error: " & @error & @CRLF & @TAB & "  Flag: " & $iFlag & @CRLF)
        ElseIf IsArray($vResult) Then
            If $iFlag = 4 Then
                For $i=0 To UBound($vResult) - 1
                    If IsArray($vResult[$i]) Then
                        _ArrayDisplay($vResult[$i], "Flag " & $iFlag & " Part " & $i & "- StringRegExp Result")
                    EndIf
                Next
            Else
                _ArrayDisplay($vResult, "Flag " & $iFlag & " - StringRegExp Result")
            EndIf
        Else
            MsgBox(0, "Flag " & $iFlag & " StringRegExp Result", $vResult)
        EndIf
    Next
EndFunc

Edited October 2, 2019 by seadoggie01