$obj.Open("xxx") doesn't set @error ?

[FMS]

Hello,

I'm not sure where to ask this but :
I'm busy whit an project that needs a SQL connection whit a database.
The problem I have is in the code below: (It works when i fill in the correct info or there is a connection)
 

$conn = ObjCreate( "ADODB.Connection" )
   $DSN = "DRIVER={SQL Server};SERVER=someservername;DATABASE=dbname;UID=user;PWD=pass;"
   
   $conn.Open($DSN)
   If @error Then
       ConsoleWrite("ObjOpen Failed.")
   Else
       ConsoleWrite("ObjOpen Success.")
   EndIf

Is the code faulty or the @error isn't set this way iff there is no connection?
When i search on this forum 9/10 likewise problems are refered to catsh the @error this way but I get the error below  
 

*location*==> The requested action with this object has failed.:
$conn.Open($DSN)
$conn^ ERROR

 

[TheXman]

 

 

1 hour ago, FMS said:

When i search on this forum 9/10 likewise problems are refered to catsh the @error this way but I get the error below

I bet those 9/10 had COM error handlers defined.

In order to be able to process @error after the COM statement, you need to have a COM error handler.  Lookup the ObjEvent() function in the Help File, especially example 2 if you just want to be able to process @error.

[FMS]

Thanks @TheXman, found it and checked. I'm rather new to object handling.
For futher reference (or maybe I've implemented it wrong) here is a simplefied piece of code I'll use
 

Global $err_handler = 0

Func Err_UnRegister()
   $err_handler = 0
EndFunc

Func Err_Register()
   $err_handler = ObjEvent("AutoIt.Error", "err_func")
EndFunc

Func err_func()
   ConsoleWrite("ObjOpen Failed."& @CRLF )
EndFunc

Func set()
   $conn = ObjCreate( "ADODB.Connection" )
   $DSN = "xxx"
   Err_Register()
   $conn.Open($DSN)
   If @error Then MsgBox(4096, "COM Error Detected", @error)
   Err_UnRegister()
EndFunc


set()

 

[TheXman]

You're welcome!

 

You could simplify it by doing something like this:

set()

Func set()
    ;Set COM error handler
    $oComErr = ObjEvent("AutoIT.Error", "com_error_handler")

    $conn = ObjCreate( "ADODB.Connection" )
    $DSN = "xxx"
    $conn.Open($DSN)
    If @error Then MsgBox(4096, "COM Error Detected", $oComErr.description)
EndFunc

Func com_error_handler($oError)
    Return
EndFunc

 

Edited October 16, 2019 by TheXman

[water]

When working with ADO you should have a look at the ADO UDF which can be found on the wiki.

[FMS]

@water I use the ADO.UDF
Do you mean that there is a better solution than the simplefied code above?

[water]

I think the ADO UDF provides a better way to create/open a connection as the error handling is built in