Getting data from set of variables

[Psychobird25]

 

I'm trying to get a bunch of variables with arrays that are setup like this (I know this input sucks - I really don't have a way around it. It's the way it was given to me).

Local $data1 = [1000010, 41, 17]
Local $data2 = [1000010, 41, 16]
Local $data3 = [1000010, 40, 16]
Local $data4 = [1000010, 39, 16]
Local $data5 = [1000010, 38, 16]

Into code which is like this:

$math1 = -($y*100) + ($x*300) + 496
ConsoleWrite($math1)

What I'm attempting to do is something like this, except in a For loop.

$x = $data1[1]
$y = $data1[2]
$math1 = -($y*100) + ($x*300) + 496
ConsoleWrite($math1)

$x = $data2[1]
$y = $data2[2]
$math1 = -($y*100) + ($x*300) + 496
ConsoleWrite($math1)

$x = $data3[1]
$y = $data3[2]
$math1 = -($y*100) + ($x*300) + 496
ConsoleWrite($math1)

Is there a way to get around the imposed limitation above where each variable is $data1, $data2, etc? Thanks.

Edited November 9, 2019 by Psychobird25

[Gianni]

do you want to use or don't want to use a "for next" loop ?

Edited November 10, 2019 by Chimp

[Zedna]

Look at Eval() and/or Execute()

https://www.autoitscript.com/autoit3/docs/functions/Eval.htm

https://www.autoitscript.com/autoit3/docs/functions/Execute.htm

Edited November 10, 2019 by Zedna

[Gianni]

.... better Execute()

Local $data1 = [1000010, 41, 17]
Local $data2 = [1000010, 41, 16]
Local $data3 = [1000010, 40, 16]
Local $data4 = [1000010, 39, 16]
Local $data5 = [1000010, 38, 16]

For $i = 1 To 5
    $x = Execute('$data' & $i & '[1]')
    $y = Execute('$data' & $i & '[2]')
    $math1 = -($y * 100) + ($x * 300) + 496
    ConsoleWrite($math1 & @CRLF)
Next

 

[Psychobird25]

11 minutes ago, Chimp said:

.... better Execute()

Local $data1 = [1000010, 41, 17]
Local $data2 = [1000010, 41, 16]
Local $data3 = [1000010, 40, 16]
Local $data4 = [1000010, 39, 16]
Local $data5 = [1000010, 38, 16]

For $i = 1 To 5
    $x = Execute('$data' & $i & '[1]')
    $y = Execute('$data' & $i & '[2]')
    $math1 = -($y * 100) + ($x * 300) + 496
    ConsoleWrite($math1 & @CRLF)
Next

 

This works! Thanks

[Gianni]

You are welcome

[jchd]

You don't even need intermediate variables $x, $y, $math1:

Local $data1 = [1000010, 41, 17]
Local $data2 = [1000010, 41, 16]
Local $data3 = [1000010, 40, 16]
Local $data4 = [1000010, 39, 16]
Local $data5 = [1000010, 38, 16]

For $i = 1 To 5
    ConsoleWrite(Execute("$data" & $i & "[1] * 300 - $data" & $i & "[2] * 100 + 496") & @LF)
Next

 

[Nine]

Well, you don't even need to use Execute :

Local $data = [[1000010, 41, 17],[1000010, 41, 16],[1000010, 40, 16],[1000010, 39, 16],[1000010, 38, 16]]
For $i = 0 To UBound($data,1)-1
  ConsoleWrite($data [$i][1]*300 - $data[$i][2]*100 + 496 & @LF)
Next

or you absolutely need to live with the data1...data5

Local $data1 = [1000010, 41, 17]
Local $data2 = [1000010, 41, 16]
Local $data3 = [1000010, 40, 16]
Local $data4 = [1000010, 39, 16]
Local $data5 = [1000010, 38, 16]
Local $data = [$data1,$data2,$data3,$data4,$data5], $dt
For $i = 0 To UBound($data,1)-1
  $dt = $data[$i]
  ConsoleWrite($dt[1]*300 - $dt[2]*100 + 496 & @LF)
Next

 

Edited November 10, 2019 by Nine

[jchd]

Changing to input format is kinda cheating

[Nine]

Was just edited...